tests/vpp/perf/l2/2n1l-10ge2p1x710-dot1q-l2bdbasemaclrn-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | BASE | DOT1Q | L2BDMACLRN | DRV_VFIO_PCI
  19 | ... | dot1q-l2bdbasemaclrn
  20 |
  21 | Suite Setup | Setup suite single link | performance
  22 | Suite Teardown | Tear down suite | performance
  23 | Test Setup | Setup test
  24 | Test Teardown | Tear down test | performance
  25 |
  26 | Test Template | Local Template
  27 |
  28 | Documentation | *RFC2544: Pkt throughput L2BD with IEEE 802.1Q test cases*
  29 |
  30 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with\
  31 | ... | single links between nodes.
  32 | ... | *[Enc] Packet Encapsulations:* Dot1q-IPv4 for L2 switching of IPv4.\
  33 | ... | IEEE 802.1Q tagging is applied on both links TG-DUT1 .
  34 | ... | *[Cfg] DUT configuration:* DUT1 is configured with:\
  35 | ... | 2 VLAN subinterfaces (VID 100 and 200),\
  36 | ... | 1 L2 BD with the 2 VLAN subinterfaces,\
  37 | ... | DUT1 tested with ${nic_name} with VF enabled.
  38 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  39 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  40 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  41 | ... | of packets transmitted. NDR and PDR are discovered for different\
  42 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  43 | ... | Test packets are\
  44 | ... | generated by TG on links to DUT1. TG traffic profile contains two L3\
  45 | ... | flow-groups (flow-group per direction, 254 flows per flow-group) with\
  46 | ... | all packets containing Ethernet header, IPv4 header with IP protocol=61\
  47 | ... | and static payload. MAC addresses are matching MAC addresses of the TG\
  48 | ... | node interfaces.
  49 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  50
  51 *** Variables ***
  52 | @{plugins_to_enable}= | dpdk_plugin.so
  53 | ${crypto_type}= | ${None}
  54 | ${nic_name}= | Intel-X710
  55 | ${nic_driver}= | vfio-pci
  56 | ${osi_layer}= | L2
  57 | ${overhead}= | ${4}
  58 # Traffic profile:
  59 | ${traffic_profile}= | trex-sl-dot1qip4-vlan1ip4src254ip4dst254
  60
  61 *** Keywords ***
  62 | Local Template
  63 | | [Documentation]
  64 | | ... | [Cfg] DUT runs L2BD with VLAN with ${phy_cores} physical core(s) for\
  65 | | ... | worker threads.
  66 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  67 | |
  68 | | ... | *Arguments:*
  69 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  70 | | ... | Type: integer, string
  71 | | ... | - phy_cores - Number of physical cores. Type: integer
  72 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  73 | |
  74 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  75 | |
  76 | | Set Test Variable | \${frame_size}
  77 | |
  78 | | Given Set Max Rate And Jumbo
  79 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  80 | | And Pre-initialize layer driver | ${nic_driver}
  81 | | And Apply Startup configuration on all VPP DUTs
  82 | | When Initialize layer driver | ${nic_driver}
  83 | | And Initialize layer interface
  84 | | And Initialize layer dot1q
  85 | | And Initialize L2 bridge domain
  86 | | Then Find NDR and PDR intervals using optimized search
  87
  88 *** Test Cases ***
  89 | tc01-64B-1c-dot1q-l2bdbasemaclrn-ndrpdr
  90 | | [Tags] | 64B | 1C
  91 | | frame_size=${64} | phy_cores=${1}
  92
  93 | tc02-64B-2c-dot1q-l2bdbasemaclrn-ndrpdr
  94 | | [Tags] | 64B | 2C
  95 | | frame_size=${64} | phy_cores=${2}
  96
  97 | tc03-64B-4c-dot1q-l2bdbasemaclrn-ndrpdr
  98 | | [Tags] | 64B | 4C
  99 | | frame_size=${64} | phy_cores=${4}
 100
 101 | tc04-1518B-1c-dot1q-l2bdbasemaclrn-ndrpdr
 102 | | [Tags] | 1518B | 1C
 103 | | frame_size=${1518} | phy_cores=${1}
 104
 105 | tc05-1518B-2c-dot1q-l2bdbasemaclrn-ndrpdr
 106 | | [Tags] | 1518B | 2C
 107 | | frame_size=${1518} | phy_cores=${2}
 108
 109 | tc06-1518B-4c-dot1q-l2bdbasemaclrn-ndrpdr
 110 | | [Tags] | 1518B | 4C
 111 | | frame_size=${1518} | phy_cores=${4}
 112
 113 | tc07-9000B-1c-dot1q-l2bdbasemaclrn-ndrpdr
 114 | | [Tags] | 9000B | 1C
 115 | | frame_size=${9000} | phy_cores=${1}
 116
 117 | tc08-9000B-2c-dot1q-l2bdbasemaclrn-ndrpdr
 118 | | [Tags] | 9000B | 2C
 119 | | frame_size=${9000} | phy_cores=${2}
 120
 121 | tc09-9000B-4c-dot1q-l2bdbasemaclrn-ndrpdr
 122 | | [Tags] | 9000B | 4C
 123 | | frame_size=${9000} | phy_cores=${4}
 124
 125 | tc10-IMIX-1c-dot1q-l2bdbasemaclrn-ndrpdr
 126 | | [Tags] | IMIX | 1C
 127 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 128
 129 | tc11-IMIX-2c-dot1q-l2bdbasemaclrn-ndrpdr
 130 | | [Tags] | IMIX | 2C
 131 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 132
 133 | tc12-IMIX-4c-dot1q-l2bdbasemaclrn-ndrpdr
 134 | | [Tags] | IMIX | 4C
 135 | | frame_size=IMIX_v4_1 | phy_cores=${4}