tests/vpp/perf/l2/10ge2p1x710-dot1q-l2xcbase-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/l2/tagging.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X710 | L2XCFWD | BASE | DOT1Q
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L2 | ${nic_name}
  23 | Suite Teardown | Tear down suite | performance
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down test | performance
  27 | ...
  28 | Test Template | Local Template
  29 | ...
  30 | Documentation | *RFC2544: Pkt throughput L2XC with IEEE 802.1Q test cases*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 cross connect. IEEE\
  35 | ... | 802.1Q tagging is applied on link between DUT1 and DUT2.
  36 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 cross-\
  37 | ... | connect. DUT1 and DUT2 are tested with ${nic_name}.\
  38 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  39 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  40 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  41 | ... | of packets transmitted. NDR and PDR are discovered for different\
  42 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  43 | ... | Test packets are\
  44 | ... | generated by TG on links to DUTs. TG traffic profile contains two L3\
  45 | ... | flow-groups (flow-group per direction, 254 flows per flow-group) with\
  46 | ... | all packets containing Ethernet header, IPv4 header with IP protocol=61\
  47 | ... | and static payload. MAC addresses are matching MAC addresses of the TG\
  48 | ... | node interfaces.
  49 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  50
  51 *** Variables ***
  52 | ${nic_name}= | Intel-X710
  53 | ${overhead}= | ${4}
  54 | ${subid}= | 10
  55 | ${tag_rewrite}= | pop-1
  56 # Traffic profile:
  57 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  58
  59 *** Keywords ***
  60 | Local Template
  61 | | [Documentation]
  62 | | ... | [Cfg] Each DUT runs L2XC config with VLAN and uses ${phy_cores}\
  63 | | ... | physical core(s) for worker threads.
  64 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  65 | | ...
  66 | | ... | *Arguments:*
  67 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  68 | | ... | Type: integer, string
  69 | | ... | - phy_cores - Number of physical cores. Type: integer
  70 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  71 | | ...
  72 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  73 | | ...
  74 | | Set Test Variable | \${frame_size}
  75 | | ...
  76 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  77 | | And Add PCI devices to all DUTs
  78 | | Set Max Rate And Jumbo And Handle Multi Seg
  79 | | And Apply startup configuration on all VPP DUTs
  80 | | When Initialize VLAN dot1q sub-interfaces in circular topology
  81 | | ... | ${dut1} | ${dut1_if2} | ${dut2} | ${dut2_if1} | ${subid}
  82 | | And Configure L2 tag rewrite method on interfaces
  83 | | ... | ${dut1} | ${subif_index_1} | ${dut2} | ${subif_index_2}
  84 | | ... | ${tag_rewrite}
  85 | | And Connect interfaces and VLAN sub-interfaces using L2XC
  86 | | ... | ${dut1} | ${dut1_if1} | ${subif_index_1}
  87 | | ... | ${dut2} | ${dut2_if2} | ${subif_index_2}
  88 | | Then Find NDR and PDR intervals using optimized search
  89
  90 *** Test Cases ***
  91 | tc01-64B-1c-dot1q-l2xcbase-ndrpdr
  92 | | [Tags] | 64B | 1C
  93 | | frame_size=${64} | phy_cores=${1}
  94
  95 | tc02-64B-2c-dot1q-l2xcbase-ndrpdr
  96 | | [Tags] | 64B | 2C
  97 | | frame_size=${64} | phy_cores=${2}
  98
  99 | tc03-64B-4c-dot1q-l2xcbase-ndrpdr
 100 | | [Tags] | 64B | 4C
 101 | | frame_size=${64} | phy_cores=${4}
 102
 103 | tc04-1518B-1c-dot1q-l2xcbase-ndrpdr
 104 | | [Tags] | 1518B | 1C
 105 | | frame_size=${1518} | phy_cores=${1}
 106
 107 | tc05-1518B-2c-dot1q-l2xcbase-ndrpdr
 108 | | [Tags] | 1518B | 2C
 109 | | frame_size=${1518} | phy_cores=${2}
 110
 111 | tc06-1518B-4c-dot1q-l2xcbase-ndrpdr
 112 | | [Tags] | 1518B | 4C
 113 | | frame_size=${1518} | phy_cores=${4}
 114
 115 | tc07-9000B-1c-dot1q-l2xcbase-ndrpdr
 116 | | [Tags] | 9000B | 1C
 117 | | frame_size=${9000} | phy_cores=${1}
 118
 119 | tc08-9000B-2c-dot1q-l2xcbase-ndrpdr
 120 | | [Tags] | 9000B | 2C
 121 | | frame_size=${9000} | phy_cores=${2}
 122
 123 | tc09-9000B-4c-dot1q-l2xcbase-ndrpdr
 124 | | [Tags] | 9000B | 4C
 125 | | frame_size=${9000} | phy_cores=${4}
 126
 127 | tc10-IMIX-1c-dot1q-l2xcbase-ndrpdr
 128 | | [Tags] | IMIX | 1C
 129 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 130
 131 | tc11-IMIX-2c-dot1q-l2xcbase-ndrpdr
 132 | | [Tags] | IMIX | 2C
 133 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 134
 135 | tc12-IMIX-4c-dot1q-l2xcbase-ndrpdr
 136 | | [Tags] | IMIX | 4C
 137 | | frame_size=IMIX_v4_1 | phy_cores=${4}