tests/vpp/perf/ip6_tunnels/10ge2p1x710-ethip6lispip6-ip6base-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/overlay/lisp_static_adjacency.robot
  17 | Variables | resources/test_data/lisp/performance/lisp_static_adjacency.py
  18 | ...
  19 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  20 | ... | NIC_Intel-X710 | IP6FWD | ENCAP | LISP | IP6UNRLAY | IP6OVRLAY
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L3 | ${nic_name}
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance test
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *RFC6830: Pkt throughput Lisp test cases*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  35 | ... | with single links between nodes.\
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISP-IPv6 on DUT1-DUT2,\
  37 | ... | Eth-IPv6 on TG-DUTn for IPv6 routing over LISPoIPv6 tunnel.\
  38 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
  39 | ... | routing and static routes. LISPoIPv6 tunnel is configured between\
  40 | ... | DUT1 and DUT2. DUT1 and DUT2 tested with ${nic_name}.\
  41 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  42 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  43 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  44 | ... | of packets transmitted. NDR and PDR are discovered for different\
  45 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  46 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  47
  48 *** Variables ***
  49 | ${nic_name}= | Intel-X710
  50 # LISP overhead
  51 | ${overhead}= | 8
  52 # Traffic profile:
  53 | ${traffic_profile}= | trex-sl-3n-ethip6-ip6src253
  54
  55 *** Keywords ***
  56 | Local Template
  57 | | [Documentation]
  58 | | ... | [Cfg] DUT runs IPv6 LISP remote static mappings and whitelist\
  59 | | ... | filters config.\
  60 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.\
  61 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  62 | | ...
  63 | | ... | *Arguments:*
  64 | | ... | - frame_size - Frame size in Bytes as integer or string (IMIX_v4_1).
  65 | | ... |   Type: integer, string
  66 | | ... | - phy_cores - Number of physical cores. Type: integer
  67 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  68 | | ...
  69 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  70 | | ...
  71 | | Set Test Variable | \${frame_size}
  72 | | ...
  73 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  74 | | And Add PCI devices to all DUTs
  75 | | Set Max Rate And Jumbo And Handle Multi Seg
  76 | | And Apply startup configuration on all VPP DUTs
  77 | | When Initialize LISP IPv6 forwarding in 3-node circular topology
  78 | | ... | ${dut1_to_dut2_ip6} | ${dut1_to_tg_ip6} | ${dut2_to_dut1_ip6}
  79 | | ... | ${dut2_to_tg_ip6} | ${prefix6}
  80 | | And Configure LISP topology in 3-node circular topology
  81 | | ... | ${dut1} | ${dut1_if2} | ${NONE}
  82 | | ... | ${dut2} | ${dut2_if1} | ${NONE}
  83 | | ... | ${duts_locator_set} | ${dut1_ip6_eid} | ${dut2_ip6_eid}
  84 | | ... | ${dut1_ip6_static_adjacency} | ${dut2_ip6_static_adjacency}
  85 | | Then Find NDR and PDR intervals using optimized search
  86
  87 *** Test Cases ***
  88 | tc01-78B-1c-ethip6lispip6-ip6base-ndrpdr
  89 | | [Tags] | 78B | 1C
  90 | | frame_size=${78} | phy_cores=${1}
  91
  92 | tc02-78B-2c-ethip6lispip6-ip6base-ndrpdr
  93 | | [Tags] | 78B | 2C
  94 | | frame_size=${78} | phy_cores=${2}
  95
  96 | tc03-78B-4c-ethip6lispip6-ip6base-ndrpdr
  97 | | [Tags] | 78B | 4C
  98 | | frame_size=${78} | phy_cores=${4}
  99
 100 | tc04-1518B-1c-ethip6lispip6-ip6base-ndrpdr
 101 | | [Tags] | 1518B | 1C
 102 | | frame_size=${1518} | phy_cores=${1}
 103
 104 | tc05-1518B-2c-ethip6lispip6-ip6base-ndrpdr
 105 | | [Tags] | 1518B | 2C
 106 | | frame_size=${1518} | phy_cores=${2}
 107
 108 | tc06-1518B-4c-ethip6lispip6-ip6base-ndrpdr
 109 | | [Tags] | 1518B | 4C
 110 | | frame_size=${1518} | phy_cores=${4}
 111
 112 | tc07-9000B-1c-ethip6lispip6-ip6base-ndrpdr
 113 | | [Tags] | 9000B | 1C
 114 | | frame_size=${9000} | phy_cores=${1}
 115
 116 | tc08-9000B-2c-ethip6lispip6-ip6base-ndrpdr
 117 | | [Tags] | 9000B | 2C
 118 | | frame_size=${9000} | phy_cores=${2}
 119
 120 | tc09-9000B-4c-ethip6lispip6-ip6base-ndrpdr
 121 | | [Tags] | 9000B | 4C
 122 | | frame_size=${9000} | phy_cores=${4}
 123
 124 | tc10-IMIX-1c-ethip6lispip6-ip6base-ndrpdr
 125 | | [Tags] | IMIX | 1C
 126 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 127
 128 | tc11-IMIX-2c-ethip6lispip6-ip6base-ndrpdr
 129 | | [Tags] | IMIX | 2C
 130 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 131
 132 | tc12-IMIX-4c-ethip6lispip6-ip6base-ndrpdr
 133 | | [Tags] | IMIX | 4C
 134 | | frame_size=IMIX_v4_1 | phy_cores=${4}