tests/vpp/perf/l2/10ge2p1x710-dot1q-l2xcbase-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/l2/tagging.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X710 | L2XCFWD | BASE | DOT1Q
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-X710
  23 | ...
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  29 | ... | ${framesize} | ${traffic_profile}
  30 | ...
  31 | Test Template | Local Template
  32 | ...
  33 | Documentation | *RFC2544: Pkt throughput L2XC with 802.1q test cases*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 cross connect. 802.1q\
  38 | ... | tagging is applied on link between DUT1 and DUT2.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 cross-\
  40 | ... | connect. DUT1 and DUT2 tested with 2p10GE NIC X710 by Intel.
  41 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  42 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  43 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  44 | ... | of packets transmitted. NDR and PDR are discovered for different
  45 | ... | Ethernet L2 frame sizes using MLRsearch library.
  46 | ... | Test packets are generated by TG on\
  47 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  48 | ... | (flow-group per direction, 253 flows per flow-group) with all packets\
  49 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static\
  50 | ... | payload. MAC addresses are matching MAC addresses of the TG node\
  51 | ... | interfaces.
  52 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  53
  54 *** Variables ***
  55 | ${subid}= | 10
  56 | ${tag_rewrite}= | pop-1
  57 | ${overhead}= | ${4}
  58 # X710-DA2 bandwidth limit
  59 | ${s_limit}= | ${10000000000}
  60 # Traffic profile:
  61 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  62
  63 *** Keywords ***
  64 | Local Template
  65 | | [Documentation]
  66 | | ... | [Cfg] DUT runs L2XC config with VLAN dot1q with ${phy_cores} phy
  67 | | ... | core(s).
  68 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  69 | | ...
  70 | | ... | *Arguments:*
  71 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  72 | | ... | Type: integer, string
  73 | | ... | - phy_cores - Number of physical cores. Type: integer
  74 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  75 | | ...
  76 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  77 | | ...
  78 | | Set Test Variable | ${framesize}
  79 | | Set Test Variable | ${min_rate} | ${10000}
  80 | | ...
  81 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  82 | | And Add PCI devices to all DUTs
  83 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  84 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  85 | | And Apply startup configuration on all VPP DUTs
  86 | | When Initialize VLAN dot1q sub-interfaces in 3-node circular topology
  87 | | ... | ${dut1} | ${dut1_if2} | ${dut2} | ${dut2_if1} | ${subid}
  88 | | And Configure L2 tag rewrite method on interfaces
  89 | | ... | ${dut1} | ${subif_index_1} | ${dut2} | ${subif_index_2}
  90 | | ... | ${tag_rewrite}
  91 | | And Connect interfaces and VLAN sub-interfaces using L2XC
  92 | | ... | ${dut1} | ${dut1_if1} | ${subif_index_1}
  93 | | ... | ${dut2} | ${dut2_if2} | ${subif_index_2}
  94 | | Then Find NDR and PDR intervals using optimized search
  95 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
  96
  97 *** Test Cases ***
  98 | tc01-64B-1c-dot1q-l2xcbase-ndrpdr
  99 | | [Tags] | 64B | 1C
 100 | | framesize=${64} | phy_cores=${1}
 101
 102 | tc02-64B-2c-dot1q-l2xcbase-ndrpdr
 103 | | [Tags] | 64B | 2C
 104 | | framesize=${64} | phy_cores=${2}
 105
 106 | tc03-64B-4c-dot1q-l2xcbase-ndrpdr
 107 | | [Tags] | 64B | 4C
 108 | | framesize=${64} | phy_cores=${4}
 109
 110 | tc04-1518B-1c-dot1q-l2xcbase-ndrpdr
 111 | | [Tags] | 1518B | 1C
 112 | | framesize=${1518} | phy_cores=${1}
 113
 114 | tc05-1518B-2c-dot1q-l2xcbase-ndrpdr
 115 | | [Tags] | 1518B | 2C
 116 | | framesize=${1518} | phy_cores=${2}
 117
 118 | tc06-1518B-4c-dot1q-l2xcbase-ndrpdr
 119 | | [Tags] | 1518B | 4C
 120 | | framesize=${1518} | phy_cores=${4}
 121
 122 | tc07-9000B-1c-dot1q-l2xcbase-ndrpdr
 123 | | [Tags] | 9000B | 1C
 124 | | framesize=${9000} | phy_cores=${1}
 125
 126 | tc08-9000B-2c-dot1q-l2xcbase-ndrpdr
 127 | | [Tags] | 9000B | 2C
 128 | | framesize=${9000} | phy_cores=${2}
 129
 130 | tc09-9000B-4c-dot1q-l2xcbase-ndrpdr
 131 | | [Tags] | 9000B | 4C
 132 | | framesize=${9000} | phy_cores=${4}
 133
 134 | tc10-IMIX-1c-dot1q-l2xcbase-ndrpdr
 135 | | [Tags] | IMIX | 1C
 136 | | framesize=IMIX_v4_1 | phy_cores=${1}
 137
 138 | tc11-IMIX-2c-dot1q-l2xcbase-ndrpdr
 139 | | [Tags] | IMIX | 2C
 140 | | framesize=IMIX_v4_1 | phy_cores=${2}
 141
 142 | tc12-IMIX-4c-dot1q-l2xcbase-ndrpdr
 143 | | [Tags] | IMIX | 4C
 144 | | framesize=IMIX_v4_1 | phy_cores=${4}