tests/vpp/perf/vm_vhost/10ge2p1x520-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X520-DA2 | DOT1Q | L2BDMACLRN | BASE | VHOST | 1VM
  20 | ... | VHOST_1024 | LBOND | LBOND_VPP | LBOND_MODE_LACP | LBOND_LB_L34
  21 | ...
  22 | Suite Setup | Run Keywords
  23 | ... | Set up 3-node performance topology with DUT's NIC model | L2
  24 | ... | Intel-X520-DA2
  25 | ... | AND | Set up performance test suite with LACP mode link bonding
  26 | ...
  27 | Suite Teardown | Tear down 3-node performance topology
  28 | ...
  29 | Test Setup | Set up performance test
  30 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  31 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  32 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  33 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  34 | ...
  35 | Test Template | Local Template
  36 | ...
  37 | Documentation | *RFC2544: Pkt throughput L2BD test cases with vhost and vpp link bonding*
  38 | ...
  39 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  40 | ... | with single links between nodes.
  41 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. 802.1q
  42 | ... | tagging is applied on link between DUT1 and DUT2.
  43 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with VPP
  44 | ... | link bonding (mode LACP, transmit policy l34) on link between DUT1 and
  45 | ... | DUT2 and L2 bridge-domain with MAC learning enabled. Qemu Guest is
  46 | ... | connected to VPP via vhost-user interfaces. Guest is running DPDK
  47 | ... | testpmd interconnecting vhost-user interfaces using 5 cores pinned to
  48 | ... | cpus 5-9 and 2048M memory. Testpmd is using socket-mem=1024M (512x2M
  49 | ... | hugepages), 5 cores (1 main core and 4 cores dedicated for io),
  50 | ... | forwarding mode is set to io, rxd/txd=1024, burst=64. DUT1, DUT2 are
  51 | ... | tested with 2p10GE NIC X520 Niantic by Intel.
  52 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  53 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  54 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  55 | ... | of packets transmitted. NDR and PDR are discovered for different
  56 | ... | Ethernet L2 frame sizes using MLRsearch library.
  57 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  58 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  59 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  60 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  61 | ... | addresses of the TG node interfaces.
  62
  63 *** Variables ***
  64 | ${subid}= | 10
  65 | ${tag_rewrite}= | pop-1
  66 | ${overhead}= | ${4}
  67 # Link bonding config
  68 | ${bond_mode}= | lacp
  69 | ${lb_mode}= | l34
  70 # Socket names
  71 | ${bd_id1}= | 1
  72 | ${bd_id2}= | 2
  73 | ${sock1}= | /tmp/sock-1-${bd_id1}
  74 | ${sock2}= | /tmp/sock-1-${bd_id2}
  75 # X520-DA2 bandwidth limit
  76 | ${s_limit}= | ${10000000000}
  77 # Traffic profile:
  78 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  79
  80 *** Keywords ***
  81 | Local Template
  82 | | [Documentation]
  83 | | ... | [Cfg] DUT runs L2BD switching config.
  84 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  85 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  86 | | ...
  87 | | ... | *Arguments:*
  88 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  89 | | ... | Type: integer, string
  90 | | ... | - phy_cores - Number of physical cores. Type: integer
  91 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  92 | | ...
  93 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  94 | | ...
  95 | | Set Test Variable | ${framesize}
  96 | | Set Test Variable | ${min_rate} | ${10000}
  97 | | ${dut1_vm_refs}= | Create Dictionary
  98 | | ${dut2_vm_refs}= | Create Dictionary
  99 | | Set Test Variable | ${dut1_vm_refs}
 100 | | Set Test Variable | ${dut2_vm_refs}
 101 | | ...
 102 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
 103 | | And Add PCI devices to all DUTs
 104 | | And Add VLAN Strip Offload switch off between DUTs in 3-node single link topology
 105 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
 106 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
 107 | | And Apply startup configuration on all VPP DUTs
 108 | | When Initialize L2 bridge domains with Vhost-User and VLAN with VPP link bonding in a 3-node circular topology
 109 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
 110 | | ... | ${tag_rewrite} | ${bond_mode} | ${lb_mode}
 111 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 112 | | ... | DUT1 | ${sock1} | ${sock2} | DUT1_VM1 | jumbo=${jumbo}
 113 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 114 | | And Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 115 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 116 | | ... | DUT2 | ${sock1} | ${sock2} | DUT2_VM1 | jumbo=${jumbo}
 117 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 118 | | And Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 119 | | And All Vpp Interfaces Ready Wait | ${nodes}
 120 | | Then Find NDR and PDR intervals using optimized search
 121 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 122
 123 *** Test Cases ***
 124 | tc01-64B-1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 125 | | [Tags] | 64B | 1C
 126 | | framesize=${64} | phy_cores=${1}
 127
 128 | tc02-64B-2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 129 | | [Tags] | 64B | 2C
 130 | | framesize=${64} | phy_cores=${2}
 131
 132 | tc03-64B-4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 133 | | [Tags] | 64B | 4C
 134 | | framesize=${64} | phy_cores=${4}
 135
 136 | tc04-1518B-1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 137 | | [Tags] | 1518B | 1C
 138 | | framesize=${1518} | phy_cores=${1}
 139
 140 | tc05-1518B-2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 141 | | [Tags] | 1518B | 2C
 142 | | framesize=${1518} | phy_cores=${2}
 143
 144 | tc06-1518B-4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 145 | | [Tags] | 1518B | 4C
 146 | | framesize=${1518} | phy_cores=${4}
 147
 148 | tc07-9000B-1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 149 | | [Tags] | 9000B | 1C
 150 | | framesize=${9000} | phy_cores=${1}
 151
 152 | tc08-9000B-2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 153 | | [Tags] | 9000B | 2C
 154 | | framesize=${9000} | phy_cores=${2}
 155
 156 | tc09-9000B-4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 157 | | [Tags] | 9000B | 4C
 158 | | framesize=${9000} | phy_cores=${4}
 159
 160 | tc10-IMIX-1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 161 | | [Tags] | IMIX | 1C
 162 | | framesize=IMIX_v4_1 | phy_cores=${1}
 163
 164 | tc11-IMIX-2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 165 | | [Tags] | IMIX | 2C
 166 | | framesize=IMIX_v4_1 | phy_cores=${2}
 167
 168 | tc12-IMIX-4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 169 | | [Tags] | IMIX | 4C
 170 | | framesize=IMIX_v4_1 | phy_cores=${4}