tests/vpp/perf/ip4_tunnels/10ge2p1x520-ethip4lispip4-ip4base-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/overlay/lisp_static_adjacency.robot
  17 | Variables | resources/test_data/lisp/performance/lisp_static_adjacency.py
  18 | ...
  19 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  20 | ... | NIC_Intel-X520-DA2 | IP4FWD | ENCAP | LISP | IP4UNRLAY | IP4OVRLAY
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L3 | Intel-X520-DA2
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance mrr test
  29 | ...
  30 | Test Template | Local template
  31 | ...
  32 | Documentation | *Raw results Lisp test cases*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  35 | ... | with single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-LISP-IPv4 on DUT1-DUT2,\
  37 | ... | Eth-IPv4 on TG-DUTn for IPv4 routing over LISPoIPv4 tunnel.
  38 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4\
  39 | ... | routing and static routes. LISPoIPv4 tunnel is configured between DUT1\
  40 | ... | and DUT2. DUT1 and DUT2 tested with 2p10GE NIC X520 Niantic by Intel.
  41 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  42 | ... | at line rate and reports total received/sent packets over trial period.
  43 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  44 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  45 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  46 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  47 | ... | addresses of the TG node interfaces.
  48 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  49
  50 *** Variables ***
  51 # X520-DA2 bandwidth limit
  52 | ${s_limit}= | ${10000000000}
  53 | ${lisp_overhead}= | ${8}
  54 # Traffic profile:
  55 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src253
  56
  57 *** Keywords ***
  58 | Local template
  59 | | [Documentation]
  60 | | ... | [Cfg] DUT runs IPv4 LISP remote static mappings and whitelist filters\
  61 | | ... | config.
  62 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  63 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  64 | | ... | trial throughput test.
  65 | | ...
  66 | | ... | *Arguments:*
  67 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  68 | | ... | Type: integer, string
  69 | | ... | - phy_cores - Number of physical cores. Type: integer
  70 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  71 | | ...
  72 | | [Arguments] | ${phy_cores} | ${framesize} | ${rxq}=${None}
  73 | | ...
  74 | | # Test Variables required for test execution and test teardown
  75 | | Set Test Variable | ${framesize}
  76 | | ${get_framesize}= | Get Frame Size | ${framesize}
  77 | | ${max_rate}= | Calculate pps | ${s_limit}
  78 | | ... | ${get_framesize + ${lisp_overhead}}
  79 | | ...
  80 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  81 | | And Add PCI devices to all DUTs
  82 | | And Run Keyword If | ${get_framesize + ${lisp_overhead}} < ${1522}
  83 | | ... | Add no multi seg to all DUTs
  84 | | And Apply startup configuration on all VPP DUTs
  85 | | When Initialize LISP IPv4 forwarding in 3-node circular topology
  86 | | ... | ${dut1_to_dut2_ip4} | ${dut1_to_tg_ip4} | ${dut2_to_dut1_ip4}
  87 | | ... | ${dut2_to_tg_ip4} | ${prefix4}
  88 | | And Configure LISP topology in 3-node circular topology
  89 | | ... | ${dut1} | ${dut1_if2} | ${NONE}
  90 | | ... | ${dut2} | ${dut2_if1} | ${NONE}
  91 | | ... | ${duts_locator_set} | ${dut1_ip4_eid} | ${dut2_ip4_eid}
  92 | | ... | ${dut1_ip4_static_adjacency} | ${dut2_ip4_static_adjacency}
  93 | | Then Traffic should pass with maximum rate
  94 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  95
  96 *** Test Cases ***
  97 | tc01-64B-1t1c-ethip4lispip4-ip4base-mrr
  98 | | [Tags] | 64B | 1C
  99 | | phy_cores=${1} | framesize=${64}
 100
 101 | tc02-1480B-1t1c-ethip4lispip4-ip4base-mrr
 102 | | [Tags] | 1480B | 1C
 103 | | phy_cores=${1} | framesize=${1480}
 104
 105 | tc03-9000B-1t1c-ethip4lispip4-ip4base-mrr
 106 | | [Tags] | 9000B | 1C
 107 | | phy_cores=${1} | framesize=${9000}
 108
 109 | tc04-IMIX-1t1c-ethip4lispip4-ip4base-mrr
 110 | | [Tags] | IMIX | 1C
 111 | | phy_cores=${1} | framesize=IMIX_v4_1
 112
 113 | tc05-64B-2t2c-ethip4lispip4-ip4base-mrr
 114 | | [Tags] | 64B | 2C
 115 | | phy_cores=${2} | framesize=${64}
 116
 117 | tc06-1480B-2t2c-ethip4lispip4-ip4base-mrr
 118 | | [Tags] | 1480B | 2C
 119 | | phy_cores=${2} | framesize=${1480}
 120
 121 | tc07-9000B-2t2c-ethip4lispip4-ip4base-mrr
 122 | | [Tags] | 9000B | 2C
 123 | | phy_cores=${2} | framesize=${9000}
 124
 125 | tc08-IMIX-2t2c-ethip4lispip4-ip4base-mrr
 126 | | [Tags] | IMIX | 2C
 127 | | phy_cores=${2} | framesize=IMIX_v4_1
 128
 129 | tc09-64B-4t4c-ethip4lispip4-ip4base-mrr
 130 | | [Tags] | 64B | 4C
 131 | | phy_cores=${4} | framesize=${64}
 132
 133 | tc10-1480B-4t4c-ethip4lispip4-ip4base-mrr
 134 | | [Tags] | 1480B | 4C
 135 | | phy_cores=${4} | framesize=${1480}
 136
 137 | tc11-9000B-4t4c-ethip4lispip4-ip4base-mrr
 138 | | [Tags] | 9000B | 4C
 139 | | phy_cores=${4} | framesize=${9000}
 140
 141 | tc12-IMIX-4t4c-ethip4lispip4-ip4base-mrr
 142 | | [Tags] | IMIX | 4C
 143 | | phy_cores=${4} | framesize=IMIX_v4_1