tests/vpp/perf/ip6_tunnels/10ge2p1x520-ethip6lispip6-ip6base-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/overlay/lisp_static_adjacency.robot
  17 | Variables | resources/test_data/lisp/performance/lisp_static_adjacency.py
  18 | ...
  19 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  20 | ... | NIC_Intel-X520-DA2 | IP6FWD | ENCAP | LISP | IP6UNRLAY | IP6OVRLAY
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L3 | Intel-X520-DA2
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance mrr test
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *RFC6830: Pkt throughput Lisp test cases*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  35 | ... | with single links between nodes.\
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISP-IPv6 on DUT1-DUT2,\
  37 | ... | Eth-IPv6 on TG-DUTn for IPv6 routing over LISPoIPv6 tunnel.\
  38 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
  39 | ... | routing and static routes. LISPoIPv6 tunnel is configured between\
  40 | ... | DUT1 and DUT2. DUT1 and DUT2 tested with 2p10GE NIC X520 Niantic\
  41 | ... | by Intel.\
  42 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic\
  43 | ... | at line rate and reports total received/sent packets over trial period.\
  44 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  45
  46 *** Variables ***
  47 # X520-DA2 bandwidth limit
  48 | ${s_limit}= | ${10000000000}
  49 # LISP overhead
  50 | ${overhead}= | 8
  51 # Traffic profile:
  52 | ${traffic_profile}= | trex-sl-3n-ethip6-ip6src253
  53
  54 *** Keywords ***
  55 | Local Template
  56 | | [Documentation]
  57 | | ... | [Cfg] DUT runs IPv6 LISP remote static mappings and whitelist\
  58 | | ... | filters config.\
  59 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.\
  60 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  61 | | ... | trial throughput test.\
  62 | | ...
  63 | | ... | *Arguments:*
  64 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  65 | | ... |   Type: integer, string
  66 | | ... | - phy_cores - Number of physical cores. Type: integer
  67 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  68 | | ...
  69 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  70 | | ...
  71 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  72 | | And Add PCI devices to all DUTs
  73 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  74 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  75 | | And Apply startup configuration on all VPP DUTs
  76 | | When Initialize LISP IPv6 forwarding in 3-node circular topology
  77 | | ... | ${dut1_to_dut2_ip6} | ${dut1_to_tg_ip6} | ${dut2_to_dut1_ip6}
  78 | | ... | ${dut2_to_tg_ip6} | ${prefix6}
  79 | | And Configure LISP topology in 3-node circular topology
  80 | | ... | ${dut1} | ${dut1_if2} | ${NONE}
  81 | | ... | ${dut2} | ${dut2_if1} | ${NONE}
  82 | | ... | ${duts_locator_set} | ${dut1_ip6_eid} | ${dut2_ip6_eid}
  83 | | ... | ${dut1_ip6_static_adjacency} | ${dut2_ip6_static_adjacency}
  84 | | Then Traffic should pass with maximum rate
  85 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  86
  87 *** Test Cases ***
  88 | tc01-78B-1c-ethip6lispip6-ip6base-mrr
  89 | | [Tags] | 78B | 1C
  90 | | framesize=${78} | phy_cores=${1}
  91
  92 | tc02-78B-2c-ethip6lispip6-ip6base-mrr
  93 | | [Tags] | 78B | 2C
  94 | | framesize=${78} | phy_cores=${2}
  95
  96 | tc03-78B-4c-ethip6lispip6-ip6base-mrr
  97 | | [Tags] | 78B | 4C
  98 | | framesize=${78} | phy_cores=${4}
  99
 100 | tc04-1518B-1c-ethip6lispip6-ip6base-mrr
 101 | | [Tags] | 1518B | 1C
 102 | | framesize=${1518} | phy_cores=${1}
 103
 104 | tc05-1518B-2c-ethip6lispip6-ip6base-mrr
 105 | | [Tags] | 1518B | 2C
 106 | | framesize=${1518} | phy_cores=${2}
 107
 108 | tc06-1518B-4c-ethip6lispip6-ip6base-mrr
 109 | | [Tags] | 1518B | 4C
 110 | | framesize=${1518} | phy_cores=${4}
 111
 112 | tc07-9000B-1c-ethip6lispip6-ip6base-mrr
 113 | | [Tags] | 9000B | 1C
 114 | | framesize=${9000} | phy_cores=${1}
 115
 116 | tc08-9000B-2c-ethip6lispip6-ip6base-mrr
 117 | | [Tags] | 9000B | 2C
 118 | | framesize=${9000} | phy_cores=${2}
 119
 120 | tc09-9000B-4c-ethip6lispip6-ip6base-mrr
 121 | | [Tags] | 9000B | 4C
 122 | | framesize=${9000} | phy_cores=${4}
 123
 124 | tc10-IMIX-1c-ethip6lispip6-ip6base-mrr
 125 | | [Tags] | IMIX | 1C
 126 | | framesize=IMIX_v4_1 | phy_cores=${1}
 127
 128 | tc11-IMIX-2c-ethip6lispip6-ip6base-mrr
 129 | | [Tags] | IMIX | 2C
 130 | | framesize=IMIX_v4_1 | phy_cores=${2}
 131
 132 | tc12-IMIX-4c-ethip6lispip6-ip6base-mrr
 133 | | [Tags] | IMIX | 4C
 134 | | framesize=IMIX_v4_1 | phy_cores=${4}