tests/vpp/perf/lb/2n1l-10ge2p1x710-ethip4-loadbalancer-l3dsr-ndrpdr.robot

   1 # Copyright (c) 2021 Intel and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | IP4 | LOADBALANCER_L3DSR | DRV_VFIO_PCI
  19 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  20 | ... | ethip4-loadbalancer-l3dsr
  21 |
  22 | Suite Setup | Setup suite topology interfaces | performance
  23 | Suite Teardown | Tear down suite | performance
  24 | Test Setup | Setup test | performance
  25 | Test Teardown | Tear down test | performance
  26 |
  27 | Test Template | Local Template
  28 |
  29 | Documentation | *RFC2544: Pkt throughput loadbalancer l3dsr test cases*
  30 |
  31 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology\
  32 | ... | with single links between nodes.
  33 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-UDP for LoadBalancer l3dsr.
  34 | ... | *[Cfg] DUT configuration:* DUT1 is configured with LoadBalancer\
  35 | ... | l3dsr and one static IPv4 /24 route entries. DUT1 tested with\
  36 | ... | ${nic_name}.
  37 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  38 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  39 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  40 | ... | of packets transmitted. NDR and PDR are discovered for different\
  41 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  42 | ... | Test packets are generated by TG on links to DUT. TG traffic profile\
  43 | ... | contains two L4 flow-groups (l3dsr use flow-group is only from TG\
  44 | ... | to DUT, 6 flows for flow-group) with all packets containing Ethernet\
  45 | ... | header, IPv4 header with IP protocol=17 and static payload. MAC\
  46 | ... | addresses are matching MAC addresses of the TG node interfaces.
  47 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  48
  49 *** Variables ***
  50 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so | lb_plugin.so
  51 | ${crypto_type}= | ${None}
  52 | ${nic_name}= | Intel-X710
  53 | ${nic_driver}= | vfio-pci
  54 | ${nic_rxq_size}= | 0
  55 | ${nic_txq_size}= | 0
  56 | ${nic_pfs}= | 2
  57 | ${nic_vfs}= | 0
  58 | ${osi_layer}= | L3
  59 | ${overhead}= | ${0}
  60 # Traffic profile:
  61 | ${traffic_profile}= | trex-stl-2n-ethip4udp-lb
  62 | ${traffic_directions}= | ${1}
  63
  64 *** Keywords ***
  65 | Local Template
  66 | | [Documentation]
  67 | | ... | [Cfg] DUT runs LoadBalancer l3dsr config.\
  68 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  69 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  70 | |
  71 | | ... | *Arguments:*
  72 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  73 | | ... | Type: integer, string
  74 | | ... | - phy_cores - Number of physical cores. Type: integer
  75 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  76 | |
  77 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  78 | |
  79 | | Set Test Variable | \${frame_size}
  80 | |
  81 | | Given Set Max Rate And Jumbo
  82 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  83 | | And Pre-initialize layer driver | ${nic_driver}
  84 | | And Apply startup configuration on all VPP DUTs
  85 | | When Initialize layer driver | ${nic_driver}
  86 | | And Initialize layer interface
  87 | | And Initialize loadbalancer l3dsr
  88 | | Then Find NDR and PDR intervals using optimized search
  89
  90 *** Test Cases ***
  91 | 64B-1c-ethip4-loadbalancer-l3dsr-ndrpdr
  92 | | [Tags] | 64B | 1C
  93 | | frame_size=${64} | phy_cores=${1}
  94
  95 | 64B-2c-ethip4-loadbalancer-l3dsr-ndrpdr
  96 | | [Tags] | 64B | 2C
  97 | | frame_size=${64} | phy_cores=${2}
  98
  99 | 64B-4c-ethip4-loadbalancer-l3dsr-ndrpdr
 100 | | [Tags] | 64B | 4C
 101 | | frame_size=${64} | phy_cores=${4}
 102
 103 | 1518B-1c-ethip4-loadbalancer-l3dsr-ndrpdr
 104 | | [Tags] | 1518B | 1C
 105 | | frame_size=${1518} | phy_cores=${1}
 106
 107 | 1518B-2c-ethip4-loadbalancer-l3dsr-ndrpdr
 108 | | [Tags] | 1518B | 2C
 109 | | frame_size=${1518} | phy_cores=${2}
 110
 111 | 1518B-4c-ethip4-loadbalancer-l3dsr-ndrpdr
 112 | | [Tags] | 1518B | 4C
 113 | | frame_size=${1518} | phy_cores=${4}
 114
 115 | 9000B-1c-ethip4-loadbalancer-l3dsr-ndrpdr
 116 | | [Tags] | 9000B | 1C
 117 | | frame_size=${9000} | phy_cores=${1}
 118
 119 | 9000B-2c-ethip4-loadbalancer-l3dsr-ndrpdr
 120 | | [Tags] | 9000B | 2C
 121 | | frame_size=${9000} | phy_cores=${2}
 122
 123 | 9000B-4c-ethip4-loadbalancer-l3dsr-ndrpdr
 124 | | [Tags] | 9000B | 4C
 125 | | frame_size=${9000} | phy_cores=${4}
 126
 127 | IMIX-1c-ethip4-loadbalancer-l3dsr-ndrpdr
 128 | | [Tags] | IMIX | 1C
 129 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 130
 131 | IMIX-2c-ethip4-loadbalancer-l3dsr-ndrpdr
 132 | | [Tags] | IMIX | 2C
 133 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 134
 135 | IMIX-4c-ethip4-loadbalancer-l3dsr-ndrpdr
 136 | | [Tags] | IMIX | 4C
 137 | | frame_size=IMIX_v4_1 | phy_cores=${4}