tests/vpp/perf/ip6_tunnels/10ge2p1x520-ethip6lispip6-ip6base-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/overlay/lisp_static_adjacency.robot
  17 | Variables | resources/test_data/lisp/performance/lisp_static_adjacency.py
  18 | ...
  19 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  20 | ... | NIC_Intel-X520-DA2 | IP6FWD | ENCAP | LISP | IP6UNRLAY | IP6OVRLAY
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L3 | Intel-X520-DA2
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  29 | ... | ${framesize} | ${traffic_profile}
  30 | ...
  31 | Test Template | Local Template
  32 | ...
  33 | Documentation | *RFC6830: Pkt throughput Lisp test cases*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  36 | ... | with single links between nodes.\
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISP-IPv6 on DUT1-DUT2,\
  38 | ... | Eth-IPv6 on TG-DUTn for IPv6 routing over LISPoIPv6 tunnel.\
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
  40 | ... | routing and static routes. LISPoIPv6 tunnel is configured between\
  41 | ... | DUT1 and DUT2. DUT1 and DUT2 tested with 2p10GE NIC X520 Niantic\
  42 | ... | by Intel.\
  43 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  44 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  45 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  46 | ... | of packets transmitted. NDR and PDR are discovered for different\
  47 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  48 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  49
  50 *** Variables ***
  51 # X520-DA2 bandwidth limit
  52 | ${s_limit}= | ${10000000000}
  53 # LISP overhead.
  54 | ${overhead}= | 8
  55 # Traffic profile:
  56 | ${traffic_profile}= | trex-sl-3n-ethip6-ip6src253
  57
  58 *** Keywords ***
  59 | Local Template
  60 | | [Documentation]
  61 | | ... | [Cfg] DUT runs IPv6 LISP remote static mappings and whitelist\
  62 | | ... | filters config.\
  63 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.\
  64 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  65 | | ...
  66 | | ... | *Arguments:*
  67 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  68 | | ... |   Type: integer, string
  69 | | ... | - phy_cores - Number of physical cores. Type: integer
  70 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  71 | | ...
  72 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  73 | | ...
  74 | | Set Test Variable | ${framesize}
  75 | | Set Test Variable | ${min_rate} | ${10000}
  76 | | ...
  77 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  78 | | And Add PCI devices to all DUTs
  79 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  80 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  81 | | And Apply startup configuration on all VPP DUTs
  82 | | When Initialize LISP IPv6 forwarding in 3-node circular topology
  83 | | ... | ${dut1_to_dut2_ip6} | ${dut1_to_tg_ip6} | ${dut2_to_dut1_ip6}
  84 | | ... | ${dut2_to_tg_ip6} | ${prefix6}
  85 | | And Configure LISP topology in 3-node circular topology
  86 | | ... | ${dut1} | ${dut1_if2} | ${NONE}
  87 | | ... | ${dut2} | ${dut2_if1} | ${NONE}
  88 | | ... | ${duts_locator_set} | ${dut1_ip6_eid} | ${dut2_ip6_eid}
  89 | | ... | ${dut1_ip6_static_adjacency} | ${dut2_ip6_static_adjacency}
  90 | | Then Find NDR and PDR intervals using optimized search
  91 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
  92
  93 *** Test Cases ***
  94 | tc01-78B-1c-ethip6lispip6-ip6base-ndrpdr
  95 | | [Tags] | 78B | 1C
  96 | | framesize=${78} | phy_cores=${1}
  97
  98 | tc02-78B-2c-ethip6lispip6-ip6base-ndrpdr
  99 | | [Tags] | 78B | 2C
 100 | | framesize=${78} | phy_cores=${2}
 101
 102 | tc03-78B-4c-ethip6lispip6-ip6base-ndrpdr
 103 | | [Tags] | 78B | 4C
 104 | | framesize=${78} | phy_cores=${4}
 105
 106 | tc04-1518B-1c-ethip6lispip6-ip6base-ndrpdr
 107 | | [Tags] | 1518B | 1C
 108 | | framesize=${1518} | phy_cores=${1}
 109
 110 | tc05-1518B-2c-ethip6lispip6-ip6base-ndrpdr
 111 | | [Tags] | 1518B | 2C
 112 | | framesize=${1518} | phy_cores=${2}
 113
 114 | tc06-1518B-4c-ethip6lispip6-ip6base-ndrpdr
 115 | | [Tags] | 1518B | 4C
 116 | | framesize=${1518} | phy_cores=${4}
 117
 118 | tc07-9000B-1c-ethip6lispip6-ip6base-ndrpdr
 119 | | [Tags] | 9000B | 1C
 120 | | framesize=${9000} | phy_cores=${1}
 121
 122 | tc08-9000B-2c-ethip6lispip6-ip6base-ndrpdr
 123 | | [Tags] | 9000B | 2C
 124 | | framesize=${9000} | phy_cores=${2}
 125
 126 | tc09-9000B-4c-ethip6lispip6-ip6base-ndrpdr
 127 | | [Tags] | 9000B | 4C
 128 | | framesize=${9000} | phy_cores=${4}
 129
 130 | tc10-IMIX-1c-ethip6lispip6-ip6base-ndrpdr
 131 | | [Tags] | IMIX | 1C
 132 | | framesize=IMIX_v4_1 | phy_cores=${1}
 133
 134 | tc11-IMIX-2c-ethip6lispip6-ip6base-ndrpdr
 135 | | [Tags] | IMIX | 2C
 136 | | framesize=IMIX_v4_1 | phy_cores=${2}
 137
 138 | tc12-IMIX-4c-ethip6lispip6-ip6base-ndrpdr
 139 | | [Tags] | IMIX | 4C
 140 | | framesize=IMIX_v4_1 | phy_cores=${4}