tests/vpp/perf/ip6/10ge2p1x520-ethip6-ip6scale200k-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-X520-DA2 | ETH | IP6FWD | SCALE | FIB_200K
  19 | ...
  20 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  21 | ... | L3 | Intel-X520-DA2
  22 | Suite Teardown | Tear down 3-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | ...
  26 | Test Teardown | Tear down performance mrr test
  27 | ...
  28 | Test Template | Local template
  29 | ...
  30 | Documentation | *Raw results IPv6 routing test cases*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6 for IPv6 routing.
  35 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6
  36 | ... | routing and 2x100k static IPv6 /64 route entries. DUT1 and DUT2 tested
  37 | ... | with 2p10GE NIC X520 Niantic by Intel.
  38 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic\
  39 | ... | at line rate and reports total received/sent packets over trial period.\
  40 | ... | Test packets are generated by TG on
  41 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  42 | ... | (flow-group per direction, 100k flows per flow-group) with all packets
  43 | ... | containing Ethernet header, IPv6 header withq IP and static payload.
  44 | ... | MAC addresses are matching MAC addresses of the TG node interfaces.
  45 | ... | Incrementing of IP.dst (IPv6 destination address) field is applied to
  46 | ... | both streams.
  47 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  48
  49 *** Variables ***
  50 # X520-DA2 bandwidth limit
  51 | ${s_limit} | ${10000000000}
  52 | ${rts_per_flow}= | ${100000}
  53 # Traffic profile:
  54 | ${traffic_profile} | trex-sl-3n-ethip6-ip6dst${rts_per_flow}
  55
  56 *** Keywords ***
  57 | Local template
  58 | | [Documentation]
  59 | | ... | [Cfg] DUT runs IPv6 routing config.
  60 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  61 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  62 | | ... | trial throughput test.
  63 | | ...
  64 | | ... | *Arguments:*
  65 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  66 | | ... | Type: integer, string
  67 | | ... | - phy_cores - Number of physical cores. Type: integer
  68 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  69 | | ...
  70 | | [Arguments] | ${phy_cores} | ${framesize} | ${rxq}=${None}
  71 | | ...
  72 | | Set Test Variable | ${framesize}
  73 | | ${get_framesize}= | Get Frame Size | ${framesize}
  74 | | ${max_rate}= | Calculate pps | ${s_limit} | ${get_framesize}
  75 | | ...
  76 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  77 | | And Add PCI devices to all DUTs
  78 | | And Run Keyword If | ${get_framesize} < ${1522}
  79 | | ... | Add no multi seg to all DUTs
  80 | | And Apply startup configuration on all VPP DUTs
  81 | | When Initialize IPv6 forwarding with scaling in 3-node circular topology
  82 | | ... | ${rts_per_flow}
  83 | | Then Traffic should pass with maximum rate
  84 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  85
  86 *** Test Cases ***
  87 | tc01-78B-1t1c-ethip6-ip6base-ip6scale200k-mrr
  88 | | [Tags] | 78B | 1C
  89 | | phy_cores=${1} | framesize=${78}
  90
  91 | tc02-1518B-1t1c-ethip6-ip6base-ip6scale200k-mrr
  92 | | [Tags] | 1518B | 1C
  93 | | phy_cores=${1} | framesize=${1518}
  94
  95 | tc03-9000B-1t1c-ethip6-ip6base-ip6scale200k-mrr
  96 | | [Tags] | 9000B | 1C
  97 | | phy_cores=${1} | framesize=${9000}
  98
  99 | tc04-IMIX-1t1c-ethip6-ip6base-ip6scale200k-mrr
 100 | | [Tags] | IMIX | 1C
 101 | | phy_cores=${1} | framesize=IMIX_v4_1
 102
 103 | tc05-78B-2t2c-ethip6-ip6base-ip6scale200k-mrr
 104 | | [Tags] | 78B | 2C
 105 | | phy_cores=${2} | framesize=${78}
 106
 107 | tc06-1518B-2t2c-ethip6-ip6base-ip6scale200k-mrr
 108 | | [Tags] | 1518B | 2C
 109 | | phy_cores=${2} | framesize=${1518}
 110
 111 | tc07-9000B-2t2c-ethip6-ip6base-ip6scale200k-mrr
 112 | | [Tags] | 9000B | 2C
 113 | | phy_cores=${2} | framesize=${9000}
 114
 115 | tc08-IMIX-2t2c-ethip6-ip6base-ip6scale200k-mrr
 116 | | [Tags] | IMIX | 2C
 117 | | phy_cores=${2} | framesize=IMIX_v4_1
 118
 119 | tc09-78B-4t4c-ethip6-ip6base-ip6scale200k-mrr
 120 | | [Tags] | 78B | 4C
 121 | | phy_cores=${4} | framesize=${78}
 122
 123 | tc10-1518B-4t4c-ethip6-ip6base-ip6scale200k-mrr
 124 | | [Tags] | 1518B | 4C
 125 | | phy_cores=${4} | framesize=${1518}
 126
 127 | tc11-9000B-4t4c-ethip6-ip6base-ip6scale200k-mrr
 128 | | [Tags] | 9000B | 4C
 129 | | phy_cores=${4} | framesize=${9000}
 130
 131 | tc12-IMIX-4t4c-ethip6-ip6base-ip6scale200k-mrr
 132 | | [Tags] | IMIX | 4C
 133 | | phy_cores=${4} | framesize=IMIX_v4_1