tests/vpp/perf/ip4_tunnels/10ge2p1x710-ethip4lispip4-ip4base-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/overlay/lisp_static_adjacency.robot
  17 | Variables | resources/test_data/lisp/performance/lisp_static_adjacency.py
  18 | ...
  19 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  20 | ... | NIC_Intel-X710 | IP4FWD | ENCAP | LISP | IP4UNRLAY | IP4OVRLAY
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L3 | Intel-X710
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  29 | ... | ${framesize} | ${traffic_profile}
  30 | ...
  31 | Test Template | Local Template
  32 | ...
  33 | Documentation | *RFC2544: Pkt throughput Lisp test cases*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-LISP-IPv4 on DUT1-DUT2,\
  38 | ... | Eth-IPv4 on TG-DUTn for IPv4 routing over LISPoIPv4 tunnel.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4\
  40 | ... | routing and static routes. LISPoIPv4 tunnel is configured between DUT1\
  41 | ... | and DUT2. DUT1 and DUT2 tested with 2p10GE NIC X710 by Intel.
  42 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  43 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  44 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  45 | ... | of packets transmitted. NDR and PDR are discovered for different
  46 | ... | Ethernet L2 frame sizes using MLRsearch library.
  47 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  48 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  49 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  50 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  51 | ... | addresses of the TG node interfaces.
  52 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  53
  54 *** Variables ***
  55 # X710 bandwidth limit
  56 | ${s_limit}= | ${10000000000}
  57 | ${overhead}= | ${8}
  58 # Traffic profile:
  59 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src253
  60
  61 *** Keywords ***
  62 | Local Template
  63 | | [Documentation]
  64 | | ... | [Cfg] DUT runs IPv4 LISP remote static mappings and whitelist filters\
  65 | | ... | config.
  66 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  67 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  68 | | ...
  69 | | ... | *Arguments:*
  70 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  71 | | ... | Type: integer, string
  72 | | ... | - phy_cores - Number of physical cores. Type: integer
  73 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  74 | | ...
  75 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  76 | | ...
  77 | | Set Test Variable | ${framesize}
  78 | | Set Test Variable | ${min_rate} | ${10000}
  79 | | ...
  80 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  81 | | And Add PCI devices to all DUTs
  82 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  83 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  84 | | And Apply startup configuration on all VPP DUTs
  85 | | When Initialize LISP IPv4 forwarding in 3-node circular topology
  86 | | ... | ${dut1_to_dut2_ip4} | ${dut1_to_tg_ip4} | ${dut2_to_dut1_ip4}
  87 | | ... | ${dut2_to_tg_ip4} | ${prefix4}
  88 | | And Configure LISP topology in 3-node circular topology
  89 | | ... | ${dut1} | ${dut1_if2} | ${NONE}
  90 | | ... | ${dut2} | ${dut2_if1} | ${NONE}
  91 | | ... | ${duts_locator_set} | ${dut1_ip4_eid} | ${dut2_ip4_eid}
  92 | | ... | ${dut1_ip4_static_adjacency} | ${dut2_ip4_static_adjacency}
  93 | | Then Find NDR and PDR intervals using optimized search
  94 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
  95
  96 *** Test Cases ***
  97 | tc01-64B-1c-ethip4lispip4-ip4base-ndrpdr
  98 | | [Tags] | 64B | 1C
  99 | | framesize=${64} | phy_cores=${1}
 100
 101 | tc02-64B-2c-ethip4lispip4-ip4base-ndrpdr
 102 | | [Tags] | 64B | 2C
 103 | | framesize=${64} | phy_cores=${2}
 104
 105 | tc03-64B-4c-ethip4lispip4-ip4base-ndrpdr
 106 | | [Tags] | 64B | 4C
 107 | | framesize=${64} | phy_cores=${4}
 108
 109 | tc04-1518B-1c-ethip4lispip4-ip4base-ndrpdr
 110 | | [Tags] | 1518B | 1C
 111 | | framesize=${1518} | phy_cores=${1}
 112
 113 | tc05-1518B-2c-ethip4lispip4-ip4base-ndrpdr
 114 | | [Tags] | 1518B | 2C
 115 | | framesize=${1518} | phy_cores=${2}
 116
 117 | tc06-1518B-4c-ethip4lispip4-ip4base-ndrpdr
 118 | | [Tags] | 1518B | 4C
 119 | | framesize=${1518} | phy_cores=${4}
 120
 121 | tc07-9000B-1c-ethip4lispip4-ip4base-ndrpdr
 122 | | [Tags] | 9000B | 1C
 123 | | framesize=${9000} | phy_cores=${1}
 124
 125 | tc08-9000B-2c-ethip4lispip4-ip4base-ndrpdr
 126 | | [Tags] | 9000B | 2C
 127 | | framesize=${9000} | phy_cores=${2}
 128
 129 | tc09-9000B-4c-ethip4lispip4-ip4base-ndrpdr
 130 | | [Tags] | 9000B | 4C
 131 | | framesize=${9000} | phy_cores=${4}
 132
 133 | tc10-IMIX-1c-ethip4lispip4-ip4base-ndrpdr
 134 | | [Tags] | IMIX | 1C
 135 | | framesize=IMIX_v4_1 | phy_cores=${1}
 136
 137 | tc11-IMIX-2c-ethip4lispip4-ip4base-ndrpdr
 138 | | [Tags] | IMIX | 2C
 139 | | framesize=IMIX_v4_1 | phy_cores=${2}
 140
 141 | tc12-IMIX-4c-ethip4lispip4-ip4base-ndrpdr
 142 | | [Tags] | IMIX | 4C
 143 | | framesize=IMIX_v4_1 | phy_cores=${4}