tests/vpp/perf/vm_vhost/10ge2p1x520-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | NIC_Intel-X520-DA2 | DOT1Q | L2BDMACLRN | BASE | VHOST | 1VM
  20 | ... | VHOST_1024
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L2 | Intel-X520-DA2
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance mrr test with vhost and VM with dpdk-testpmd
  28 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  29 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  30 | ...
  31 | Test Template | Local Template
  32 | ...
  33 | Documentation | *Raw results L2BD test cases with vhost*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. 802.1q
  38 | ... | tagging is applied on link between DUT1 and DUT2.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
  40 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via
  41 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting
  42 | ... | vhost-user interfaces using 5 cores pinned to cpus 5-9 and 2048M
  43 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
  44 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
  45 | ... | io, rxd/txd=1024, burst=64. DUT1, DUT2 are tested with 2p10GE NIC X520
  46 | ... | Niantic by Intel.
  47 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  48 | ... | at line rate and reports total received/sent packets over trial period.
  49 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  50 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  51 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  52 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  53 | ... | addresses of the TG node interfaces.
  54
  55 *** Variables ***
  56 | ${perf_qemu_qsz}= | 1024
  57 | ${subid}= | 10
  58 | ${tag_rewrite}= | pop-1
  59 | ${overhead}= | ${4}
  60 # Socket names
  61 | ${bd_id1}= | 1
  62 | ${bd_id2}= | 2
  63 | ${sock1}= | /tmp/sock-1-${bd_id1}
  64 | ${sock2}= | /tmp/sock-1-${bd_id2}
  65 # X520-DA2 bandwidth limit
  66 | ${s_limit}= | ${10000000000}
  67 # Traffic profile:
  68 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  69
  70 *** Keywords ***
  71 | Local Template
  72 | | [Documentation]
  73 | | ... | [Cfg] DUT runs L2BD switching config.
  74 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  75 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  76 | | ... | trial throughput test.
  77 | | ...
  78 | | ... | *Arguments:*
  79 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  80 | | ... | Type: integer, string
  81 | | ... | - phy_cores - Number of physical cores. Type: integer
  82 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  83 | | ...
  84 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  85 | | ...
  86 | | ${dut1_vm_refs}= | Create Dictionary
  87 | | ${dut2_vm_refs}= | Create Dictionary
  88 | | Set Test Variable | ${dut1_vm_refs}
  89 | | Set Test Variable | ${dut2_vm_refs}
  90 | | ...
  91 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  92 | | And Add PCI devices to all DUTs
  93 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  94 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  95 | | And Apply startup configuration on all VPP DUTs
  96 | | When Initialize L2 bridge domains with Vhost-User and VLAN in a 3-node circular topology
  97 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
  98 | | ... | ${tag_rewrite}
  99 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 100 | | ... | ${dut1} | ${sock1} | ${sock2} | DUT1_VM1
 101 | | ... | jumbo_frames=${jumbo}
 102 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 103 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 104 | | ... | ${dut2} | ${sock1} | ${sock2} | DUT2_VM1
 105 | | ... | jumbo_frames=${jumbo}
 106 | | Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 107 | | Then Traffic should pass with maximum rate
 108 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
 109
 110 *** Test Cases ***
 111 | tc01-64B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 112 | | [Tags] | 64B | 1C
 113 | | framesize=${64} | phy_cores=${1}
 114
 115 | tc02-64B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 116 | | [Tags] | 64B | 2C
 117 | | framesize=${64} | phy_cores=${2}
 118
 119 | tc03-64B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 120 | | [Tags] | 64B | 4C
 121 | | framesize=${64} | phy_cores=${4}
 122
 123 | tc04-1518B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 124 | | [Tags] | 1518B | 1C
 125 | | framesize=${1518} | phy_cores=${1}
 126
 127 | tc05-1518B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 128 | | [Tags] | 1518B | 2C
 129 | | framesize=${1518} | phy_cores=${2}
 130
 131 | tc06-1518B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 132 | | [Tags] | 1518B | 4C
 133 | | framesize=${1518} | phy_cores=${4}
 134
 135 | tc07-9000B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 136 | | [Tags] | 9000B | 1C
 137 | | framesize=${9000} | phy_cores=${1}
 138
 139 | tc08-9000B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 140 | | [Tags] | 9000B | 2C
 141 | | framesize=${9000} | phy_cores=${2}
 142
 143 | tc09-9000B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 144 | | [Tags] | 9000B | 4C
 145 | | framesize=${9000} | phy_cores=${4}
 146
 147 | tc10-IMIX-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 148 | | [Tags] | IMIX | 1C
 149 | | framesize=IMIX_v4_1 | phy_cores=${1}
 150
 151 | tc11-IMIX-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 152 | | [Tags] | IMIX | 2C
 153 | | framesize=IMIX_v4_1 | phy_cores=${2}
 154
 155 | tc12-IMIX-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 156 | | [Tags] | IMIX | 4C
 157 | | framesize=IMIX_v4_1 | phy_cores=${4}