tests/vpp/perf/ip4_tunnels/10ge2p1x710-ethip4lispip4-ip4base-ndrpdr.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/overlay/lisp.robot
  17 |
  18 | Variables | resources/test_data/lisp/performance/lisp_static_adjacency.py
  19 |
  20 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  21 | ... | NIC_Intel-X710 | IP4FWD | ENCAP | LISP | IP4UNRLAY | IP4OVRLAY
  22 | ... | DRV_VFIO_PCI
  23 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  24 | ... | ethip4lispip4-ip4base
  25 |
  26 | Suite Setup | Setup suite topology interfaces | performance
  27 | Suite Teardown | Tear down suite | performance
  28 | Test Setup | Setup test | performance | performance
  29 | Test Teardown | Tear down test | performance
  30 |
  31 | Test Template | Local Template
  32 |
  33 | Documentation | *RFC2544: Pkt throughput Lisp test cases*
  34 |
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-LISP-IPv4 on DUT1-DUT2,\
  38 | ... | Eth-IPv4 on TG-DUTn for IPv4 routing over LISPoIPv4 tunnel.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4\
  40 | ... | routing and static routes. LISPoIPv4 tunnel is configured between DUT1\
  41 | ... | and DUT2. DUT1 and DUT2 tested with ${nic_name}.\
  42 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  43 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  44 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  45 | ... | of packets transmitted. NDR and PDR are discovered for different\
  46 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  47 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  48 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  49 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  50 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  51 | ... | addresses of the TG node interfaces.
  52 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  53
  54 *** Variables ***
  55 | @{plugins_to_enable}= | dpdk_plugin.so
  56 | ${crypto_type}= | ${None}
  57 | ${nic_name}= | Intel-X710
  58 | ${nic_driver}= | vfio-pci
  59 | ${nic_rxq_size}= | 0
  60 | ${nic_txq_size}= | 0
  61 | ${nic_pfs}= | 2
  62 | ${nic_vfs}= | 0
  63 | ${osi_layer}= | L3
  64 | ${overhead}= | ${8}
  65 # Traffic profile:
  66 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src253
  67
  68 *** Keywords ***
  69 | Local Template
  70 | | [Documentation]
  71 | | ... | [Cfg] DUT runs IPv4 LISP remote static mappings and whitelist filters\
  72 | | ... | config.
  73 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  74 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  75 | |
  76 | | ... | *Arguments:*
  77 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  78 | | ... | Type: integer, string
  79 | | ... | - phy_cores - Number of physical cores. Type: integer
  80 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  81 | |
  82 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  83 | |
  84 | | Set Test Variable | \${frame_size}
  85 | |
  86 | | Given Set Max Rate And Jumbo
  87 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  88 | | And Pre-initialize layer driver | ${nic_driver}
  89 | | And Apply startup configuration on all VPP DUTs
  90 | | When Initialize layer driver | ${nic_driver}
  91 | | And Initialize layer interface
  92 | | And Initialize LISP IPv4 forwarding in 3-node circular topology
  93 | | ... | ${dut1_to_dut2_ip4} | ${dut1_to_tg_ip4} | ${dut2_to_dut1_ip4}
  94 | | ... | ${dut2_to_tg_ip4} | ${prefix4}
  95 | | And Configure LISP topology in 3-node circular topology
  96 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${NONE}
  97 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${NONE}
  98 | | ... | ${duts_locator_set} | ${dut1_ip4_eid} | ${dut2_ip4_eid}
  99 | | ... | ${dut1_ip4_static_adjacency} | ${dut2_ip4_static_adjacency}
 100 | | Then Find NDR and PDR intervals using optimized search
 101
 102 *** Test Cases ***
 103 | 64B-1c-ethip4lispip4-ip4base-ndrpdr
 104 | | [Tags] | 64B | 1C
 105 | | frame_size=${64} | phy_cores=${1}
 106
 107 | 64B-2c-ethip4lispip4-ip4base-ndrpdr
 108 | | [Tags] | 64B | 2C
 109 | | frame_size=${64} | phy_cores=${2}
 110
 111 | 64B-4c-ethip4lispip4-ip4base-ndrpdr
 112 | | [Tags] | 64B | 4C
 113 | | frame_size=${64} | phy_cores=${4}
 114
 115 | 1518B-1c-ethip4lispip4-ip4base-ndrpdr
 116 | | [Tags] | 1518B | 1C
 117 | | frame_size=${1518} | phy_cores=${1}
 118
 119 | 1518B-2c-ethip4lispip4-ip4base-ndrpdr
 120 | | [Tags] | 1518B | 2C
 121 | | frame_size=${1518} | phy_cores=${2}
 122
 123 | 1518B-4c-ethip4lispip4-ip4base-ndrpdr
 124 | | [Tags] | 1518B | 4C
 125 | | frame_size=${1518} | phy_cores=${4}
 126
 127 | 9000B-1c-ethip4lispip4-ip4base-ndrpdr
 128 | | [Tags] | 9000B | 1C
 129 | | frame_size=${9000} | phy_cores=${1}
 130
 131 | 9000B-2c-ethip4lispip4-ip4base-ndrpdr
 132 | | [Tags] | 9000B | 2C
 133 | | frame_size=${9000} | phy_cores=${2}
 134
 135 | 9000B-4c-ethip4lispip4-ip4base-ndrpdr
 136 | | [Tags] | 9000B | 4C
 137 | | frame_size=${9000} | phy_cores=${4}
 138
 139 | IMIX-1c-ethip4lispip4-ip4base-ndrpdr
 140 | | [Tags] | IMIX | 1C
 141 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 142
 143 | IMIX-2c-ethip4lispip4-ip4base-ndrpdr
 144 | | [Tags] | IMIX | 2C
 145 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 146
 147 | IMIX-4c-ethip4lispip4-ip4base-ndrpdr
 148 | | [Tags] | IMIX | 4C
 149 | | frame_size=IMIX_v4_1 | phy_cores=${4}