tests/vpp/perf/l2/2n1l-25ge2p1xxv710-eth-l2patch-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-XXV710 | ETH | L2PATCH | BASE
  19 | ...
  20 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  21 | ... | L2 | Intel-XXV710
  22 | Suite Teardown | Tear down 2-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | ...
  26 | Test Teardown | Tear down performance mrr test
  27 | ...
  28 | Test Template | Local template
  29 | ...
  30 | Documentation | *Raw results L2patch test cases*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 patch.
  35 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 patch\
  36 | ... | DUT1 tested with 2p25GE NIC XXV710 by Intel.
  37 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic\
  38 | ... | at line rate and reports total received/sent packets over trial period.
  39 | ... | Test packets are generated by TG on
  40 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  41 | ... | (flow-group per direction, 254 flows per flow-group) with all packets
  42 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
  43 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  44 | ... | interfaces.
  45
  46 *** Variables ***
  47 # XXV710-DA2 bandwidth limit ~50Gbps/2=25Gbps
  48 | ${s_25G} | ${25000000000}
  49 # XXV710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  50 | ${s_18.75Mpps} | ${18750000}
  51 # Traffic profile:
  52 | ${traffic_profile} | trex-sl-2n-ethip4-ip4src254
  53
  54 *** Keywords ***
  55 | Local template
  56 | | [Documentation]
  57 | | ... | [Cfg] DUT runs L2 patch config with ${phy_cores} phy
  58 | | ... | core(s).
  59 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  60 | | ... | trial throughput test.
  61 | | ...
  62 | | ... | *Arguments:*
  63 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  64 | | ... | Type: integer, string
  65 | | ... | - phy_cores - Number of physical cores. Type: integer
  66 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  67 | | ...
  68 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  69 | | ...
  70 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  71 | | And Add PCI devices to all DUTs
  72 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  73 | | ... | ${s_25G} | ${framesize} | pps_limit=${s_18.75Mpps}
  74 | | And Add DPDK dev default RXD to all DUTs | 2048
  75 | | And Add DPDK dev default TXD to all DUTs | 2048
  76 | | And Apply startup configuration on all VPP DUTs
  77 | | When Initialize L2 patch
  78 | | Then Traffic should pass with maximum rate
  79 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  80
  81 *** Test Cases ***
  82 | tc01-64B-1c-eth-l2patch-mrr
  83 | | [Tags] | 64B | 1C
  84 | | framesize=${64} | phy_cores=${1}
  85
  86 | tc02-1518B-1c-eth-l2patch-mrr
  87 | | [Tags] | 1518B | 1C
  88 | | framesize=${1518} | phy_cores=${1}
  89
  90 | tc03-9000B-1c-eth-l2patch-mrr
  91 | | [Tags] | 9000B | 1C
  92 | | framesize=${9000} | phy_cores=${1}
  93
  94 | tc04-IMIX-1c-eth-l2patch-mrr
  95 | | [Tags] | IMIX | 1C
  96 | | framesize=IMIX_v4_1 | phy_cores=${1}
  97
  98 | tc05-64B-2c-eth-l2patch-mrr
  99 | | [Tags] | 64B | 2C
 100 | | framesize=${64} | phy_cores=${2}
 101
 102 | tc06-1518B-2c-eth-l2patch-mrr
 103 | | [Tags] | 1518B | 2C
 104 | | framesize=${1518} | phy_cores=${2}
 105
 106 | tc07-9000B-2c-eth-l2patch-mrr
 107 | | [Tags] | 9000B | 2C
 108 | | framesize=${9000} | phy_cores=${2}
 109
 110 | tc08-IMIX-2c-eth-l2patch-mrr
 111 | | [Tags] | IMIX | 2C
 112 | | framesize=IMIX_v4_1 | phy_cores=${2}
 113
 114 | tc09-64B-4c-eth-l2patch-mrr
 115 | | [Tags] | 64B | 4C
 116 | | framesize=${64} | phy_cores=${4}
 117
 118 | tc10-1518B-4c-eth-l2patch-mrr
 119 | | [Tags] | 1518B | 4C
 120 | | framesize=${1518} | phy_cores=${4}
 121
 122 | tc11-9000B-4c-eth-l2patch-mrr
 123 | | [Tags] | 9000B | 4C
 124 | | framesize=${9000} | phy_cores=${4}
 125
 126 | tc12-IMIX-4c-eth-l2patch-mrr
 127 | | [Tags] | IMIX | 4C
 128 | | framesize=IMIX_v4_1 | phy_cores=${4}