tests/vpp/perf/nfv_density/dcr_memif/chain_ipsec/10ge2p1x710-ethip4ipsec5000tnlsw-l2bd-1ch-16mif-8drc1c-vppip4-aes256gcm-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR | TNL_5000
  18 | ... | IPSEC | IPSECSW | IPSECINT | NIC_Intel-X710 | SCALE | 8DCR
  19 | ... | DOCKER | 2R1C | NF_DENSITY | CHAIN | NF_VPPIP4 | 1DCR1T
  20 | ... | AES_256_GCM | AES | DRV_VFIO_PCI
  21 |
  22 | Suite Setup | Setup suite single link | performance
  23 | Suite Teardown | Tear down suite | performance
  24 | Test Setup | Setup test
  25 | Test Teardown | Tear down test | performance | container
  26 |
  27 | Test Template | Local Template
  28 |
  29 | Documentation | **RFC2544: Pkt throughput L2BD test cases with memif 1 chain
  30 | ... | 8 docker container*
  31 |
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 bridge domain.
  35 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  36 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  37 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  38 | ... | of packets transmitted. NDR and PDR are discovered for different\
  39 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  40 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  41 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  42 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  43 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  44 | ... | addresses of the TG node interfaces.
  45 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  46
  47 *** Variables ***
  48 | @{plugins_to_enable}= | dpdk_plugin.so | memif_plugin.so
  49 | ... | crypto_ia32_plugin.so | crypto_ipsecmb_plugin.so
  50 | ... | crypto_openssl_plugin.so
  51 | ${crypto_type}= | ${None}
  52 | ${nic_name}= | Intel-X710
  53 | ${nic_driver}= | vfio-pci
  54 | ${osi_layer}= | L3
  55 | ${overhead}= | ${54}
  56 | ${tg_if1_ip4}= | 192.168.10.254
  57 | ${dut1_if1_ip4}= | 192.168.10.1
  58 | ${dut1_if2_ip4}= | 100.0.0.254
  59 | ${dut2_if1_ip4}= | 200.0.0.1
  60 | ${dut2_if2_ip4}= | 192.168.20.1
  61 | ${tg_if2_ip4}= | 192.168.20.254
  62 | ${raddr_ip4}= | 20.0.0.0
  63 | ${laddr_ip4}= | 10.0.0.0
  64 | ${addr_range}= | ${24}
  65 | ${n_instances}= | ${8}
  66 | ${n_tunnels}= | ${5000}
  67 | ${nf_dtcr}= | ${1}
  68 | ${nf_dtc}= | ${1}
  69 # Traffic profile:
  70 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}-${n_instances}cnf
  71 # Container
  72 | ${container_engine}= | Docker
  73 | ${container_chain_topology}= | chain_ipsec
  74
  75 *** Keywords ***
  76 | Local Template
  77 | | [Documentation]
  78 | | ... | [Cfg] DUT1 runs IPSec tunneling AES_256_GCM config to ${n_instances}.
  79 | | ... | containers.
  80 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  81 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  82 | |
  83 | | ... | *Arguments:*
  84 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  85 | | ... | Type: integer, string
  86 | | ... | - phy_cores - Number of physical cores. Type: integer
  87 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  88 | |
  89 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  90 | |
  91 | | Set Test Variable | \${frame_size}
  92 | |
  93 | | # These are enums (not strings) so they cannot be in Variables table.
  94 | | ${encr_alg}= | Crypto Alg AES GCM 256
  95 | | ${auth_alg}= | Set Variable | ${None}
  96 | | ${ipsec_proto} = | IPsec Proto ESP
  97 | |
  98 | | Given Set Max Rate And Jumbo
  99 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
 100 | | And Pre-initialize layer driver | ${nic_driver}
 101 | | And Apply startup configuration on all VPP DUTs
 102 | | When Initialize layer driver | ${nic_driver}
 103 | | And Initialize IPSec in 3-node circular topology
 104 | | And Stop VPP service on all DUTs | ${nodes}
 105 | | And VPP IPsec Create Tunnel Interfaces in Containers
 106 | | ... | ${nodes} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${dut1_if2}
 107 | | ... | ${dut2_if1} | ${n_tunnels} | ${encr_alg} | ${auth_alg}
 108 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range} | ${n_instances}
 109 | | And Start containers for test
 110 | | ... | nf_chains=${1} | nf_nodes=${n_instances} | auto_scale=${False}
 111 | | ... | pinning=${False}
 112 | | And Start vswitch in container | phy_cores=${phy_cores} | rx_queues=${rxq}
 113 | | Then Find NDR and PDR intervals using optimized search
 114
 115 *** Test Cases ***
 116 | tc01-64B-1c-ethip4ipsec5000tnlsw-l2bd-1ch-16mif-8drc1c-vppip4-aes256gcm-ndrpdr
 117 | | [Tags] | 64B | 1C
 118 | | frame_size=${64} | phy_cores=${1}
 119
 120 | tc02-64B-2c-ethip4ipsec5000tnlsw-l2bd-1ch-16mif-8drc1c-vppip4-aes256gcm-ndrpdr
 121 | | [Tags] | 64B | 2C
 122 | | frame_size=${64} | phy_cores=${2}
 123
 124 | tc03-64B-4c-ethip4ipsec5000tnlsw-l2bd-1ch-16mif-8drc1c-vppip4-aes256gcm-ndrpdr
 125 | | [Tags] | 64B | 4C
 126 | | frame_size=${64} | phy_cores=${4}
 127
 128 | tc04-1518B-1c-ethip4ipsec5000tnlsw-l2bd-1ch-16mif-8drc1c-vppip4-aes256gcm-ndrpdr
 129 | | [Tags] | 1518B | 1C
 130 | | frame_size=${1518} | phy_cores=${1}
 131
 132 | tc05-1518B-2c-ethip4ipsec5000tnlsw-l2bd-1ch-16mif-8drc1c-vppip4-aes256gcm-ndrpdr
 133 | | [Tags] | 1518B | 2C
 134 | | frame_size=${1518} | phy_cores=${2}
 135
 136 | tc06-1518B-4c-ethip4ipsec5000tnlsw-l2bd-1ch-16mif-8drc1c-vppip4-aes256gcm-ndrpdr
 137 | | [Tags] | 1518B | 4C
 138 | | frame_size=${1518} | phy_cores=${4}
 139
 140 | tc10-IMIX-1c-ethip4ipsec5000tnlsw-l2bd-1ch-16mif-8drc1c-vppip4-aes256gcm-ndrpdr
 141 | | [Tags] | IMIX | 1C
 142 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 143
 144 | tc11-IMIX-2c-ethip4ipsec5000tnlsw-l2bd-1ch-16mif-8drc1c-vppip4-aes256gcm-ndrpdr
 145 | | [Tags] | IMIX | 2C
 146 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 147
 148 | tc12-IMIX-4c-ethip4ipsec5000tnlsw-l2bd-1ch-16mif-8drc1c-vppip4-aes256gcm-ndrpdr
 149 | | [Tags] | IMIX | 4C
 150 | | frame_size=IMIX_v4_1 | phy_cores=${4}