tests/vpp/perf/ip4/2n1l-25ge2p1xxv710-ethip4udp-ip4base-nat44-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/ip/nat.robot
  17 | Resource | resources/libraries/robot/shared/traffic.robot
  18 | ...
  19 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  20 | ... | NIC_Intel-XXV710 | ETH | IP4FWD | FEATURE | NAT44 | BASE
  21 | ...
  22 | Suite Setup | Run Keywords
  23 | ... | Set up 2-node performance topology with DUT's NIC model | L3
  24 | ... | Intel-XXV710
  25 | ... | AND | Set up performance test suite with NAT
  26 | Suite Teardown | Tear down 2-node performance topology
  27 | ...
  28 | Test Setup | Set up performance test
  29 | ...
  30 | Test Teardown | Tear down performance mrr test
  31 | ...
  32 | Test Template | Local Template
  33 | ...
  34 | Documentation | *Raw results NAT44 performance test cases*
  35 | ...
  36 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology
  37 | ... | with single links between nodes.
  38 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-UDP for IPv4 routing.
  39 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and
  40 | ... | one static IPv4 /18 route entries.
  41 | ... | DUT1 is tested with 2p25GE NIC XXV710 by Intel.
  42 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  43 | ... | at line rate and reports total received/sent packets over trial period.
  44 | ... | Test packets are generated by TG on links to DUT1. TG traffic profile
  45 | ... | contains two L3 flow-groups (flow-group per direction, 1 flow per
  46 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  47 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  48 | ... | addresses of the TG node interfaces.
  49 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  50
  51 *** Variables ***
  52 # XXV710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  53 | ${s_24.5G}= | ${24500000000}
  54 # XXV710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  55 | ${s_18.75Mpps}= | ${18750000}
  56 # Traffic profile:
  57 | ${traffic_profile}= | trex-sl-2n-ethip4udp-1u1p
  58
  59 *** Keywords ***
  60 | Local Template
  61 | | ...
  62 | | [Documentation]
  63 | | ... | [Cfg] DUT runs IPv4 routing config.
  64 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  65 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  66 | | ... | trial throughput test.
  67 | | ...
  68 | | ... | *Arguments:*
  69 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  70 | | ... | Type: integer, string
  71 | | ... | - phy_cores - Number of physical cores. Type: integer
  72 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  73 | | ...
  74 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  75 | | ...
  76 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  77 | | And Add PCI devices to all DUTs
  78 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  79 | | ... | ${s_24.5G} | ${framesize} | pps_limit=${s_18.75Mpps}
  80 | | And Add NAT to all DUTs
  81 | | And Apply startup configuration on all VPP DUTs
  82 | | When Initialize NAT44 in circular topology
  83 | | Then Traffic should pass with maximum rate
  84 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  85
  86 *** Test Cases ***
  87 | tc01-64B-1c-ethip4udp-ip4base-nat44-mrr
  88 | | [Tags] | 64B | 1C
  89 | | framesize=${64} | phy_cores=${1}
  90
  91 | tc02-64B-2c-ethip4udp-ip4base-nat44-mrr
  92 | | [Tags] | 64B | 2C
  93 | | framesize=${64} | phy_cores=${2}
  94
  95 | tc03-64B-4c-ethip4udp-ip4base-nat44-mrr
  96 | | [Tags] | 64B | 4C
  97 | | framesize=${64} | phy_cores=${4}
  98
  99 | tc04-1518B-1c-ethip4udp-ip4base-nat44-mrr
 100 | | [Tags] | 1518B | 1C
 101 | | framesize=${1518} | phy_cores=${1}
 102
 103 | tc05-1518B-2c-ethip4udp-ip4base-nat44-mrr
 104 | | [Tags] | 1518B | 2C
 105 | | framesize=${1518} | phy_cores=${2}
 106
 107 | tc06-1518B-4c-ethip4udp-ip4base-nat44-mrr
 108 | | [Tags] | 1518B | 4C
 109 | | framesize=${1518} | phy_cores=${4}
 110
 111 | tc07-9000B-1c-ethip4udp-ip4base-nat44-mrr
 112 | | [Tags] | 9000B | 1C
 113 | | framesize=${9000} | phy_cores=${1}
 114
 115 | tc08-9000B-2c-ethip4udp-ip4base-nat44-mrr
 116 | | [Tags] | 9000B | 2C
 117 | | framesize=${9000} | phy_cores=${2}
 118
 119 | tc09-9000B-4c-ethip4udp-ip4base-nat44-mrr
 120 | | [Tags] | 9000B | 4C
 121 | | framesize=${9000} | phy_cores=${4}
 122
 123 | tc10-IMIX-1c-ethip4udp-ip4base-nat44-mrr
 124 | | [Tags] | IMIX | 1C
 125 | | framesize=IMIX_v4_1 | phy_cores=${1}
 126
 127 | tc11-IMIX-2c-ethip4udp-ip4base-nat44-mrr
 128 | | [Tags] | IMIX | 2C
 129 | | framesize=IMIX_v4_1 | phy_cores=${2}
 130
 131 | tc12-IMIX-4c-ethip4udp-ip4base-nat44-mrr
 132 | | [Tags] | IMIX | 4C
 133 | | framesize=IMIX_v4_1 | phy_cores=${4}