tests/vpp/perf/l2/25ge2p1xxv710-eth-l2patch-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-XXV710 | ETH | L2PATCH | BASE
  19 | ...
  20 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  21 | ... | L2 | Intel-XXV710
  22 | ...
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | ...
  27 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  28 | ... | ${framesize} | ${traffic_profile}
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *RFC2544: Pkt throughput L2patch test cases*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  35 | ... | with single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 patch.
  37 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 patch\
  38 | ... | DUT1 and DUT2 tested with 2p25GE NIC XXV710 by Intel.
  39 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  40 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  41 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  42 | ... | of packets transmitted. NDR and PDR are discovered for different\
  43 | ... | Ethernet L2 frame sizes using MLRsearch library\
  44 | ... | Test packets are generated by TG on\
  45 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  46 | ... | (flow-group per direction, 254 flows per flow-group) with\
  47 | ... | all packets containing Ethernet header,IPv4 header with static payload.\
  48 | ... | MAC addresses are matching MAC addresses of the TG node interfaces.
  49 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  50
  51 *** Variables ***
  52 # XXV710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  53 | ${s_24.5G} | ${24500000000}
  54 # XXV710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  55 | ${s_18.75Mpps} | ${18750000}
  56 # Traffic profile:
  57 | ${traffic_profile} | trex-sl-3n-ethip4-ip4src254
  58
  59 *** Keywords ***
  60 | Local Template
  61 | | [Documentation]
  62 | | ... | [Cfg] DUT runs L2 patch config with ${phy_cores} phy
  63 | | ... | core(s).
  64 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.
  65 | | ...
  66 | | ... | *Arguments:*
  67 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  68 | | ... | Type: integer, string
  69 | | ... | - phy_cores - Number of physical cores. Type: integer
  70 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  71 | | ...
  72 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  73 | | ...
  74 | | Set Test Variable | ${framesize}
  75 | | Set Test Variable | ${min_rate} | ${10000}
  76 | | ...
  77 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  78 | | And Add PCI devices to all DUTs
  79 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  80 | | ... | ${s_24.5G} | ${framesize} | pps_limit=${s_18.75Mpps}
  81 | | And Add DPDK dev default RXD to all DUTs | 2048
  82 | | And Add DPDK dev default TXD to all DUTs | 2048
  83 | | And Apply startup configuration on all VPP DUTs
  84 | | When Initialize L2 patch
  85 | | Then Find NDR and PDR intervals using optimized search
  86 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
  87
  88 *** Test Cases ***
  89 | tc01-64B-1c-eth-l2patch-ndrpdr
  90 | | [Tags] | 64B | 1C
  91 | | framesize=${64} | phy_cores=${1}
  92
  93 | tc02-64B-2c-eth-l2patch-ndrpdr
  94 | | [Tags] | 64B | 2C
  95 | | framesize=${64} | phy_cores=${2}
  96
  97 | tc03-64B-4c-eth-l2patch-ndrpdr
  98 | | [Tags] | 64B | 4C
  99 | | framesize=${64} | phy_cores=${4}
 100
 101 | tc04-1518B-1c-eth-l2patch-ndrpdr
 102 | | [Tags] | 1518B | 1C
 103 | | framesize=${1518} | phy_cores=${1}
 104
 105 | tc05-1518B-2c-eth-l2patch-ndrpdr
 106 | | [Tags] | 1518B | 2C
 107 | | framesize=${1518} | phy_cores=${2}
 108
 109 | tc06-1518B-4c-eth-l2patch-ndrpdr
 110 | | [Tags] | 1518B | 4C
 111 | | framesize=${1518} | phy_cores=${4}
 112
 113 | tc07-9000B-1c-eth-l2patch-ndrpdr
 114 | | [Tags] | 9000B | 1C
 115 | | framesize=${9000} | phy_cores=${1}
 116
 117 | tc08-9000B-2c-eth-l2patch-ndrpdr
 118 | | [Tags] | 9000B | 2C
 119 | | framesize=${9000} | phy_cores=${2}
 120
 121 | tc09-9000B-4c-eth-l2patch-ndrpdr
 122 | | [Tags] | 9000B | 4C
 123 | | framesize=${9000} | phy_cores=${4}
 124
 125 | tc10-IMIX-1c-eth-l2patch-ndrpdr
 126 | | [Tags] | IMIX | 1C
 127 | | framesize=IMIX_v4_1 | phy_cores=${1}
 128
 129 | tc11-IMIX-2c-eth-l2patch-ndrpdr
 130 | | [Tags] | IMIX | 2C
 131 | | framesize=IMIX_v4_1 | phy_cores=${2}
 132
 133 | tc12-IMIX-4c-eth-l2patch-ndrpdr
 134 | | [Tags] | IMIX | 4C
 135 | | framesize=IMIX_v4_1 | phy_cores=${4}