tests/vpp/perf/l2/2n1l-25ge2p1xxv710-eth-l2xcbase-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-XXV710 | ETH | L2XCFWD | BASE | L2XCBASE
  19 | ...
  20 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  21 | ... | L2 | Intel-XXV710
  22 | ...
  23 | Suite Teardown | Tear down 2-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | ...
  27 | Test Teardown | Tear down performance mrr test
  28 | ...
  29 | Test Template | Local Template
  30 | ...
  31 | Documentation | *Raw results L2XC test cases*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 cross connect.
  36 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 cross-connect.
  37 | ... | DUT1 tested with 2p25GE NIC XXV710 by Intel.
  38 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic
  39 | ... | at line rate and reports total received/sent packets over trial period.
  40 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  41 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  42 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  43 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  44 | ... | addresses of the TG node interfaces.
  45 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  46
  47 *** Variables ***
  48 # XXV710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  49 | ${s_24.5G}= | ${24500000000}
  50 # XXV710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  51 | ${s_18.75Mpps}= | ${18750000}
  52 # Traffic profile:
  53 | ${traffic_profile}= | trex-sl-2n-ethip4-ip4src254
  54
  55 *** Keywords ***
  56 | Local Template
  57 | | [Documentation]
  58 | | ... | [Cfg] DUT runs L2XC config.\
  59 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  60 | | ... | [Ver] Measure MaxReceivedRate for ${framesize} frames using single\
  61 | | ... | trial throughput test.
  62 | | ...
  63 | | ... | *Arguments:*
  64 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  65 | | ... |   Type: integer, string
  66 | | ... | - phy_cores - Number of physical cores. Type: integer
  67 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  68 | | ...
  69 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  70 | | ...
  71 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  72 | | And Add PCI devices to all DUTs
  73 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  74 | | ... | ${s_24.5G} | ${framesize} | pps_limit=${s_18.75Mpps}
  75 | | And Apply startup configuration on all VPP DUTs
  76 | | And Initialize L2 xconnect in 2-node circular topology
  77 | | Then Traffic should pass with maximum rate
  78 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  79
  80 *** Test Cases ***
  81 | tc01-64B-1c-eth-l2xcbase-mrr
  82 | | [Tags] | 64B | 1C
  83 | | framesize=${64} | phy_cores=${1}
  84
  85 | tc02-64B-2c-eth-l2xcbase-mrr
  86 | | [Tags] | 64B | 2C
  87 | | framesize=${64} | phy_cores=${2}
  88
  89 | tc03-64B-4c-eth-l2xcbase-mrr
  90 | | [Tags] | 64B | 4C
  91 | | framesize=${64} | phy_cores=${4}
  92
  93 | tc04-1518B-1c-eth-l2xcbase-mrr
  94 | | [Tags] | 1518B | 1C
  95 | | framesize=${1518} | phy_cores=${1}
  96
  97 | tc05-1518B-2c-eth-l2xcbase-mrr
  98 | | [Tags] | 1518B | 2C
  99 | | framesize=${1518} | phy_cores=${2}
 100
 101 | tc06-1518B-4c-eth-l2xcbase-mrr
 102 | | [Tags] | 1518B | 4C
 103 | | framesize=${1518} | phy_cores=${4}
 104
 105 | tc07-9000B-1c-eth-l2xcbase-mrr
 106 | | [Tags] | 9000B | 1C
 107 | | framesize=${9000} | phy_cores=${1}
 108
 109 | tc08-9000B-2c-eth-l2xcbase-mrr
 110 | | [Tags] | 9000B | 2C
 111 | | framesize=${9000} | phy_cores=${2}
 112
 113 | tc09-9000B-4c-eth-l2xcbase-mrr
 114 | | [Tags] | 9000B | 4C
 115 | | framesize=${9000} | phy_cores=${4}
 116
 117 | tc10-IMIX-1c-eth-l2xcbase-mrr
 118 | | [Tags] | IMIX | 1C
 119 | | framesize=IMIX_v4_1 | phy_cores=${1}
 120
 121 | tc11-IMIX-2c-eth-l2xcbase-mrr
 122 | | [Tags] | IMIX | 2C
 123 | | framesize=IMIX_v4_1 | phy_cores=${2}
 124
 125 | tc12-IMIX-4c-eth-l2xcbase-mrr
 126 | | [Tags] | IMIX | 4C
 127 | | framesize=IMIX_v4_1 | phy_cores=${4}