tests/vpp/perf/nfv_density/vm_vhost/chain/2n-10ge2p1x710-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | L2BDMACLRN | BASE | VHOST | VM
  19 | ... | VHOST_1024 | NF_DENSITY | NF_VPPIP4 | CHAIN | 1R2C | 2VM2T
  20 | ...
  21 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  22 | ... | L3 | ${nic_name}
  23 | Suite Teardown | Tear down 2-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance test with vhost
  27 | ...
  28 | Test Template | Local Template
  29 | ...
  30 | Documentation
  31 | ... | *RFC2544: Pkt throughput L2BD test cases with 4 vhost 1 chain 2 VMs*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology\
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  36 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 bridge-\
  37 | ... | domain and MAC learning enabled. Qemu VNFs are connected to VPP via\
  38 | ... | vhost-user interfaces. Guest is running VPP IPv4 interconnecting \
  39 | ... | vhost-user interfaces, rxd/txd=1024. DUT1 is tested with ${nic_name}.
  40 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  41 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  42 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  43 | ... | of packets transmitted. NDR and PDR are discovered for different\
  44 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  45 | ... | Test packets are generated by TG on\
  46 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  47 | ... | (flow-group per direction, 254 flows per flow-group) with all packets\
  48 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static\
  49 | ... | payload. MAC addresses are matching MAC addresses of NFs nodes\
  50 | ... | interfaces.
  51 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  52
  53 *** Variables ***
  54 | ${nic_name}= | Intel-X710
  55 | ${overhead}= | ${0}
  56 | ${nf_dtcr}= | ${1}
  57 | ${nf_dtc}= | ${1}
  58 # Traffic profile:
  59 | ${traffic_profile}= | trex-sl-2n3n-ethip4-ip4src254-1c2n
  60
  61 *** Keywords ***
  62 | Local Template
  63 | | [Documentation]
  64 | | ... | [Cfg] DUT runs L2BD switching config.
  65 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  66 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  67 | | ...
  68 | | ... | *Arguments:*
  69 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  70 | | ... | Type: integer, string
  71 | | ... | - phy_cores - Number of physical cores. Type: integer
  72 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  73 | | ...
  74 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  75 | | ...
  76 | | Set Test Variable | \${frame_size}
  77 | | ...
  78 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  79 | | And Add PCI devices to all DUTs
  80 | | Set Max Rate And Jumbo And Handle Multi Seg
  81 | | And Apply startup configuration on all VPP DUTs
  82 | | When Initialize L2 bridge domains for multiple chains with Vhost-User
  83 | | ... | nf_chains=${1} | nf_nodes=${2}
  84 | | And Configure chains of NFs connected via vhost-user
  85 | | ... | nf_chains=${1} | nf_nodes=${2} | jumbo=${jumbo}
  86 | | ... | use_tuned_cfs=${False} | auto_scale=${False} | vnf=vpp_chain_ip4
  87 | | Then Find NDR and PDR intervals using optimized search
  88
  89 *** Test Cases ***
  90 | tc01-64B-1c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
  91 | | [Tags] | 64B | 1C
  92 | | frame_size=${64} | phy_cores=${1}
  93
  94 | tc02-64B-2c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
  95 | | [Tags] | 64B | 2C
  96 | | frame_size=${64} | phy_cores=${2}
  97
  98 | tc03-64B-4c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
  99 | | [Tags] | 64B | 4C
 100 | | frame_size=${64} | phy_cores=${4}
 101
 102 | tc04-1518B-1c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
 103 | | [Tags] | 1518B | 1C
 104 | | frame_size=${1518} | phy_cores=${1}
 105
 106 | tc05-1518B-2c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
 107 | | [Tags] | 1518B | 2C
 108 | | frame_size=${1518} | phy_cores=${2}
 109
 110 | tc06-1518B-4c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
 111 | | [Tags] | 1518B | 4C
 112 | | frame_size=${1518} | phy_cores=${4}
 113
 114 | tc07-9000B-1c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
 115 | | [Tags] | 9000B | 1C
 116 | | frame_size=${9000} | phy_cores=${1}
 117
 118 | tc08-9000B-2c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
 119 | | [Tags] | 9000B | 2C
 120 | | frame_size=${9000} | phy_cores=${2}
 121
 122 | tc09-9000B-4c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
 123 | | [Tags] | 9000B | 4C
 124 | | frame_size=${9000} | phy_cores=${4}
 125
 126 | tc10-IMIX-1c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
 127 | | [Tags] | IMIX | 1C
 128 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 129
 130 | tc11-IMIX-2c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
 131 | | [Tags] | IMIX | 2C
 132 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 133
 134 | tc12-IMIX-4c-eth-l2bd-1ch-4vh-2vm2t-vppip4-ndrpdr
 135 | | [Tags] | IMIX | 4C
 136 | | frame_size=IMIX_v4_1 | phy_cores=${4}