tests/vpp/perf/ip6/10ge2p1x710-ethip6-ip6base-copwhtlistbase-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.Cop
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | NIC_Intel-X710 | ETH | IP6FWD | FEATURE | COPWHLIST
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L3 | Intel-X710
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | ...
  27 | Test Teardown | Tear down performance mrr test
  28 | ...
  29 | Test Template | Local Template
  30 | ...
  31 | Documentation | *Raw results IPv6 whitelist test cases*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6 for IPv6 routing.
  36 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6
  37 | ... | routing, two static IPv6 /64 routes and IPv6 COP security whitelist
  38 | ... | ingress /64 filter entries applied on links TG - DUT1 and DUT2 - TG.
  39 | ... | DUT1 and DUT2 tested with 2p10GE NIC X710 by Intel.
  40 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic\
  41 | ... | at line rate and reports total received/sent packets over trial period.\
  42 | ... | Test packets are generated by TG on
  43 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  44 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  45 | ... | containing Ethernet header, IPv6 header and static
  46 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  47 | ... | interfaces.
  48 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  49
  50 *** Variables ***
  51 # X710-DA2 bandwidth limit
  52 | ${s_limit}= | ${10000000000}
  53 # Traffic profile:
  54 | ${traffic_profile}= | trex-sl-3n-ethip6-ip6src253
  55
  56 *** Keywords ***
  57 | Local Template
  58 | | [Documentation]
  59 | | ... | [Cfg] DUT runs IPv6 routing and whitelist filters config with
  60 | | ... | ${phy_cores} phy core(s).
  61 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  62 | | ... | trial throughput test.
  63 | | ...
  64 | | ... | *Arguments:*
  65 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  66 | | ... | Type: integer, string
  67 | | ... | - phy_cores - Number of physical cores. Type: integer
  68 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  69 | | ...
  70 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  71 | | ...
  72 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  73 | | And Add PCI devices to all DUTs
  74 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  75 | | ... | ${s_limit} | ${framesize}
  76 | | And Apply startup configuration on all VPP DUTs
  77 | | When Initialize IPv6 forwarding in 3-node circular topology
  78 | | And Add Fib Table | ${dut1} | 1 | ipv6=${TRUE}
  79 | | And Vpp Route Add | ${dut1} | 2001:1:: | 64 | vrf=1 | local=${TRUE}
  80 | | And Add Fib Table | ${dut2} | 1 | ipv6=${TRUE}
  81 | | And Vpp Route Add | ${dut2} | 2001:2:: | 64 | vrf=1 | local=${TRUE}
  82 | | And COP Add whitelist Entry | ${dut1} | ${dut1_if1} | ip6 | 1
  83 | | And COP Add whitelist Entry | ${dut2} | ${dut2_if2} | ip6 | 1
  84 | | And COP interface enable or disable | ${dut1} | ${dut1_if1} | enable
  85 | | And COP interface enable or disable | ${dut2} | ${dut2_if2} | enable
  86 | | Then Traffic should pass with maximum rate
  87 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  88
  89 *** Test Cases ***
  90 | tc01-78B-1c-ethip6-ip6base-copwhtlistbase-mrr
  91 | | [Tags] | 78B | 1C
  92 | | framesize=${78} | phy_cores=${1}
  93
  94 | tc02-78B-2c-ethip6-ip6base-copwhtlistbase-mrr
  95 | | [Tags] | 78B | 2C
  96 | | framesize=${78} | phy_cores=${2}
  97
  98 | tc03-78B-4c-ethip6-ip6base-copwhtlistbase-mrr
  99 | | [Tags] | 78B | 4C
 100 | | framesize=${78} | phy_cores=${4}
 101
 102 | tc04-1518B-1c-ethip6-ip6base-copwhtlistbase-mrr
 103 | | [Tags] | 1518B | 1C
 104 | | framesize=${1518} | phy_cores=${1}
 105
 106 | tc05-1518B-2c-ethip6-ip6base-copwhtlistbase-mrr
 107 | | [Tags] | 1518B | 2C
 108 | | framesize=${1518} | phy_cores=${2}
 109
 110 | tc06-1518B-4c-ethip6-ip6base-copwhtlistbase-mrr
 111 | | [Tags] | 1518B | 4C
 112 | | framesize=${1518} | phy_cores=${4}
 113
 114 | tc07-9000B-1c-ethip6-ip6base-copwhtlistbase-mrr
 115 | | [Tags] | 9000B | 1C
 116 | | framesize=${9000} | phy_cores=${1}
 117
 118 | tc08-9000B-2c-ethip6-ip6base-copwhtlistbase-mrr
 119 | | [Tags] | 9000B | 2C
 120 | | framesize=${9000} | phy_cores=${2}
 121
 122 | tc09-9000B-4c-ethip6-ip6base-copwhtlistbase-mrr
 123 | | [Tags] | 9000B | 4C
 124 | | framesize=${9000} | phy_cores=${4}
 125
 126 | tc10-IMIX-1c-ethip6-ip6base-copwhtlistbase-mrr
 127 | | [Tags] | IMIX | 1C
 128 | | framesize=IMIX_v4_1 | phy_cores=${1}
 129
 130 | tc11-IMIX-2c-ethip6-ip6base-copwhtlistbase-mrr
 131 | | [Tags] | IMIX | 2C
 132 | | framesize=IMIX_v4_1 | phy_cores=${2}
 133
 134 | tc12-IMIX-4c-ethip6-ip6base-copwhtlistbase-mrr
 135 | | [Tags] | IMIX | 4C
 136 | | framesize=IMIX_v4_1 | phy_cores=${4}