tests/vpp/perf/l2/10ge2p1x520-eth-l2bdbasemaclrn-macip-iacl10sl-100kflows-ndrpdrdisc.robot

   1 # Copyright (c) 2017 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDRDISC
  18 | ... | NIC_Intel-X520-DA2 | ETH | L2BDMACLRN | FEATURE | MACIP | ACL_STATELESS
  19 | ... | IACL | ACL10 | 100k_FLOWS
  20 | ...
  21 | Suite Setup | Run Keywords
  22 | ... | Set up 3-node performance topology with DUT's NIC model | L2
  23 | ... | Intel-X520-DA2
  24 | ... | AND | Set up performance test suite with ACL
  25 | Suite Teardown | Tear down 3-node performance topology
  26 | ...
  27 | Test Setup | Set up performance test
  28 | ...
  29 | Test Teardown | Tear down performance test with MACIP ACL
  30 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  31 | ...
  32 | Documentation | *RFC2544: Packet throughput L2BD test cases with ACL*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  35 | ... | with single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  37 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 bridge domain\
  38 | ... | and MAC learning enabled. DUT2 is configured with L2 cross-connects.\
  39 | ... | Required MACIP ACL rules are applied to input paths of both DUT1\
  40 | ... | interfaces. DUT1 and DUT2 are tested with 2p10GE NIC X520 Niantic by\
  41 | ... | Intel.
  42 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  43 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  44 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  45 | ... | of packets transmitted. NDR and PDR are discovered for different\
  46 | ... | Ethernet L2 frame sizes using either binary search or linear search\
  47 | ... | algorithms with configured starting rate and final step that determines\
  48 | ... | throughput measurement resolution. Test packets are generated by TG on\
  49 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  50 | ... | (flow-group per direction, ${flows_per_dir} flows per flow-group) with\
  51 | ... | all packets containing Ethernet header, IPv4 header with IP protocol=61\
  52 | ... | and static payload. MAC addresses are matching MAC addresses of the TG\
  53 | ... | node interfaces.
  54 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  55
  56 *** Variables ***
  57 # X520-DA2 bandwidth limit
  58 | ${s_limit}= | ${10000000000}
  59
  60 # ACL test setup
  61 | ${acl_action}= | permit
  62 | ${no_hit_aces_number}= | 10
  63 | ${flows_per_dir}= | 100k
  64
  65 # starting points for non-hitting ACLs
  66 | ${src_ip_start}= | 30.30.30.1
  67 | ${ip_step}= | ${1}
  68 | ${src_mac_start}= | 01:02:03:04:05:06
  69 | ${src_mac_step}= | ${1000}
  70 | ${src_mac_mask}= | 00:00:00:00:00:00
  71 | ${tg_stream1_mac}= | ca:fe:00:00:00:00
  72 | ${tg_stream2_mac}= | fa:ce:00:00:00:00
  73 | ${tg_mac_mask}= | ff:ff:ff:fe:00:00
  74 | ${tg_stream1_subnet}= | 10.0.0.0/15
  75 | ${tg_stream2_subnet}= | 20.0.0.0/15
  76
  77 # traffic profile
  78 | ${traffic_profile}= | trex-sl-3n-ethip4-macsrc100kip4src100k
  79
  80 *** Keywords ***
  81 | Discover NDR or PDR for L2 Bridge Domain with MACIP ACLs
  82 | | ...
  83 | | [Arguments] | ${wt} | ${rxq} | ${framesize} | ${min_rate} | ${search_type}
  84 | | ...
  85 | | Set Test Variable | ${framesize}
  86 | | Set Test Variable | ${min_rate}
  87 | | ${max_rate}= | Calculate pps | ${s_limit} | ${framesize}
  88 | | ${binary_min}= | Set Variable | ${min_rate}
  89 | | ${binary_max}= | Set Variable | ${max_rate}
  90 | | ${threshold}= | Set Variable | ${min_rate}
  91 | | ...
  92 | | Given Add '${wt}' worker threads and '${rxq}' rxqueues in 3-node single-link circular topology
  93 | | And Add PCI devices to all DUTs
  94 | | ${get_framesize}= | Get Frame Size | ${framesize}
  95 | | And Run Keyword If | ${get_framesize} < ${1522} | Add no multi seg to all DUTs
  96 | | And Apply startup configuration on all VPP DUTs
  97 | | When Initialize L2 bridge domain with MACIP ACLs on DUT1 in 3-node circular topology
  98 | | Then Run Keyword If | '${search_type}' == 'NDR'
  99 | | ... | Find NDR using binary search and pps
 100 | | ... | ${framesize} | ${binary_min} | ${binary_max} | ${traffic_profile}
 101 | | ... | ${min_rate} | ${max_rate} | ${threshold}
 102 | | ... | ELSE IF | '${search_type}' == 'PDR'
 103 | | ... | Find PDR using binary search and pps
 104 | | ... | ${framesize} | ${binary_min} | ${binary_max} | ${traffic_profile}
 105 | | ... | ${min_rate} | ${max_rate} | ${threshold}
 106 | | ... | ${perf_pdr_loss_acceptance} | ${perf_pdr_loss_acceptance_type}
 107
 108 *** Test Cases ***
 109 | tc01-64B-1t1c-eth-l2bdbasemaclrn-macip-iacl10sl-100kflows-ndrdisc
 110 | | [Documentation]
 111 | | ... | [Cfg] DUT runs L2BD switching config with MACIP ACL with\
 112 | | ... | 1 thread, 1 phy core, 1 receive queue per NIC port.
 113 | | ... | [Ver] Find NDR for 64 Byte frames using binary search start at 10GE\
 114 | | ... | linerate, step 50kpps.
 115 | | ...
 116 | | [Tags] | 64B | 1T1C | STHREAD | NDRDISC
 117 | | ...
 118 | | [Template] | Discover NDR or PDR for L2 Bridge Domain with MACIP ACLs
 119 | | wt=1 | rxq=1 | framesize=${64} | min_rate=${50000} | search_type=NDR
 120
 121 | tc02-64B-1t1c-eth-l2bdbasemaclrn-macip-iacl10sl-100kflows-pdrdisc
 122 | | [Documentation]
 123 | | ... | [Cfg] DUT runs L2BD switching config with MACIP ACL with\
 124 | | ... | 1 thread, 1 phy core, 1 receive queue per NIC port.
 125 | | ... | [Ver] Find PDR for 64 Byte frames using binary search start at 10GE\
 126 | | ... | linerate, step 50kpps, LT=0.5%.
 127 | | ...
 128 | | [Tags] | 64B | 1T1C | STHREAD | PDRDISC | SKIP_PATCH
 129 | | ...
 130 | | [Template] | Discover NDR or PDR for L2 Bridge Domain with MACIP ACLs
 131 | | wt=1 | rxq=1 | framesize=${64} | min_rate=${50000} | search_type=PDR
 132
 133 | tc03-64B-2t2c-eth-l2bdbasemaclrn-macip-iacl10sl-100kflows-ndrdisc
 134 | | [Documentation]
 135 | | ... | [Cfg] DUT runs L2BD switching config with MACIP ACL with\
 136 | | ... | 2 threads, 2 phy cores, 1 receive queue per NIC port.
 137 | | ... | [Ver] Find NDR for 64 Byte frames using binary search start at 10GE\
 138 | | ... | linerate, step 50kpps.
 139 | | ...
 140 | | [Tags] | 64B | 2T2C | MTHREAD | NDRDISC
 141 | | ...
 142 | | [Template] | Discover NDR or PDR for L2 Bridge Domain with MACIP ACLs
 143 | | wt=2 | rxq=1 | framesize=${64} | min_rate=${50000} | search_type=NDR
 144
 145 | tc04-64B-2t2c-eth-l2bdbasemaclrn-macip-iacl10sl-100kflows-pdrdisc
 146 | | [Documentation]
 147 | | ... | [Cfg] DUT runs L2BD switching config with MACIP ACL with\
 148 | | ... | 2 threads, 2 phy cores, 1 receive queue per NIC port.
 149 | | ... | [Ver] Find PDR for 64 Byte frames using binary search start at 10GE\
 150 | | ... | linerate, step 50kpps, LT=0.5%.
 151 | | ...
 152 | | [Tags] | 64B | 2T2C | MTHREAD | PDRDISC | SKIP_PATCH
 153 | | ...
 154 | | [Template] | Discover NDR or PDR for L2 Bridge Domain with MACIP ACLs
 155 | | wt=2 | rxq=1 | framesize=${64} | min_rate=${50000} | search_type=PDR
 156
 157 | tc05-64B-4t4c-eth-l2bdbasemaclrn-macip-iacl10sl-100kflows-ndrdisc
 158 | | [Documentation]
 159 | | ... | [Cfg] DUT runs L2BD switching config with MACIP ACL with\
 160 | | ... | 4 threads, 4 phy cores, 2 receive queues per NIC port.
 161 | | ... | [Ver] Find NDR for 64 Byte frames using binary search start at 10GE\
 162 | | ... | linerate, step 50kpps.
 163 | | ...
 164 | | [Tags] | 64B | 4T4C | MTHREAD | NDRDISC
 165 | | ...
 166 | | [Template] | Discover NDR or PDR for L2 Bridge Domain with MACIP ACLs
 167 | | wt=4 | rxq=2 | framesize=${64} | min_rate=${50000} | search_type=NDR
 168
 169 | tc06-64B-4t4c-eth-l2bdbasemaclrn-macip-iacl10sl-100kflows-pdrdisc
 170 | | [Documentation]
 171 | | ... | [Cfg] DUT runs L2BD switching config with MACIP ACL with\
 172 | | ... | 4 threads, 4 phy cores, 2 receive queues per NIC port.
 173 | | ... | [Ver] Find PDR for 64 Byte frames using binary search start at 10GE\
 174 | | ... | linerate, step 50kpps, LT=0.5%.
 175 | | ...
 176 | | [Tags] | 64B | 4T4C | MTHREAD | PDRDISC | SKIP_PATCH
 177 | | ...
 178 | | [Template] | Discover NDR or PDR for L2 Bridge Domain with MACIP ACLs
 179 | | wt=4 | rxq=2 | framesize=${64} | min_rate=${50000} | search_type=PDR