tests/vpp/perf/ip4/2n1l-25ge2p1xxv710-dot1q-ip4base-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-XXV710 | ETH | IP4FWD | BASE | DOT1Q | IP4BASE
  19 | ...
  20 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  21 | ... | L3 | Intel-XXV710
  22 | ...
  23 | Suite Teardown | Tear down 2-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | ...
  27 | Test Teardown | Tear down performance mrr test
  28 | ...
  29 | Test Template | Local Template
  30 | ...
  31 | Documentation | *Raw results IPv4 routing with IEEE 802.1Q test cases*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with\
  34 | ... | single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing. IEEE 802.1Q\
  36 | ... | tagging is applied on link between DUT1-if2 and TG-if2.
  37 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and\
  38 | ... | two static IPv4 /30 route entries. DUT1 is tested with 2p25GE NIC\
  39 | ... | XXV710 by Intel.
  40 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic\
  41 | ... | at line rate and reports total received/sent packets over trial period.\
  42 | ... | Test packets are generated by TG on links to DUT1. TG traffic profile\
  43 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per\
  44 | ... | flow-group) with all packets containing Ethernet header, IPv4 header\
  45 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC\
  46 | ... | addresses of the TG node interfaces.
  47 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  48
  49 *** Variables ***
  50 | ${subid}= | 10
  51 | ${tag_rewrite}= | pop-1
  52 | ${overhead}= | ${4}
  53 # XXV710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  54 | ${s_24.5G}= | ${24500000000}
  55 # XXV710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  56 | ${s_18.75Mpps}= | ${18750000}
  57 # TG subnets used by T-Rex
  58 | ${tg_if1_net}= | 10.10.10.0
  59 | ${tg_if2_net}= | 20.20.20.0
  60 # Traffic profile:
  61 | ${traffic_profile}= | trex-sl-2n-dot1qip4asym-ip4src254
  62
  63 *** Keywords ***
  64 | Local Template
  65 | | [Documentation]
  66 | | ... | [Cfg] DUT runs IPv4 routing with VLAN and uses ${phy_cores}\
  67 | | ... | physical core(s) for worker threads.
  68 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  69 | | ... | trial throughput test.
  70 | | ...
  71 | | ... | *Arguments:*
  72 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  73 | | ... | Type: integer, string
  74 | | ... | - phy_cores - Number of physical cores. Type: integer
  75 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  76 | | ...
  77 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  78 | | ...
  79 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  80 | | And Add PCI devices to all DUTs
  81 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  82 | | ... | ${s_24.5G} | ${framesize} | pps_limit=${s_18.75Mpps}
  83 | | ... | overhead=${overhead}
  84 | | And Apply startup configuration on all VPP DUTs
  85 | | When Initialize IPv4 forwarding with VLAN dot1q sub-interfaces in circular topology
  86 | | ... | ${tg_if1_net} | ${tg_if2_net} | ${subid} | ${tag_rewrite}
  87 | | Then Traffic should pass with maximum rate
  88 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  89
  90 *** Test Cases ***
  91 | tc01-64B-1c-dot1q-ip4base-mrr
  92 | | [Tags] | 64B | 1C
  93 | | framesize=${64} | phy_cores=${1}
  94
  95 | tc02-64B-2c-dot1q-ip4base-mrr
  96 | | [Tags] | 64B | 2C
  97 | | framesize=${64} | phy_cores=${2}
  98
  99 | tc03-64B-4c-dot1q-ip4base-mrr
 100 | | [Tags] | 64B | 4C
 101 | | framesize=${64} | phy_cores=${4}
 102
 103 | tc04-1518B-1c-dot1q-ip4base-mrr
 104 | | [Tags] | 1518B | 1C
 105 | | framesize=${1518} | phy_cores=${1}
 106
 107 | tc05-1518B-2c-dot1q-ip4base-mrr
 108 | | [Tags] | 1518B | 2C
 109 | | framesize=${1518} | phy_cores=${2}
 110
 111 | tc06-1518B-4c-dot1q-ip4base-mrr
 112 | | [Tags] | 1518B | 4C
 113 | | framesize=${1518} | phy_cores=${4}
 114
 115 | tc07-9000B-1c-dot1q-ip4base-mrr
 116 | | [Tags] | 9000B | 1C
 117 | | framesize=${9000} | phy_cores=${1}
 118
 119 | tc08-9000B-2c-dot1q-ip4base-mrr
 120 | | [Tags] | 9000B | 2C
 121 | | framesize=${9000} | phy_cores=${2}
 122
 123 | tc09-9000B-4c-dot1q-ip4base-mrr
 124 | | [Tags] | 9000B | 4C
 125 | | framesize=${9000} | phy_cores=${4}
 126
 127 | tc10-IMIX-1c-dot1q-ip4base-mrr
 128 | | [Tags] | IMIX | 1C
 129 | | framesize=IMIX_v4_1 | phy_cores=${1}
 130
 131 | tc11-IMIX-2c-dot1q-ip4base-mrr
 132 | | [Tags] | IMIX | 2C
 133 | | framesize=IMIX_v4_1 | phy_cores=${2}
 134
 135 | tc12-IMIX-4c-dot1q-ip4base-mrr
 136 | | [Tags] | IMIX | 4C
 137 | | framesize=IMIX_v4_1 | phy_cores=${4}