tests/vpp/perf/ip4_tunnels/10ge2p1x520-ethip4lispip6-ip4base-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/overlay/lisp_static_adjacency.robot
  17 | Variables | resources/test_data/lisp/performance/lisp_static_adjacency.py
  18 | ...
  19 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  20 | ... | NIC_Intel-X520-DA2 | IP4FWD | ENCAP | LISP | IP6UNRLAY | IP4OVRLAY
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L3 | Intel-X520-DA2
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance mrr test
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *Raw results Lisp test cases*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  35 | ... | with single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-LISP-IPv6 on DUT1-DUT2,\
  37 | ... | Eth-IPv4 on TG-DUTn for IPv4 routing over LISPoIPv6 tunnel.
  38 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4\
  39 | ... | routing and static routes. LISPoIPv6 tunnel is configured between DUT1\
  40 | ... | and DUT2. DUT1 and DUT2 tested with 2p10GE NIC X520 Niantic by Intel.
  41 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  42 | ... | at line rate and reports total received/sent packets over trial period.
  43 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  44 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  45 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  46 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  47 | ... | addresses of the TG node interfaces.
  48 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  49
  50 *** Variables ***
  51 # X520-DA2 bandwidth limit
  52 | ${s_limit}= | ${10000000000}
  53 | ${overhead}= | ${48}
  54 # Traffic profile:
  55 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src253
  56
  57 *** Keywords ***
  58 | Local Template
  59 | | [Documentation]
  60 | | ... | [Cfg] DUT runs IPv6 LISP remote static mappings and whitelist filters\
  61 | | ... | config.
  62 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  63 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  64 | | ... | trial throughput test.
  65 | | ...
  66 | | ... | *Arguments:*
  67 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  68 | | ... | Type: integer, string
  69 | | ... | - phy_cores - Number of physical cores. Type: integer
  70 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  71 | | ...
  72 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  73 | | ...
  74 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  75 | | And Add PCI devices to all DUTs
  76 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  77 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  78 | | And Apply startup configuration on all VPP DUTs
  79 | | When Initialize LISP IPv4 over IPv6 forwarding in 3-node circular topology
  80 | | ... | ${dut1_to_dut2_ip4o6} | ${dut1_to_tg_ip4o6} | ${dut2_to_dut1_ip4o6}
  81 | | ... | ${dut2_to_tg_ip4o6} | ${tg_prefix4o6} | ${dut_prefix4o6}
  82 | | And Configure LISP topology in 3-node circular topology
  83 | | ... | ${dut1} | ${dut1_if2} | ${NONE}
  84 | | ... | ${dut2} | ${dut2_if1} | ${NONE}
  85 | | ... | ${duts_locator_set} | ${dut1_ip4o6_eid} | ${dut2_ip4o6_eid}
  86 | | ... | ${dut1_ip4o6_static_adjacency} | ${dut2_ip4o6_static_adjacency}
  87 | | Then Traffic should pass with maximum rate
  88 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  89
  90 *** Test Cases ***
  91 | tc01-64B-1c-ethip4lispip6-ip4base-mrr
  92 | | [Tags] | 64B | 1C
  93 | | framesize=${64} | phy_cores=${1}
  94
  95 | tc02-64B-2c-ethip4lispip6-ip4base-mrr
  96 | | [Tags] | 64B | 2C
  97 | | framesize=${64} | phy_cores=${2}
  98
  99 | tc03-64B-4c-ethip4lispip6-ip4base-mrr
 100 | | [Tags] | 64B | 4C
 101 | | framesize=${64} | phy_cores=${4}
 102
 103 | tc04-1518B-1c-ethip4lispip6-ip4base-mrr
 104 | | [Tags] | 1518B | 1C
 105 | | framesize=${1518} | phy_cores=${1}
 106
 107 | tc05-1518B-2c-ethip4lispip6-ip4base-mrr
 108 | | [Tags] | 1518B | 2C
 109 | | framesize=${1518} | phy_cores=${2}
 110
 111 | tc06-1518B-4c-ethip4lispip6-ip4base-mrr
 112 | | [Tags] | 1518B | 4C
 113 | | framesize=${1518} | phy_cores=${4}
 114
 115 | tc07-9000B-1c-ethip4lispip6-ip4base-mrr
 116 | | [Tags] | 9000B | 1C
 117 | | framesize=${9000} | phy_cores=${1}
 118
 119 | tc08-9000B-2c-ethip4lispip6-ip4base-mrr
 120 | | [Tags] | 9000B | 2C
 121 | | framesize=${9000} | phy_cores=${2}
 122
 123 | tc09-9000B-4c-ethip4lispip6-ip4base-mrr
 124 | | [Tags] | 9000B | 4C
 125 | | framesize=${9000} | phy_cores=${4}
 126
 127 | tc10-IMIX-1c-ethip4lispip6-ip4base-mrr
 128 | | [Tags] | IMIX | 1C
 129 | | framesize=IMIX_v4_1 | phy_cores=${1}
 130
 131 | tc11-IMIX-2c-ethip4lispip6-ip4base-mrr
 132 | | [Tags] | IMIX | 2C
 133 | | framesize=IMIX_v4_1 | phy_cores=${2}
 134
 135 | tc12-IMIX-4c-ethip4lispip6-ip4base-mrr
 136 | | [Tags] | IMIX | 4C
 137 | | framesize=IMIX_v4_1 | phy_cores=${4}