tests/vpp/perf/l2/10ge2p1x710-avf-eth-l2patch-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | L2PATCH | BASE | DRV_AVF
  19 | ...
  20 | Suite Setup | Run Keywords
  21 | ... | Set up SRIOV 3-node performance topology with DUT's NIC model
  22 | ... | L2 | ${nic_name} | AVF
  23 | ... | AND | Set up performance test suite with AVF driver
  24 | Suite Teardown | Tear down suite | performance
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down test | performance
  28 | ...
  29 | Test Template | Local template
  30 | ...
  31 | Documentation | *RFC2544: Pkt throughput L2patch test cases*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 patch.
  36 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 patch\
  37 | ... | DUT1 and DUT2 tested with ${nic_name} with VF enabled.\
  38 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  39 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  40 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  41 | ... | of packets transmitted. NDR and PDR are discovered for different\
  42 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  43 | ... | Test packets are generated by TG on
  44 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  45 | ... | (flow-group per direction, 254 flows per flow-group) with all packets
  46 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
  47 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  48 | ... | interfaces.
  49 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  50
  51 *** Variables ***
  52 | ${nic_name}= | Intel-X710
  53 | ${overhead}= | ${0}
  54 # Traffic profile:
  55 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  56
  57 *** Keywords ***
  58 | Local template
  59 | | [Documentation]
  60 | | ... | [Cfg] DUT runs L2 patch config with ${phy_cores} phy
  61 | | ... | core(s).
  62 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  63 | | ...
  64 | | ... | *Arguments:*
  65 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  66 | | ... | Type: integer, string
  67 | | ... | - phy_cores - Number of physical cores. Type: integer
  68 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  69 | | ...
  70 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  71 | | ...
  72 | | Set Test Variable | \${frame_size}
  73 | | ...
  74 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  75 | | And Add DPDK no PCI to all DUTs
  76 | | Set Max Rate And Jumbo
  77 | | And Apply startup configuration on all VPP DUTs
  78 | | When Initialize AVF interfaces
  79 | | And Initialize L2 patch
  80 | | Then Find NDR and PDR intervals using optimized search
  81
  82 *** Test Cases ***
  83 | tc01-64B-1c-avf-eth-l2patch-ndrpdr
  84 | | [Tags] | 64B | 1C
  85 | | frame_size=${64} | phy_cores=${1}
  86
  87 | tc02-64B-2c-avf-eth-l2patch-ndrpdr
  88 | | [Tags] | 64B | 2C
  89 | | frame_size=${64} | phy_cores=${2}
  90
  91 | tc03-64B-4c-avf-eth-l2patch-ndrpdr
  92 | | [Tags] | 64B | 4C
  93 | | frame_size=${64} | phy_cores=${4}
  94
  95 | tc04-1518B-1c-avf-eth-l2patch-ndrpdr
  96 | | [Tags] | 1518B | 1C
  97 | | frame_size=${1518} | phy_cores=${1}
  98
  99 | tc05-1518B-2c-avf-eth-l2patch-ndrpdr
 100 | | [Tags] | 1518B | 2C
 101 | | frame_size=${1518} | phy_cores=${2}
 102
 103 | tc06-1518B-4c-avf-eth-l2patch-ndrpdr
 104 | | [Tags] | 1518B | 4C
 105 | | frame_size=${1518} | phy_cores=${4}
 106
 107 | tc10-IMIX-1c-avf-eth-l2patch-ndrpdr
 108 | | [Tags] | IMIX | 1C
 109 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 110
 111 | tc11-IMIX-2c-avf-eth-l2patch-ndrpdr
 112 | | [Tags] | IMIX | 2C
 113 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 114
 115 | tc12-IMIX-4c-avf-eth-l2patch-ndrpdr
 116 | | [Tags] | IMIX | 4C
 117 | | frame_size=IMIX_v4_1 | phy_cores=${4}