tests/vpp/perf/l2/40ge2p1xl710-eth-l2xcbase-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.InterfaceUtil
  17 | Library | resources.libraries.python.NodePath
  18 | ...
  19 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  20 | ... | NIC_Intel-XL710 | ETH | L2XCFWD | BASE
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L2 | Intel-XL710
  24 | ...
  25 | Suite Teardown | Tear down 3-node performance topology
  26 | ...
  27 | Test Setup | Set up performance test
  28 | ...
  29 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  30 | ... | ${framesize} | ${traffic_profile}
  31 | ...
  32 | Test Template | Local Template
  33 | ...
  34 | Documentation | *RFC2544: Pkt throughput L2XC test cases*
  35 | ...
  36 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  37 | ... | with single links between nodes.
  38 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 cross connect.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 cross-
  40 | ... | connect. DUT1 and DUT2 tested with 2p40GE NIC XL710 by Intel.
  41 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  42 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  43 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  44 | ... | of packets transmitted. NDR and PDR are discovered for different
  45 | ... | Ethernet L2 frame sizes using MLRsearch library.
  46 | ... | Test packets are generated by TG on
  47 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  48 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  49 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
  50 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  51 | ... | interfaces.
  52 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  53
  54 *** Variables ***
  55 # XL710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  56 | ${s_24.5G}= | ${24500000000}
  57 # XL710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  58 | ${s_18.75Mpps}= | ${18750000}
  59 # Traffic profile:
  60 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  61
  62 *** Keywords ***
  63 | Local Template
  64 | | [Documentation]
  65 | | ... | [Cfg] DUT runs L2XC config with ${phy_cores} phy
  66 | | ... | core(s).
  67 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  68 | | ...
  69 | | ... | *Arguments:*
  70 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  71 | | ... | Type: integer, string
  72 | | ... | - phy_cores - Number of physical cores. Type: integer
  73 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  74 | | ...
  75 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  76 | | ...
  77 | | Set Test Variable | ${framesize}
  78 | | Set Test Variable | ${min_rate} | ${10000}
  79 | | ...
  80 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  81 | | And Add PCI devices to all DUTs
  82 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  83 | | ... | ${s_24.5G} | ${framesize} | pps_limit=${s_18.75Mpps}
  84 | | And Add DPDK dev default RXD to all DUTs | 2048
  85 | | And Add DPDK dev default TXD to all DUTs | 2048
  86 | | And Apply startup configuration on all VPP DUTs
  87 | | When Initialize L2 xconnect in 3-node circular topology
  88 | | Then Find NDR and PDR intervals using optimized search
  89 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
  90
  91 *** Test Cases ***
  92 | tc01-64B-1c-eth-l2xcbase-ndrpdr
  93 | | [Tags] | 64B | 1C
  94 | | framesize=${64} | phy_cores=${1}
  95
  96 | tc02-64B-2c-eth-l2xcbase-ndrpdr
  97 | | [Tags] | 64B | 2C
  98 | | framesize=${64} | phy_cores=${2}
  99
 100 | tc03-64B-4c-eth-l2xcbase-ndrpdr
 101 | | [Tags] | 64B | 4C
 102 | | framesize=${64} | phy_cores=${4}
 103
 104 | tc04-1518B-1c-eth-l2xcbase-ndrpdr
 105 | | [Tags] | 1518B | 1C
 106 | | framesize=${1518} | phy_cores=${1}
 107
 108 | tc05-1518B-2c-eth-l2xcbase-ndrpdr
 109 | | [Tags] | 1518B | 2C
 110 | | framesize=${1518} | phy_cores=${2}
 111
 112 | tc06-1518B-4c-eth-l2xcbase-ndrpdr
 113 | | [Tags] | 1518B | 4C
 114 | | framesize=${1518} | phy_cores=${4}
 115
 116 | tc07-9000B-1c-eth-l2xcbase-ndrpdr
 117 | | [Tags] | 9000B | 1C
 118 | | framesize=${9000} | phy_cores=${1}
 119
 120 | tc08-9000B-2c-eth-l2xcbase-ndrpdr
 121 | | [Tags] | 9000B | 2C
 122 | | framesize=${9000} | phy_cores=${2}
 123
 124 | tc09-9000B-4c-eth-l2xcbase-ndrpdr
 125 | | [Tags] | 9000B | 4C
 126 | | framesize=${9000} | phy_cores=${4}
 127
 128 | tc10-IMIX-1c-eth-l2xcbase-ndrpdr
 129 | | [Tags] | IMIX | 1C
 130 | | framesize=IMIX_v4_1 | phy_cores=${1}
 131
 132 | tc11-IMIX-2c-eth-l2xcbase-ndrpdr
 133 | | [Tags] | IMIX | 2C
 134 | | framesize=IMIX_v4_1 | phy_cores=${2}
 135
 136 | tc12-IMIX-4c-eth-l2xcbase-ndrpdr
 137 | | [Tags] | IMIX | 4C
 138 | | framesize=IMIX_v4_1 | phy_cores=${4}