tests/vpp/perf/l2/2n1l-10ge2p1x710-eth-l2xcbase-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | L2XCFWD | BASE | L2XCBASE
  19 | ...
  20 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  21 | ... | L2 | Intel-X710
  22 | Suite Teardown | Tear down 2-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | ...
  26 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  27 | ... | ${framesize} | ${traffic_profile}
  28 | ...
  29 | Test Template | Local template
  30 | ...
  31 | Documentation | *Packet throughput L2XC test cases*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  36 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 cross-connect.
  37 | ... | DUT1 tested with 2p10GE NIC X710 by Intel.
  38 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  39 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  40 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  41 | ... | of packets transmitted. NDR and PDR are discovered for different\
  42 | ... | Ethernet L2 frame sizes using MLRsearch library\
  43 | ... | Test packets are generated by TG on\
  44 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  45 | ... | (flow-group per direction, 254 flows per flow-group) with\
  46 | ... | all packets containing Ethernet header,IPv4 header with static payload.\
  47 | ... | MAC addresses are matching MAC addresses of the TG node interfaces.
  48 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  49
  50 *** Variables ***
  51 # X710 bandwidth limit
  52 | ${s_limit} | ${10000000000}
  53 # Traffic profile:
  54 | ${traffic_profile} | trex-sl-2n-ethip4-ip4src254
  55
  56 *** Keywords ***
  57 | Local template
  58 | | [Documentation]
  59 | | ... | [Cfg] DUT runs L2XC config.\
  60 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  61 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.
  62 | | ...
  63 | | ... | *Arguments:*
  64 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  65 | | ... |   Type: integer, string
  66 | | ... | - phy_cores - Number of physical cores. Type: integer
  67 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  68 | | ...
  69 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  70 | | ...
  71 | | Set Test Variable | ${framesize}
  72 | | Set Test Variable | ${min_rate} | ${20000}
  73 | | ${get_framesize}= | Get Frame Size | ${framesize}
  74 | | ${max_rate}= | Calculate pps | ${s_limit} | ${get_framesize}
  75 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  76 | | And Add PCI devices to all DUTs
  77 | | And Run Keyword If | ${get_framesize} < ${1522}
  78 | | ... | Add no multi seg to all DUTs
  79 | | And Apply startup configuration on all VPP DUTs
  80 | | And Initialize L2 xconnect in 2-node circular topology
  81 | | Then Find NDR and PDR intervals using optimized search
  82 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
  83
  84 *** Test Cases ***
  85 | tc01-64B-1t1c-eth-l2xcbase-ndrpdr
  86 | | [Tags] | 64B | 1C
  87 | | framesize=${64} | phy_cores=${1}
  88
  89 | tc02-1518B-1t1c-eth-l2xcbase-ndrpdr
  90 | | [Tags] | 1518B | 1C
  91 | | framesize=${1518} | phy_cores=${1}
  92
  93 | tc03-9000B-1t1c-eth-l2xcbase-ndrpdr
  94 | | [Tags] | 9000B | 1C
  95 | | framesize=${9000} | phy_cores=${1}
  96
  97 | tc04-IMIX-1t1c-eth-l2xcbase-ndrpdr
  98 | | [Tags] | IMIX | 1C
  99 | | framesize=IMIX_v4_1 | phy_cores=${1}
 100
 101 | tc05-64B-2t2c-eth-l2xcbase-ndrpdr
 102 | | [Tags] | 64B | 2C
 103 | | framesize=${64} | phy_cores=${2}
 104
 105 | tc06-1518B-2t2c-eth-l2xcbase-ndrpdr
 106 | | [Tags] | 1518B | 2C
 107 | | framesize=${1518} | phy_cores=${2}
 108
 109 | tc07-9000B-2t2c-eth-l2xcbase-ndrpdr
 110 | | [Tags] | 9000B | 2C
 111 | | framesize=${9000} | phy_cores=${2}
 112
 113 | tc08-IMIX-2t2c-eth-l2xcbase-ndrpdr
 114 | | [Tags] | IMIX | 2C
 115 | | framesize=IMIX_v4_1 | phy_cores=${2}
 116
 117 | tc09-64B-4t4c-eth-l2xcbase-ndrpdr
 118 | | [Tags] | 64B | 4C
 119 | | framesize=${64} | phy_cores=${4}
 120
 121 | tc10-1518B-4t4c-eth-l2xcbase-ndrpdr
 122 | | [Tags] | 1518B | 4C
 123 | | framesize=${1518} | phy_cores=${4}
 124
 125 | tc11-9000B-4t4c-eth-l2xcbase-ndrpdr
 126 | | [Tags] | 9000B | 4C
 127 | | framesize=${9000} | phy_cores=${4}
 128
 129 | tc12-IMIX-4t4c-eth-l2xcbase-ndrpdr
 130 | | [Tags] | IMIX | 4C
 131 | | framesize=IMIX_v4_1 | phy_cores=${4}