tests/vpp/perf/l2/10ge2p1x710-dot1q-l2xcbase-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/l2/tagging.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | NIC_Intel-X710 | L2XCFWD | BASE | DOT1Q
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-X710
  23 | ...
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance mrr test
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *Raw results L2XC with 802.1q test cases*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  35 | ... | with single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 cross connect. 802.1q\
  37 | ... | tagging is applied on link between DUT1 and DUT2.
  38 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 cross-\
  39 | ... | connect. DUT1 and DUT2 tested with 2p10GE NIC X710 by Intel.
  40 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic\
  41 | ... | at line rate and reports total received/sent packets over trial period.\
  42 | ... | Test packets are generated by TG on\
  43 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  44 | ... | (flow-group per direction, 253 flows per flow-group) with all packets\
  45 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static\
  46 | ... | payload. MAC addresses are matching MAC addresses of the TG node\
  47 | ... | interfaces.
  48 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  49
  50 *** Variables ***
  51 | ${subid}= | 10
  52 | ${tag_rewrite}= | pop-1
  53 | ${overhead}= | ${4}
  54 # X710-DA2 bandwidth limit
  55 | ${s_limit}= | ${10000000000}
  56 # Traffic profile:
  57 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  58
  59 *** Keywords ***
  60 | Local Template
  61 | | [Documentation]
  62 | | ... | [Cfg] DUT runs L2XC config with VLAN dot1q with ${phy_cores} phy
  63 | | ... | core(s).
  64 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  65 | | ... | trial throughput test.
  66 | | ...
  67 | | ... | *Arguments:*
  68 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  69 | | ... | Type: integer, string
  70 | | ... | - phy_cores - Number of physical cores. Type: integer
  71 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  72 | | ...
  73 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  74 | | ...
  75 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  76 | | And Add PCI devices to all DUTs
  77 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  78 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  79 | | And Apply startup configuration on all VPP DUTs
  80 | | And Set interfaces in path in 3-node circular topology up
  81 | | When Initialize VLAN dot1q sub-interfaces in 3-node circular topology
  82 | | ... | ${dut1} | ${dut1_if2} | ${dut2} | ${dut2_if1} | ${subid}
  83 | | And Configure L2 tag rewrite method on interfaces
  84 | | ... | ${dut1} | ${subif_index_1} | ${dut2} | ${subif_index_2}
  85 | | ... | ${tag_rewrite}
  86 | | And Connect interfaces and VLAN sub-interfaces using L2XC
  87 | | ... | ${dut1} | ${dut1_if1} | ${subif_index_1}
  88 | | ... | ${dut2} | ${dut2_if2} | ${subif_index_2}
  89 | | Then Traffic should pass with maximum rate
  90 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  91
  92 *** Test Cases ***
  93 | tc01-64B-1c-dot1q-l2xcbase-mrr
  94 | | [Tags] | 64B | 1C
  95 | | framesize=${64} | phy_cores=${1}
  96
  97 | tc02-64B-2c-dot1q-l2xcbase-mrr
  98 | | [Tags] | 64B | 2C
  99 | | framesize=${64} | phy_cores=${2}
 100
 101 | tc03-64B-4c-dot1q-l2xcbase-mrr
 102 | | [Tags] | 64B | 4C
 103 | | framesize=${64} | phy_cores=${4}
 104
 105 | tc04-1518B-1c-dot1q-l2xcbase-mrr
 106 | | [Tags] | 1518B | 1C
 107 | | framesize=${1518} | phy_cores=${1}
 108
 109 | tc05-1518B-2c-dot1q-l2xcbase-mrr
 110 | | [Tags] | 1518B | 2C
 111 | | framesize=${1518} | phy_cores=${2}
 112
 113 | tc06-1518B-4c-dot1q-l2xcbase-mrr
 114 | | [Tags] | 1518B | 4C
 115 | | framesize=${1518} | phy_cores=${4}
 116
 117 | tc07-9000B-1c-dot1q-l2xcbase-mrr
 118 | | [Tags] | 9000B | 1C
 119 | | framesize=${9000} | phy_cores=${1}
 120
 121 | tc08-9000B-2c-dot1q-l2xcbase-mrr
 122 | | [Tags] | 9000B | 2C
 123 | | framesize=${9000} | phy_cores=${2}
 124
 125 | tc09-9000B-4c-dot1q-l2xcbase-mrr
 126 | | [Tags] | 9000B | 4C
 127 | | framesize=${9000} | phy_cores=${4}
 128
 129 | tc10-IMIX-1c-dot1q-l2xcbase-mrr
 130 | | [Tags] | IMIX | 1C
 131 | | framesize=IMIX_v4_1 | phy_cores=${1}
 132
 133 | tc11-IMIX-2c-dot1q-l2xcbase-mrr
 134 | | [Tags] | IMIX | 2C
 135 | | framesize=IMIX_v4_1 | phy_cores=${2}
 136
 137 | tc12-IMIX-4c-dot1q-l2xcbase-mrr
 138 | | [Tags] | IMIX | 4C
 139 | | framesize=IMIX_v4_1 | phy_cores=${4}