tests/vpp/perf/ip6_tunnels/10ge2p1x710-ethip6lispip4-ip6base-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/overlay/lisp_static_adjacency.robot
  17 | Variables | resources/test_data/lisp/performance/lisp_static_adjacency.py
  18 | ...
  19 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  20 | ... | NIC_Intel-X710 | IP6FWD | ENCAP | LISP | IP4UNRLAY | IP6OVRLAY
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L3 | ${nic_name}
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance test
  28 | ...
  29 | Test Template | Local Template
  30 | ...
  31 | Documentation | *RFC6830: Pkt throughput Lisp test cases*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  34 | ... | with single links between nodes.\
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISP-IPv4 on DUT1-DUT2,\
  36 | ... | Eth-IPv6 on TG-DUTn for IPv6 routing over LISPoIPv4 tunnel.\
  37 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
  38 | ... | routing and static routes. LISPoIPv4 tunnel is configured between\
  39 | ... | DUT1 and DUT2. DUT1 and DUT2 tested with ${nic_name}.\
  40 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  41 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  42 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  43 | ... | of packets transmitted. NDR and PDR are discovered for different\
  44 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  45 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  46
  47 *** Variables ***
  48 | ${nic_name}= | Intel-X710
  49 # LISP overhead
  50 | ${overhead}= | 48
  51 # Traffic profile:
  52 | ${traffic_profile}= | trex-sl-3n-ethip6-ip6src253
  53
  54 *** Keywords ***
  55 | Local Template
  56 | | [Documentation]
  57 | | ... | [Cfg] DUT runs IPv6 LISP remote static mappings and whitelist\
  58 | | ... | filters config.\
  59 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.\
  60 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  61 | | ...
  62 | | ... | *Arguments:*
  63 | | ... | - frame_size - Frame size in Bytes as integer or string (IMIX_v4_1).
  64 | | ... |   Type: integer, string
  65 | | ... | - phy_cores - Number of physical cores. Type: integer
  66 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  67 | | ...
  68 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  69 | | ...
  70 | | Set Test Variable | \${frame_size}
  71 | | ...
  72 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  73 | | And Add PCI devices to all DUTs
  74 | | Set Max Rate And Jumbo And Handle Multi Seg
  75 | | And Apply startup configuration on all VPP DUTs
  76 | | When Initialize LISP IPv6 over IPv4 forwarding in 3-node circular topology
  77 | | ... | ${dut1_to_dut2_ip6o4} | ${dut1_to_tg_ip6o4} | ${dut2_to_dut1_ip6o4}
  78 | | ... | ${dut2_to_tg_ip6o4} | ${tg_prefix6o4} | ${dut_prefix6o4}
  79 | | And Configure LISP topology in 3-node circular topology
  80 | | ... | ${dut1} | ${dut1_if2} | ${NONE}
  81 | | ... | ${dut2} | ${dut2_if1} | ${NONE}
  82 | | ... | ${duts_locator_set} | ${dut1_ip6o4_eid} | ${dut2_ip6o4_eid}
  83 | | ... | ${dut1_ip6o4_static_adjacency} | ${dut2_ip6o4_static_adjacency}
  84 | | Then Find NDR and PDR intervals using optimized search
  85
  86 *** Test Cases ***
  87 | tc01-78B-1c-ethip6lispip4-ip6base-ndrpdr
  88 | | [Tags] | 78B | 1C
  89 | | frame_size=${78} | phy_cores=${1}
  90
  91 | tc02-78B-2c-ethip6lispip4-ip6base-ndrpdr
  92 | | [Tags] | 78B | 2C
  93 | | frame_size=${78} | phy_cores=${2}
  94
  95 | tc03-78B-4c-ethip6lispip4-ip6base-ndrpdr
  96 | | [Tags] | 78B | 4C
  97 | | frame_size=${78} | phy_cores=${4}
  98
  99 | tc04-1518B-1c-ethip6lispip4-ip6base-ndrpdr
 100 | | [Tags] | 1518B | 1C
 101 | | frame_size=${1518} | phy_cores=${1}
 102
 103 | tc05-1518B-2c-ethip6lispip4-ip6base-ndrpdr
 104 | | [Tags] | 1518B | 2C
 105 | | frame_size=${1518} | phy_cores=${2}
 106
 107 | tc06-1518B-4c-ethip6lispip4-ip6base-ndrpdr
 108 | | [Tags] | 1518B | 4C
 109 | | frame_size=${1518} | phy_cores=${4}
 110
 111 | tc07-9000B-1c-ethip6lispip4-ip6base-ndrpdr
 112 | | [Tags] | 9000B | 1C
 113 | | frame_size=${9000} | phy_cores=${1}
 114
 115 | tc08-9000B-2c-ethip6lispip4-ip6base-ndrpdr
 116 | | [Tags] | 9000B | 2C
 117 | | frame_size=${9000} | phy_cores=${2}
 118
 119 | tc09-9000B-4c-ethip6lispip4-ip6base-ndrpdr
 120 | | [Tags] | 9000B | 4C
 121 | | frame_size=${9000} | phy_cores=${4}
 122
 123 | tc10-IMIX-1c-ethip6lispip4-ip6base-ndrpdr
 124 | | [Tags] | IMIX | 1C
 125 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 126
 127 | tc11-IMIX-2c-ethip6lispip4-ip6base-ndrpdr
 128 | | [Tags] | IMIX | 2C
 129 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 130
 131 | tc12-IMIX-4c-ethip6lispip4-ip6base-ndrpdr
 132 | | [Tags] | IMIX | 4C
 133 | | frame_size=IMIX_v4_1 | phy_cores=${4}