tests/vpp/perf/l2/10ge2p1x710-dot1q-l2bdbasemaclrn-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-X710 | BASE | DOT1Q | L2BDMACLRN
  19 | ...
  20 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  21 | ... | L2 | Intel-X710
  22 | Suite Teardown | Tear down 3-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | Test Teardown | Tear down performance mrr test
  26 | ...
  27 | Test Template | Local template
  28 | ...
  29 | Documentation | *Raw results L2BD test cases with 802.1q test cases*
  30 | ...
  31 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  32 | ... | with single links between nodes.
  33 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.\
  34 | ... | 802.1q tagging is applied on link between DUT1 and DUT2.
  35 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge\
  36 | ... | domain and MAC learning enabled. DUT1 and DUT2 tested with 2p10GE NIC
  37 | ... | X710 by Intel.
  38 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic\
  39 | ... | at line rate and reports total received/sent packets over trial period.\
  40 | ... | Test packets are generated by TG on\
  41 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  42 | ... | (flow-group per direction, 254 flows per flow-group) with all packets\
  43 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static\
  44 | ... | payload. MAC addresses are matching MAC addresses of the TG node\
  45 | ... | interfaces.
  46 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  47
  48 *** Variables ***
  49 | ${subid}= | 10
  50 | ${tag_rewrite}= | pop-1
  51 | ${vlan_overhead}= | ${4}
  52 | ${avg_imix_framesize}= | ${357.833}
  53 # X710-DA2 bandwidth limit
  54 | ${s_limit}= | ${10000000000}
  55 # Bridge domain IDs
  56 | ${bd_id1}= | 1
  57 | ${bd_id2}= | 2
  58 # Traffic profile:
  59 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  60
  61 *** Keywords ***
  62 | Local template
  63 | | [Documentation]
  64 | | ... | [Cfg] DUT runs L2BD config with VLAN with ${phy_cores} phy
  65 | | ... | core(s).
  66 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  67 | | ... | trial throughput test.
  68 | | ...
  69 | | ... | *Arguments:*
  70 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  71 | | ... | Type: integer, string
  72 | | ... | - phy_cores - Number of physical cores. Type: integer
  73 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  74 | | ...
  75 | | [Arguments] | ${phy_cores} | ${framesize} | ${rxq}=${None}
  76 | | ...
  77 | | Set Test Variable | ${framesize}
  78 | | ${get_framesize}= | Get Frame Size | ${framesize}
  79 | | ${max_rate}= | Calculate pps | ${s_limit}
  80 | | ... | ${get_framesize} + ${vlan_overhead}
  81 | | ...
  82 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  83 | | And Add PCI devices to all DUTs
  84 | | And Run Keyword If | ${get_framesize} < ${1522}
  85 | | ... | Add no multi seg to all DUTs
  86 | | And Apply startup configuration on all VPP DUTs
  87 | | When Initialize L2 bridge domains with VLAN dot1q sub-interfaces in a 3-node circular topology
  88 | | ... | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
  89 | | Then Traffic should pass with maximum rate
  90 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  91
  92 *** Test Cases ***
  93 | tc01-64B-1t1c-dot1q-l2bdbasemaclrn-mrr
  94 | | [Tags] | 64B | 1C
  95 | | phy_cores=${1} | framesize=${64}
  96
  97 | tc02-1518B-1t1c-dot1q-l2bdbasemaclrn-mrr
  98 | | [Tags] | 1518B | 1C
  99 | | phy_cores=${1} | framesize=${1518}
 100
 101 | tc03-9000B-1t1c-dot1q-l2bdbasemaclrn-mrr
 102 | | [Tags] | 9000B | 1C
 103 | | phy_cores=${1} | framesize=${9000}
 104
 105 | tc04-IMIX-1t1c-dot1q-l2bdbasemaclrn-mrr
 106 | | [Tags] | IMIX | 1C
 107 | | phy_cores=${1} | framesize=IMIX_v4_1
 108
 109 | tc05-64B-2t2c-dot1q-l2bdbasemaclrn-mrr
 110 | | [Tags] | 64B | 2C
 111 | | phy_cores=${2} | framesize=${64}
 112
 113 | tc06-1518B-2t2c-dot1q-l2bdbasemaclrn-mrr
 114 | | [Tags] | 1518B | 2C
 115 | | phy_cores=${2} | framesize=${1518}
 116
 117 | tc07-9000B-2t2c-dot1q-l2bdbasemaclrn-mrr
 118 | | [Tags] | 9000B | 2C
 119 | | phy_cores=${2} | framesize=${9000}
 120
 121 | tc08-IMIX-2t2c-dot1q-l2bdbasemaclrn-mrr
 122 | | [Tags] | IMIX | 2C
 123 | | phy_cores=${2} | framesize=IMIX_v4_1
 124
 125 | tc09-64B-4t4c-dot1q-l2bdbasemaclrn-mrr
 126 | | [Tags] | 64B | 4C
 127 | | phy_cores=${4} | framesize=${64}
 128
 129 | tc10-1518B-4t4c-dot1q-l2bdbasemaclrn-mrr
 130 | | [Tags] | 1518B | 4C
 131 | | phy_cores=${4} | framesize=${1518}
 132
 133 | tc11-9000B-4t4c-dot1q-l2bdbasemaclrn-mrr
 134 | | [Tags] | 9000B | 4C
 135 | | phy_cores=${4} | framesize=${9000}
 136
 137 | tc12-IMIX-4t4c-dot1q-l2bdbasemaclrn-mrr
 138 | | [Tags] | IMIX | 4C
 139 | | phy_cores=${4} | framesize=IMIX_v4_1