tests/vpp/perf/l2/10ge2p1x710-dot1q-l2xcbase-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/l2/tagging.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | NIC_Intel-X710 | L2XCFWD | BASE | DOT1Q
  20 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  21 | ... | L2 | Intel-X710
  22 | Suite Teardown | Tear down 3-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | ...
  26 | Test Teardown | Tear down performance mrr test
  27 | ...
  28 | Test Template | Local template
  29 | ...
  30 | Documentation | *Raw results L2XC with 802.1q test cases*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 cross connect. 802.1q\
  35 | ... | tagging is applied on link between DUT1 and DUT2.
  36 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 cross-\
  37 | ... | connect. DUT1 and DUT2 tested with 2p10GE NIC X710 by Intel.
  38 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic\
  39 | ... | at line rate and reports total received/sent packets over trial period.\
  40 | ... | Test packets are generated by TG on\
  41 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  42 | ... | (flow-group per direction, 253 flows per flow-group) with all packets\
  43 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static\
  44 | ... | payload. MAC addresses are matching MAC addresses of the TG node\
  45 | ... | interfaces.
  46 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  47
  48 *** Variables ***
  49 | ${subid}= | 10
  50 | ${tag_rewrite}= | pop-1
  51 # X710-DA2 bandwidth limit
  52 | ${s_limit}= | ${10000000000}
  53 # Traffic profile:
  54 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  55
  56 *** Keywords ***
  57 | Local template
  58 | | [Documentation]
  59 | | ... | [Cfg] DUT runs L2XC config with VLAN dot1q with ${phy_cores} phy
  60 | | ... | core(s).
  61 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  62 | | ... | trial throughput test.
  63 | | ...
  64 | | ... | *Arguments:*
  65 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  66 | | ... | Type: integer, string
  67 | | ... | - phy_cores - Number of physical cores. Type: integer
  68 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  69 | | ...
  70 | | [Arguments] | ${phy_cores} | ${framesize} | ${rxq}=${None}
  71 | | ...
  72 | | Set Test Variable | ${framesize}
  73 | | ${get_framesize}= | Get Frame Size | ${framesize}
  74 | | ${max_rate}= | Calculate pps | ${s_limit} | ${get_framesize}
  75 | | ...
  76 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  77 | | And Add PCI devices to all DUTs
  78 | | And Run Keyword If | ${get_framesize} < ${1522}
  79 | | ... | Add no multi seg to all DUTs
  80 | | And Apply startup configuration on all VPP DUTs
  81 | | And Set interfaces in path in 3-node circular topology up
  82 | | When Initialize VLAN dot1q sub-interfaces in 3-node circular topology
  83 | | ... | ${dut1} | ${dut1_if2} | ${dut2} | ${dut2_if1} | ${subid}
  84 | | And Configure L2 tag rewrite method on interfaces
  85 | | ... | ${dut1} | ${subif_index_1} | ${dut2} | ${subif_index_2}
  86 | | ... | ${tag_rewrite}
  87 | | And Connect interfaces and VLAN sub-interfaces using L2XC
  88 | | ... | ${dut1} | ${dut1_if1} | ${subif_index_1}
  89 | | ... | ${dut2} | ${dut2_if2} | ${subif_index_2}
  90 | | Then Traffic should pass with maximum rate
  91 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  92
  93 *** Test Cases ***
  94 | tc01-64B-1t1c-dot1q-l2xcbase-mrr
  95 | | [Tags] | 64B | 1C
  96 | | phy_cores=${1} | framesize=${64}
  97
  98 | tc02-1518B-1t1c-dot1q-l2xcbase-mrr
  99 | | [Tags] | 1518B | 1C
 100 | | phy_cores=${1} | framesize=${1518}
 101
 102 | tc03-9000B-1t1c-dot1q-l2xcbase-mrr
 103 | | [Tags] | 9000B | 1C
 104 | | phy_cores=${1} | framesize=${9000}
 105
 106 | tc04-IMIX-1t1c-dot1q-l2xcbase-mrr
 107 | | [Tags] | IMIX | 1C
 108 | | phy_cores=${1} | framesize=IMIX_v4_1
 109
 110 | tc05-64B-2t2c-dot1q-l2xcbase-mrr
 111 | | [Tags] | 64B | 2C
 112 | | phy_cores=${2} | framesize=${64}
 113
 114 | tc06-1518B-2t2c-dot1q-l2xcbase-mrr
 115 | | [Tags] | 1518B | 2C
 116 | | phy_cores=${2} | framesize=${1518}
 117
 118 | tc07-9000B-2t2c-dot1q-l2xcbase-mrr
 119 | | [Tags] | 9000B | 2C
 120 | | phy_cores=${2} | framesize=${9000}
 121
 122 | tc08-IMIX-2t2c-dot1q-l2xcbase-mrr
 123 | | [Tags] | IMIX | 2C
 124 | | phy_cores=${2} | framesize=IMIX_v4_1
 125
 126 | tc09-64B-4t4c-dot1q-l2xcbase-mrr
 127 | | [Tags] | 64B | 4C
 128 | | phy_cores=${4} | framesize=${64}
 129
 130 | tc10-1518B-4t4c-dot1q-l2xcbase-mrr
 131 | | [Tags] | 1518B | 4C
 132 | | phy_cores=${4} | framesize=${1518}
 133
 134 | tc11-9000B-4t4c-dot1q-l2xcbase-mrr
 135 | | [Tags] | 9000B | 4C
 136 | | phy_cores=${4} | framesize=${9000}
 137
 138 | tc12-IMIX-4t4c-dot1q-l2xcbase-mrr
 139 | | [Tags] | IMIX | 4C
 140 | | phy_cores=${4} | framesize=IMIX_v4_1