tests/vpp/perf/l2/10ge2p1x82599es-dot1ad-l2xcbase-ndrpdr.robot

   1 # Copyright (c) 2019 PANTHEON.tech and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/l2/tagging.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-82599ES | L2XCFWD | BASE | DOT1AD
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-82599ES
  23 | ...
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  29 | ... | ${framesize} | ${traffic_profile}
  30 | ...
  31 | Test Template | Local Template
  32 | ...
  33 | Documentation | *RFC2544: Pkt throughput L2XC with 802.1ad test cases*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 xconnect.
  38 | ... | 802.1ad tagging is applied on link between DUT1 and DUT2 with inner 4B
  39 | ... | vlan tag (id=100) and outer 4B vlan tag (id=200).
  40 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 cross-
  41 | ... | connect. DUT1 and DUT2 tested with 2p10GE NIC 82599ES by Intel.
  42 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  43 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  44 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  45 | ... | of packets transmitted. NDR and PDR are discovered for different
  46 | ... | Ethernet L2 frame sizes using MLRsearch library.
  47 | ... | Test packets are generated by TG on
  48 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  49 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  50 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  51 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  52 | ... | node interfaces.
  53 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  54
  55 *** Variables ***
  56 | ${subid}= | 10
  57 | ${outer_vlan_id}= | 100
  58 | ${inner_vlan_id}= | 200
  59 | ${type_subif}= | two_tags
  60 | ${tag_rewrite}= | pop-2
  61 | ${overhead}= | ${8}
  62 # 82599ES bandwidth limit
  63 | ${s_limit}= | ${10000000000}
  64 # Traffic profile:
  65 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  66
  67 *** Keywords ***
  68 | Local Template
  69 | | [Documentation]
  70 | | ... | [Cfg] DUT runs L2XC forwarding config.
  71 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  72 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  73 | | ...
  74 | | ... | *Arguments:*
  75 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  76 | | ... | Type: integer, string
  77 | | ... | - phy_cores - Number of physical cores. Type: integer
  78 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  79 | | ...
  80 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  81 | | ...
  82 | | Set Test Variable | ${framesize}
  83 | | Set Test Variable | ${min_rate} | ${10000}
  84 | | ...
  85 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  86 | | And Add PCI devices to all DUTs
  87 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  88 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  89 | | And Apply startup configuration on all VPP DUTs
  90 | | And Set interfaces in path up
  91 | | When Initialize VLAN sub-interfaces in 3-node circular topology
  92 | | ... | ${dut1} | ${dut1_if2} | ${dut2} | ${dut2_if1} | ${subid}
  93 | | ... | ${outer_vlan_id} | ${inner_vlan_id} | ${type_subif}
  94 | | And Configure L2 tag rewrite method on interfaces
  95 | | ... | ${dut1} | ${subif_index_1} | ${dut2} | ${subif_index_2}
  96 | | ... | ${tag_rewrite}
  97 | | And Connect interfaces and VLAN sub-interfaces using L2XC
  98 | | ... | ${dut1} | ${dut1_if1} | ${subif_index_1}
  99 | | ... | ${dut2} | ${dut2_if2} | ${subif_index_2}
 100 | | Then Find NDR and PDR intervals using optimized search
 101 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 102
 103 *** Test Cases ***
 104 | tc01-64B-1c-dot1ad-l2xcbase-ndrpdr
 105 | | [Tags] | 64B | 1C
 106 | | framesize=${64} | phy_cores=${1}
 107
 108 | tc02-64B-2c-dot1ad-l2xcbase-ndrpdr
 109 | | [Tags] | 64B | 2C
 110 | | framesize=${64} | phy_cores=${2}
 111
 112 | tc03-64B-4c-dot1ad-l2xcbase-ndrpdr
 113 | | [Tags] | 64B | 4C
 114 | | framesize=${64} | phy_cores=${4}
 115
 116 | tc04-1518B-1c-dot1ad-l2xcbase-ndrpdr
 117 | | [Tags] | 1518B | 1C
 118 | | framesize=${1518} | phy_cores=${1}
 119
 120 | tc05-1518B-2c-dot1ad-l2xcbase-ndrpdr
 121 | | [Tags] | 1518B | 2C
 122 | | framesize=${1518} | phy_cores=${2}
 123
 124 | tc06-1518B-4c-dot1ad-l2xcbase-ndrpdr
 125 | | [Tags] | 1518B | 4C
 126 | | framesize=${1518} | phy_cores=${4}
 127
 128 | tc07-9000B-1c-dot1ad-l2xcbase-ndrpdr
 129 | | [Tags] | 9000B | 1C
 130 | | framesize=${9000} | phy_cores=${1}
 131
 132 | tc08-9000B-2c-dot1ad-l2xcbase-ndrpdr
 133 | | [Tags] | 9000B | 2C
 134 | | framesize=${9000} | phy_cores=${2}
 135
 136 | tc09-9000B-4c-dot1ad-l2xcbase-ndrpdr
 137 | | [Tags] | 9000B | 4C
 138 | | framesize=${9000} | phy_cores=${4}
 139
 140 | tc10-IMIX-1c-dot1ad-l2xcbase-ndrpdr
 141 | | [Tags] | IMIX | 1C
 142 | | framesize=IMIX_v4_1 | phy_cores=${1}
 143
 144 | tc11-IMIX-2c-dot1ad-l2xcbase-ndrpdr
 145 | | [Tags] | IMIX | 2C
 146 | | framesize=IMIX_v4_1 | phy_cores=${2}
 147
 148 | tc12-IMIX-4c-dot1ad-l2xcbase-ndrpdr
 149 | | [Tags] | IMIX | 4C
 150 | | framesize=IMIX_v4_1 | phy_cores=${4}