tests/vpp/perf/nfv_density/vm_vhost/chain_dot1qip4vxlan/2n-10ge2p1x710-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | RECONF
  18 | ... | NIC_Intel-X710 | L2BDMACLRN | ENCAP | VXLAN | L2OVRLAY | IP4UNRLAY
  19 | ... | VHOST | VM | VHOST_1024 | VXLAN | DOT1Q | NF_DENSITY | NF_TESTPMD
  20 | ... | CHAIN | 1R1C | 1_ADDED_CHAIN | 1VM2T | DRV_VFIO_PCI
  21 | ... | dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd
  22 |
  23 | Suite Setup | Setup suite single link | performance
  24 | Suite Teardown | Tear down suite | performance
  25 | Test Setup | Setup test
  26 | Test Teardown | Tear down test | performance | vhost
  27 |
  28 | Test Template | Local Template
  29 |
  30 | Documentation | *RFC2544: Packet loss L2BD test cases with Dot1Q and
  31 | ... | VXLANoIPv4 with ${nf_chains} instances, ${nf_nodes} VMs per instance.*
  32 |
  33 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology\
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Dot1q-IPv4-UDP-VXLAN-Eth-IPv4 for L2\
  36 | ... | switching of IPv4. Dot1q-IPv4-UDP-VXLAN-Eth-IPv4 is applied on link\
  37 | ... | between DUT1 and TG.
  38 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 bridge-\
  39 | ... | domain and MAC learning enabled. Qemu VNFs are connected\
  40 | ... | to VPP via vhost-user interfaces. Guest is running testpmd l2xc\
  41 | ... | interconnecting vhost-user interfaces, rxd/txd=1024. DUT1 is\
  42 | ... | tested with ${nic_name}.
  43 | ... | *[Ver] TG verification:* TG finds and throughput NDR (Non Drop\
  44 | ... | Rate) with zero packet loss tolerance, then measured loss at this load\
  45 | ... | while additional chain is configured.\
  46 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile\
  47 | ... | contains two L3 flow-groups (flow-group per direction, 256 flows per\
  48 | ... | flow-group) with all packets containing Ethernet header with .1Q, IPv4\
  49 | ... | header, UPD header, VXLAN header and static payload. MAC addresses are\
  50 | ... | matching MAC addresses of the TG node interfaces.
  51 | ... | *[Ref] Applicable standard specifications:* RFC2544, RFC7348.
  52
  53 *** Variables ***
  54 | @{plugins_to_enable}= | dpdk_plugin.so
  55 | ${crypto_type}= | ${None}
  56 | ${nic_name}= | Intel-X710
  57 | ${nic_driver}= | vfio-pci
  58 | ${osi_layer}= | L3
  59 | ${overhead}= | ${54}
  60 | ${nf_dtcr}= | ${1}
  61 | ${nf_dtc}= | ${1}
  62 | ${nf_chains}= | ${1}
  63 | ${nf_added_chains}= | ${1}
  64 | ${nf_nodes}= | ${1}
  65 # Traffic profile:
  66 | ${traffic_profile}=
  67 | ... | trex-sl-dot1qip4vxlan-ip4src${nf_chains}udpsrcrnd
  68
  69 *** Keywords ***
  70 | Local Template
  71 | | [Documentation]
  72 | | ... | [Cfg] DUT runs Dot1Q-IP4-Vxlan L2BD switching config.\
  73 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  74 | | ... | [Ver] Measure packet loss during reconfig at NDR load.\
  75 | |
  76 | | ... | *Arguments:*
  77 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  78 | | ... | Type: integer, string
  79 | | ... | - phy_cores - Number of worker threads to be used. Type: integer
  80 | | ... | - rxq - Number of Rx queues to be used. Type: integer
  81 | |
  82 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  83 | |
  84 | | Set Test Variable | \${frame_size}
  85 | |
  86 | | ${nf_total_chains}= | Evaluate | ${nf_chains} + ${nf_added_chains}
  87 | | Given Set Max Rate And Jumbo
  88 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  89 | | And Pre-initialize layer driver | ${nic_driver}
  90 | | And Apply startup configuration on all VPP DUTs
  91 | | When Initialize layer driver | ${nic_driver}
  92 | | And Initialize layer interface
  93 | | ... | count=${nf_total_chains}
  94 | | And Initialize layer dot1q
  95 | | ... | count=${nf_chains} | vlan_per_chain=${False}
  96 | | And Initialize layer ip4vxlan
  97 | | ... | count=${nf_chains}
  98 | | And Initialize L2 bridge domains for multiple chains with Vhost-User
  99 | | ... | nf_chains=${nf_chains} | nf_nodes=${nf_nodes}
 100 | | And Configure chains of NFs connected via vhost-user
 101 | | ... | nf_chains=${nf_chains} | nf_nodes=${nf_nodes} | jumbo=${jumbo}
 102 | | ... | use_tuned_cfs=${False} | auto_scale=${False} | vnf=testpmd_io
 103 | | ${bidirectional_throughput}= | Find Throughput Using MLRsearch
 104 | | ${unidirectional_throughput}= | Evaluate | ${bidirectional_throughput} / 2.0
 105 | | Start Traffic on Background | ${unidirectional_throughput}pps
 106 | | And Initialize layer dot1q
 107 | | ... | count=${nf_total_chains} | vlan_per_chain=${False}
 108 | | ... | start=${nf_chains+1}
 109 | | And Initialize layer ip4vxlan
 110 | | ... | count=${nf_total_chains} | start=${nf_chains+1}
 111 | | And Initialize L2 bridge domains for multiple chains with Vhost-User
 112 | | ... | nf_chains=${nf_total_chains} | nf_nodes=${nf_nodes}
 113 | | ... | start=${nf_chains+1}
 114 | | ${result}= | Stop Running Traffic
 115 | | Display Reconfig Test Message | ${result}
 116
 117 *** Test Cases ***
 118 | tc01-118B-1c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 119 | | [Tags] | 118B | 1C
 120 | | frame_size=${118} | phy_cores=${1}
 121
 122 | tc02-118B-2c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 123 | | [Tags] | 118B | 2C
 124 | | frame_size=${118} | phy_cores=${2}
 125
 126 | tc03-118B-4c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 127 | | [Tags] | 118B | 4C
 128 | | frame_size=${118} | phy_cores=${4}
 129
 130 | tc04-1518B-1c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 131 | | [Tags] | 1518B | 1C
 132 | | frame_size=${1518} | phy_cores=${1}
 133
 134 | tc05-1518B-2c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 135 | | [Tags] | 1518B | 2C
 136 | | frame_size=${1518} | phy_cores=${2}
 137
 138 | tc06-1518B-4c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 139 | | [Tags] | 1518B | 4C
 140 | | frame_size=${1518} | phy_cores=${4}
 141
 142 | tc07-9000B-1c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 143 | | [Tags] | 9000B | 1C
 144 | | frame_size=${9000} | phy_cores=${1}
 145
 146 | tc08-9000B-2c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 147 | | [Tags] | 9000B | 2C
 148 | | frame_size=${9000} | phy_cores=${2}
 149
 150 | tc09-9000B-4c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 151 | | [Tags] | 9000B | 4C
 152 | | frame_size=${9000} | phy_cores=${4}
 153
 154 | tc10-IMIX-1c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 155 | | [Tags] | IMIX | 1C
 156 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 157
 158 | tc11-IMIX-2c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 159 | | [Tags] | IMIX | 2C
 160 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 161
 162 | tc12-IMIX-4c-dot1qip4vxlan-l2bd-1ch-1ach-2vh-1vm2t-testpmd-reconf
 163 | | [Tags] | IMIX | 4C
 164 | | frame_size=IMIX_v4_1 | phy_cores=${4}