tests/vpp/perf/srv6/10ge2p1x520-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X520-DA2 | SRv6 | IP6FWD | FEATURE | SRv6_PROXY
  19 | ... | SRv6_PROXY_STAT | MEMIF | LXC
  20 | ...
  21 | Suite Setup | Run Keywords
  22 | ... | Set up 3-node performance topology with DUT's NIC model | L3
  23 | ... | Intel-X520-DA2
  24 | ... | AND | Set up performance test suite with MEMIF
  25 | ... | AND | Set up performance test suite with Static SRv6 proxy
  26 | ...
  27 | Suite Teardown | Tear down 3-node performance topology
  28 | ...
  29 | Test Setup | Set up performance test
  30 | ...
  31 | Test Teardown | Run Keywords
  32 | ... | Tear down performance test with SRv6 with encapsulation
  33 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  34 | ... | AND | Tear down performance test with container
  35 | ...
  36 | Test Template | Local Template
  37 | ...
  38 | Documentation | *Packet throughput Segment routing over IPv6 dataplane with\
  39 | ... | Static SRv6 proxy test cases*
  40 | ...
  41 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  42 | ... | with single links between nodes.
  43 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-SRH-IPv6 on DUT1-DUT2 and\
  44 | ... | DUTn->TG, Eth-IPv6 on TG->DUTn and DUTn-LXC for IPv6 routing over SRv6.
  45 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
  46 | ... | routing and static route, SR policy and steering policy for one\
  47 | ... | direction and one SR behaviour (function) - End.AS - for other\
  48 | ... | direction. DUT1 and DUT2 are tested with 2p10GE NIC X520 Niantic\
  49 | ... | by Intel.
  50 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  51 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  52 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  53 | ... | of packets transmitted. NDR and PDR are discovered for different\
  54 | ... | Ethernet L2 frame sizes using MLRsearch library\
  55 | ... | Test packets are generated by TG on\
  56 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  57 | ... | (flow-group per direction, 253 flows per flow-group) with\
  58 | ... | all packets containing Ethernet header,IPv6 header with static payload.\
  59 | ... | MAC addresses are matching MAC addresses of the TG node interfaces.
  60 | ... | *[Ref] Applicable standard specifications:* SRv6 Network Programming -\
  61 | ... | draft 3 and Segment Routing for Service Chaining - internet draft 01.
  62
  63 *** Variables ***
  64 # X520-DA2 bandwidth limit
  65 | ${s_limit}= | ${10000000000}
  66 # SIDs
  67 | ${dut1_sid1}= | 2002:1::
  68 | ${dut1_sid2}= | 2003:2::
  69 | ${dut1_bsid}= | 2002:1::1
  70 | ${dut2_sid1}= | 2002:2::
  71 | ${dut2_sid1}= | 2002:2::
  72 | ${dut2_sid2}= | 2003:1::
  73 | ${dut2_bsid}= | 2003:1::1
  74 | ${out_sid1_1}= | 2002:3::
  75 | ${out_sid1_2}= | 2002:4::
  76 | ${out_sid2_1}= | 2003:3::
  77 | ${out_sid2_2}= | 2003:4::
  78 | ${sid_prefix}= | ${64}
  79 # IP settings
  80 | ${tg_if1_ip6_subnet}= | 2001:1::
  81 | ${tg_if2_ip6_subnet}= | 2001:2::
  82 | ${dst_addr_nr}= | ${1}
  83 | ${dut1_if1_ip6}= | 2001:1::1
  84 | ${dut1_if2_ip6}= | 2001:3::1
  85 | ${dut1-memif-1-if1_ip6}= | 3001:1::1
  86 | ${dut1-memif-1-if2_ip6}= | 3001:1::2
  87 | ${dut1_nh}= | 4002::
  88 | ${dut2_if1_ip6}= | 2001:3::2
  89 | ${dut2_if2_ip6}= | 2001:2::1
  90 | ${dut2-memif-1-if1_ip6}= | 3002:1::1
  91 | ${dut2-memif-1-if2_ip6}= | 3002:1::2
  92 | ${dut2_nh}= | 4001::
  93 | ${prefix}= | ${64}
  94 # outer IPv6 header + SRH with 3 SIDs: 40+(8+3*16)B
  95 | ${srv6_overhead_3sids}= | ${96}
  96 # Traffic profile:
  97 | ${traffic_profile}= | trex-sl-3n-ethip6-ip6src253
  98 # Container
  99 | ${container_engine}= | LXC
 100 | ${container_chain_topology}= | chain
 101
 102 *** Keywords ***
 103 | Local Template
 104 | | [Documentation]
 105 | | ... | [Cfg] DUT1 and DUT2 are configured with IPv6\
 106 | | ... | routing and static route, SR policy and steering policy for one\
 107 | | ... | direction and one SR behaviour (function) - End - for other direction.
 108 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
 109 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.
 110 | | ...
 111 | | ... | *Arguments:*
 112 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
 113 | | ... |   Type: integer, string
 114 | | ... | - phy_cores - Number of physical cores. Type: integer
 115 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
 116 | | ...
 117 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
 118 | | ...
 119 | | Set Test Variable | ${framesize}
 120 | | Set Test Variable | ${min_rate} | ${10000}
 121 | | ...
 122 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
 123 | | And Add PCI devices to all DUTs
 124 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
 125 | | ... | ${s_limit} | ${framesize} | overhead=${srv6_overhead_3sids}
 126 | | And Apply startup configuration on all VPP DUTs
 127 | | And Set up performance test with containers | nf_chains=${1} | nf_nodes=${1}
 128 | | When Initialize IPv6 forwarding over SRv6 with endpoint to SR-unaware Service Function via 'static_proxy' behaviour in 3-node circular topology
 129 | | Then Find NDR and PDR intervals using optimized search
 130 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 131
 132 *** Test Cases ***
 133 | tc01-78B-1c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 134 | | [Tags] | 78B | 1C
 135 | | framesize=${78} | phy_cores=${1}
 136
 137 | tc02-78B-2c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 138 | | [Tags] | 78B | 2C
 139 | | framesize=${78} | phy_cores=${2}
 140
 141 | tc03-78B-4c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 142 | | [Tags] | 78B | 4C
 143 | | framesize=${78} | phy_cores=${4}
 144
 145 | tc04-1518B-1c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 146 | | [Tags] | 1518B | 1C
 147 | | framesize=${1518} | phy_cores=${1}
 148
 149 | tc05-1518B-2c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 150 | | [Tags] | 1518B | 2C
 151 | | framesize=${1518} | phy_cores=${2}
 152
 153 | tc06-1518B-4c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 154 | | [Tags] | 1518B | 4C
 155 | | framesize=${1518} | phy_cores=${4}
 156
 157 | tc07-9000B-1c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 158 | | [Tags] | 9000B | 1C
 159 | | framesize=${9000} | phy_cores=${1}
 160
 161 | tc08-9000B-2c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 162 | | [Tags] | 9000B | 2C
 163 | | framesize=${9000} | phy_cores=${2}
 164
 165 | tc09-9000B-4c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 166 | | [Tags] | 9000B | 4C
 167 | | framesize=${9000} | phy_cores=${4}
 168
 169 | tc10-IMIX-1c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 170 | | [Tags] | IMIX | 1C
 171 | | framesize=IMIX_v4_1 | phy_cores=${1}
 172
 173 | tc11-IMIX-2c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 174 | | [Tags] | IMIX | 2C
 175 | | framesize=IMIX_v4_1 | phy_cores=${2}
 176
 177 | tc12-IMIX-4c-ethip6srhip6-ip6base-srv6proxy-stat-ndrpdr
 178 | | [Tags] | IMIX | 4C
 179 | | framesize=IMIX_v4_1 | phy_cores=${4}