tests/vpp/perf/vm_vhost/10ge2p1x520-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X520-DA2 | DOT1Q | L2BDMACLRN | BASE | VHOST | 1VM
  20 | ... | VHOST_1024
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L2 | Intel-X520-DA2
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  28 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  29 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  30 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  31 | ...
  32 | Test Template | Local Template
  33 | ...
  34 | Documentation | *RFC2544: Pkt throughput L2BD with vhost abd IEEE 802.1Q test
  35 | ... | cases*
  36 | ...
  37 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  38 | ... | with single links between nodes.
  39 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. IEEE\
  40 | ... | 802.1Q tagging is applied on link between DUT1 and DUT2.
  41 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-\
  42 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via\
  43 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting\
  44 | ... | vhost-user interfaces, forwarding mode is set to io, rxd/txd=1024.\
  45 | ... | DUT1 and DUT2 are tested with 2p10GE NIC X520 Niantic by Intel.
  46 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  47 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  48 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  49 | ... | of packets transmitted. NDR and PDR are discovered for different\
  50 | ... | Ethernet L2 frame sizes using MLRsearch library. Test packets are\
  51 | ... | generated by TG on links to DUTs. TG traffic profile contains two L3\
  52 | ... | flow-groups (flow-group per direction, 254 flows per flow-group) with\
  53 | ... | all packets containing Ethernet header, IPv4 header with IP protocol=61\
  54 | ... | and static payload. MAC addresses are matching MAC addresses of the TG\
  55 | ... | node interfaces.
  56 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  57
  58 *** Variables ***
  59 | ${subid}= | 10
  60 | ${tag_rewrite}= | pop-1
  61 | ${overhead}= | ${4}
  62 # Socket names
  63 | ${bd_id1}= | 1
  64 | ${bd_id2}= | 2
  65 | ${sock1}= | /tmp/sock-1-${bd_id1}
  66 | ${sock2}= | /tmp/sock-1-${bd_id2}
  67 # X520-DA2 bandwidth limit
  68 | ${s_limit}= | ${10000000000}
  69 # Traffic profile:
  70 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  71
  72 *** Keywords ***
  73 | Local Template
  74 | | [Documentation]
  75 | | ... | [Cfg] Each DUT runs L2BD switching with VLAN and uses ${phy_cores}\
  76 | | ... | physical core(s) for worker threads.
  77 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  78 | | ...
  79 | | ... | *Arguments:*
  80 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  81 | | ... | Type: integer, string
  82 | | ... | - phy_cores - Number of physical cores. Type: integer
  83 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  84 | | ...
  85 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  86 | | ...
  87 | | Set Test Variable | ${framesize}
  88 | | Set Test Variable | ${min_rate} | ${10000}
  89 | | ${dut1_vm_refs}= | Create Dictionary
  90 | | ${dut2_vm_refs}= | Create Dictionary
  91 | | Set Test Variable | ${dut1_vm_refs}
  92 | | Set Test Variable | ${dut2_vm_refs}
  93 | | ...
  94 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  95 | | And Add PCI devices to all DUTs
  96 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  97 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  98 | | And Apply startup configuration on all VPP DUTs
  99 | | When Initialize L2 bridge domains with Vhost-User and VLAN in circular topology
 100 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
 101 | | ... | ${tag_rewrite}
 102 | | And Configure guest VMs with dpdk-testpmd connected via vhost-user
 103 | | ... | vm_count=${1} | jumbo=${jumbo} | perf_qemu_qsz=${1024}
 104 | | ... | use_tuned_cfs=${False}
 105 | | Then Find NDR and PDR intervals using optimized search
 106 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 107
 108 *** Test Cases ***
 109 | tc01-64B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 110 | | [Tags] | 64B | 1C
 111 | | framesize=${64} | phy_cores=${1}
 112
 113 | tc02-64B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 114 | | [Tags] | 64B | 2C
 115 | | framesize=${64} | phy_cores=${2}
 116
 117 | tc03-64B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 118 | | [Tags] | 64B | 4C
 119 | | framesize=${64} | phy_cores=${4}
 120
 121 | tc04-1518B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 122 | | [Tags] | 1518B | 1C
 123 | | framesize=${1518} | phy_cores=${1}
 124
 125 | tc05-1518B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 126 | | [Tags] | 1518B | 2C
 127 | | framesize=${1518} | phy_cores=${2}
 128
 129 | tc06-1518B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 130 | | [Tags] | 1518B | 4C
 131 | | framesize=${1518} | phy_cores=${4}
 132
 133 | tc07-9000B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 134 | | [Tags] | 9000B | 1C
 135 | | framesize=${9000} | phy_cores=${1}
 136
 137 | tc08-9000B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 138 | | [Tags] | 9000B | 2C
 139 | | framesize=${9000} | phy_cores=${2}
 140
 141 | tc09-9000B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 142 | | [Tags] | 9000B | 4C
 143 | | framesize=${9000} | phy_cores=${4}
 144
 145 | tc10-IMIX-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 146 | | [Tags] | IMIX | 1C
 147 | | framesize=IMIX_v4_1 | phy_cores=${1}
 148
 149 | tc11-IMIX-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 150 | | [Tags] | IMIX | 2C
 151 | | framesize=IMIX_v4_1 | phy_cores=${2}
 152
 153 | tc12-IMIX-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 154 | | [Tags] | IMIX | 4C
 155 | | framesize=IMIX_v4_1 | phy_cores=${4}