tests/vpp/perf/ip6/40ge2p1xl710-ethip6-ip6base-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-XL710 | ETH | IP6FWD | BASE
  19 | ...
  20 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  21 | ... | L3 | Intel-XL710
  22 | Suite Teardown | Tear down 3-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | ...
  26 | Test Teardown | Tear down performance mrr test
  27 | ...
  28 | Test Template | Local template
  29 | ...
  30 | Documentation | *Raw results IPv6 routing test cases*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6 for IPv6 routing.
  35 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6
  36 | ... | routing and two static IPv6 /64 route entries. DUT1 and DUT2 tested with
  37 | ... | 2p40GE NIC XL710 by Intel.
  38 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  39 | ... | at line rate and reports total received/sent packets over trial period.
  40 | ... | Test packets are generated by TG on
  41 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  42 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  43 | ... | containing Ethernet header, IPv6 header and static payload.
  44 | ... | MAC addresses are matching MAC addresses of the TG node interfaces.
  45 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  46
  47 *** Variables ***
  48 # XL710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  49 | ${s_24.5G} | ${24500000000}
  50 # XL710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  51 | ${s_18.75Mpps} | ${18750000}
  52 # Traffic profile:
  53 | ${traffic_profile} | trex-sl-3n-ethip6-ip6src253
  54
  55 *** Keywords ***
  56 | Local template
  57 | | [Documentation]
  58 | | ... | [Cfg] DUT runs IPv6 routing config.
  59 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  60 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  61 | | ... | trial throughput test.
  62 | | ...
  63 | | ... | *Arguments:*
  64 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  65 | | ... | Type: integer, string
  66 | | ... | - phy_cores - Number of physical cores. Type: integer
  67 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  68 | | ...
  69 | | [Arguments] | ${phy_cores} | ${framesize} | ${rxq}=${None}
  70 | | ...
  71 | | Set Test Variable | ${framesize}
  72 | | ${get_framesize}= | Get Frame Size | ${framesize}
  73 | | ${max_rate}= | Calculate pps | ${s_24.5G} | ${get_framesize}
  74 | | ${max_rate}= | Set Variable If
  75 | | ... | ${max_rate} > ${s_18.75Mpps} | ${s_18.75Mpps} | ${max_rate}
  76 | | ...
  77 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  78 | | And Add PCI devices to all DUTs
  79 | | And Run Keyword If | ${get_framesize} < ${1522}
  80 | | ... | Add no multi seg to all DUTs
  81 | | And Add DPDK dev default RXD to all DUTs | 2048
  82 | | And Add DPDK dev default TXD to all DUTs | 2048
  83 | | And Apply startup configuration on all VPP DUTs
  84 | | And Initialize IPv6 forwarding in 3-node circular topology
  85 | | Then Traffic should pass with maximum rate
  86 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  87
  88 *** Test Cases ***
  89 | tc01-78B-1t1c-ethip6-ip6base-mrr
  90 | | [Tags] | 78B | 1C
  91 | | framesize=${78} | phy_cores=${1}
  92
  93 | tc02-1518B-1t1c-ethip6-ip6base-mrr
  94 | | [Tags] | 1518B | 1C
  95 | | framesize=${1518} | phy_cores=${1}
  96
  97 | tc03-9000B-1t1c-ethip6-ip6base-mrr
  98 | | [Tags] | 9000B | 1C
  99 | | framesize=${9000} | phy_cores=${1}
 100
 101 | tc04-IMIX-1t1c-ethip6-ip6base-mrr
 102 | | [Tags] | IMIX | 1C
 103 | | framesize=IMIX_v4_1 | phy_cores=${1}
 104
 105 | tc05-78B-2t2c-ethip6-ip6base-mrr
 106 | | [Tags] | 78B | 2C
 107 | | framesize=${78} | phy_cores=${2}
 108
 109 | tc06-1518B-2t2c-ethip6-ip6base-mrr
 110 | | [Tags] | 1518B | 2C
 111 | | framesize=${1518} | phy_cores=${2}
 112
 113 | tc07-9000B-2t2c-ethip6-ip6base-mrr
 114 | | [Tags] | 9000B | 2C
 115 | | framesize=${9000} | phy_cores=${2}
 116
 117 | tc08-IMIX-2t2c-ethip6-ip6base-mrr
 118 | | [Tags] | IMIX | 2C
 119 | | framesize=IMIX_v4_1 | phy_cores=${2}
 120
 121 | tc09-78B-4t4c-ethip6-ip6base-mrr
 122 | | [Tags] | 78B | 4C
 123 | | framesize=${78} | phy_cores=${4}
 124
 125 | tc10-1518B-4t4c-ethip6-ip6base-mrr
 126 | | [Tags] | 1518B | 4C
 127 | | framesize=${1518} | phy_cores=${4}
 128
 129 | tc11-9000B-4t4c-ethip6-ip6base-mrr
 130 | | [Tags] | 9000B | 4C
 131 | | framesize=${9000} | phy_cores=${4}
 132
 133 | tc12-IMIX-4t4c-ethip6-ip6base-mrr
 134 | | [Tags] | IMIX | 4C
 135 | | framesize=IMIX_v4_1 | phy_cores=${4}