tests/vpp/perf/l2/25ge2p1xxv710-avf-eth-l2xcbase-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-XXV710 | ETH | L2XCFWD | BASE | L2XCBASE | DRV_AVF
  19 | ...
  20 | Suite Setup | Run Keywords
  21 | ... | Set up SRIOV 3-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-XXV710 | AVF
  23 | ... | AND | Set up performance test suite with AVF driver
  24 | ...
  25 | Suite Teardown | Tear down 3-node performance topology
  26 | ...
  27 | Test Setup | Set up performance test
  28 | ...
  29 | Test Teardown | Tear down performance mrr test
  30 | ...
  31 | Test Template | Local template
  32 | ...
  33 | Documentation | *Raw results L2XC test cases*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 cross-connect.
  38 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 cross-\
  39 | ... | connect. DUT1 and DUT2 tested with 2p25GE NIC XXV710 by Intel with VF\
  40 | ... | enabled.
  41 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic\
  42 | ... | at line rate and reports total received/sent packets over trial period.\
  43 | ... | Test packets are generated by TG on\
  44 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  45 | ... | (flow-group per direction, 254 flows per flow-group) with all packets\
  46 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static\
  47 | ... | payload. MAC addresses are matching MAC addresses of the TG node\
  48 | ... | interfaces.
  49
  50 *** Variables ***
  51 # XXV710-DA2 bandwidth limit ~50Gbps/2=25Gbps
  52 | ${s_25G}= | ${25000000000}
  53 # XXV710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  54 | ${s_18.75Mpps}= | ${18750000}
  55 # Traffic profile:
  56 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  57
  58 *** Keywords ***
  59 | Local template
  60 | | [Documentation]
  61 | | ... | [Cfg] DUT runs L2XC config with ${phy_cores} phy
  62 | | ... | core(s).
  63 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  64 | | ... | trial throughput test.
  65 | | ...
  66 | | ... | *Arguments:*
  67 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  68 | | ... | Type: integer, string
  69 | | ... | - phy_cores - Number of physical cores. Type: integer
  70 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  71 | | ...
  72 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  73 | | ...
  74 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  75 | | And Add DPDK no PCI to all DUTs
  76 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo
  77 | | ... | ${s_25G} | ${framesize} | pps_limit=${s_18.75Mpps}
  78 | | And Apply startup configuration on all VPP DUTs
  79 | | When Initialize AVF interfaces
  80 | | And Initialize L2 Xconnect In 3-node Circular Topology
  81 | | Then Traffic should pass with maximum rate
  82 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  83
  84 *** Test Cases ***
  85 | tc01-64B-1c-avf-eth-l2xcbase-mrr
  86 | | [Tags] | 64B | 1C
  87 | | framesize=${64} | phy_cores=${1}
  88
  89 | tc02-64B-2c-avf-eth-l2xcbase-mrr
  90 | | [Tags] | 64B | 2C
  91 | | framesize=${64} | phy_cores=${2}
  92
  93 | tc03-64B-4c-avf-eth-l2xcbase-mrr
  94 | | [Tags] | 64B | 4C
  95 | | framesize=${64} | phy_cores=${4}
  96
  97 | tc04-1518B-1c-avf-eth-l2xcbase-mrr
  98 | | [Tags] | 1518B | 1C
  99 | | framesize=${1518} | phy_cores=${1}
 100
 101 | tc05-1518B-2c-avf-eth-l2xcbase-mrr
 102 | | [Tags] | 1518B | 2C
 103 | | framesize=${1518} | phy_cores=${2}
 104
 105 | tc06-1518B-4c-avf-eth-l2xcbase-mrr
 106 | | [Tags] | 1518B | 4C
 107 | | framesize=${1518} | phy_cores=${4}
 108
 109 | tc10-IMIX-1c-avf-eth-l2xcbase-mrr
 110 | | [Tags] | IMIX | 1C
 111 | | framesize=IMIX_v4_1 | phy_cores=${1}
 112
 113 | tc11-IMIX-2c-avf-eth-l2xcbase-mrr
 114 | | [Tags] | IMIX | 2C
 115 | | framesize=IMIX_v4_1 | phy_cores=${2}
 116
 117 | tc12-IMIX-4c-avf-eth-l2xcbase-mrr
 118 | | [Tags] | IMIX | 4C
 119 | | framesize=IMIX_v4_1 | phy_cores=${4}