tests/vpp/perf/ip6/10ge2p1x710-dot1q-ip6base-ndrpdr.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | IP6FWD | BASE | DOT1Q | IP6BASE | DRV_VFIO_PCI
  19 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  20 | ... | dot1q-ip6base
  21 |
  22 | Suite Setup | Setup suite topology interfaces | performance
  23 | Suite Teardown | Tear down suite | performance
  24 | Test Setup | Setup test | performance | performance
  25 | Test Teardown | Tear down test | performance
  26 |
  27 | Test Template | Local Template
  28 |
  29 | Documentation | *RFC2544: Pkt throughput IPv6 routing with IEEE 802.1Q test
  30 | ... | cases*
  31 |
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6 for IPv6 routing. IEEE 802.1Q\
  35 | ... | tagging is applied on link between DUT1 and DUT2.
  36 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
  37 | ... | routing and two static IPv6 /64 route entries. DUT1 and DUT2 are tested\
  38 | ... | with ${nic_name}.\
  39 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  40 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  41 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  42 | ... | of packets transmitted. NDR and PDR are discovered for different\
  43 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  44 | ... | Test packets are\
  45 | ... | generated by TG on links to DUTs. TG traffic profile contains two L3\
  46 | ... | flow-groups (flow-group per direction, 253 flows per flow-group) with\
  47 | ... | all packets containing Ethernet header, IPv6 header with IP\
  48 | ... | protocol=61 and static payload. MAC addresses are matching MAC\
  49 | ... | addresses of the TG node interfaces.
  50 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  51
  52 *** Variables ***
  53 | @{plugins_to_enable}= | dpdk_plugin.so
  54 | ${crypto_type}= | ${None}
  55 | ${nic_name}= | Intel-X710
  56 | ${nic_driver}= | vfio-pci
  57 | ${nic_rxq_size}= | 0
  58 | ${nic_txq_size}= | 0
  59 | ${nic_pfs}= | 2
  60 | ${nic_vfs}= | 0
  61 | ${osi_layer}= | L3
  62 | ${overhead}= | ${4}
  63 | ${subid}= | 10
  64 | ${tag_rewrite}= | pop-1
  65 # TG subnets used by T-Rex
  66 | ${tg_if1_net}= | 2001:1::0
  67 | ${tg_if2_net}= | 2001:2::0
  68 # Traffic profile:
  69 | ${traffic_profile}= | trex-sl-3n-ethip6-ip6src253
  70
  71 *** Keywords ***
  72 | Local Template
  73 | | [Documentation]
  74 | | ... | [Cfg] Each DUT runs IPv6 routing with VLAN and uses ${phy_cores}\
  75 | | ... | physical core(s) for worker threads.
  76 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  77 | |
  78 | | ... | *Arguments:*
  79 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  80 | | ... | Type: integer, string
  81 | | ... | - phy_cores - Number of physical cores. Type: integer
  82 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  83 | |
  84 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  85 | |
  86 | | Set Test Variable | \${frame_size}
  87 | |
  88 | | Given Set Max Rate And Jumbo
  89 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  90 | | And Pre-initialize layer driver | ${nic_driver}
  91 | | And Apply startup configuration on all VPP DUTs
  92 | | When Initialize layer driver | ${nic_driver}
  93 | | And Initialize layer interface
  94 | | And Initialize IPv6 forwarding with VLAN dot1q sub-interfaces in circular topology
  95 | | ... | ${tg_if1_net} | ${tg_if2_net} | ${subid} | ${tag_rewrite}
  96 | | Then Find NDR and PDR intervals using optimized search
  97
  98 *** Test Cases ***
  99 | 78B-1c-dot1q-ip6base-ndrpdr
 100 | | [Tags] | 78B | 1C
 101 | | frame_size=${78} | phy_cores=${1}
 102
 103 | 78B-2c-dot1q-ip6base-ndrpdr
 104 | | [Tags] | 78B | 2C
 105 | | frame_size=${78} | phy_cores=${2}
 106
 107 | 78B-4c-dot1q-ip6base-ndrpdr
 108 | | [Tags] | 78B | 4C
 109 | | frame_size=${78} | phy_cores=${4}
 110
 111 | 1518B-1c-dot1q-ip6base-ndrpdr
 112 | | [Tags] | 1518B | 1C
 113 | | frame_size=${1518} | phy_cores=${1}
 114
 115 | 1518B-2c-dot1q-ip6base-ndrpdr
 116 | | [Tags] | 1518B | 2C
 117 | | frame_size=${1518} | phy_cores=${2}
 118
 119 | 1518B-4c-dot1q-ip6base-ndrpdr
 120 | | [Tags] | 1518B | 4C
 121 | | frame_size=${1518} | phy_cores=${4}
 122
 123 | 9000B-1c-dot1q-ip6base-ndrpdr
 124 | | [Tags] | 9000B | 1C
 125 | | frame_size=${9000} | phy_cores=${1}
 126
 127 | 9000B-2c-dot1q-ip6base-ndrpdr
 128 | | [Tags] | 9000B | 2C
 129 | | frame_size=${9000} | phy_cores=${2}
 130
 131 | 9000B-4c-dot1q-ip6base-ndrpdr
 132 | | [Tags] | 9000B | 4C
 133 | | frame_size=${9000} | phy_cores=${4}
 134
 135 | IMIX-1c-dot1q-ip6base-ndrpdr
 136 | | [Tags] | IMIX | 1C
 137 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 138
 139 | IMIX-2c-dot1q-ip6base-ndrpdr
 140 | | [Tags] | IMIX | 2C
 141 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 142
 143 | IMIX-4c-dot1q-ip6base-ndrpdr
 144 | | [Tags] | IMIX | 4C
 145 | | frame_size=IMIX_v4_1 | phy_cores=${4}