tests/vpp/perf/vm_vhost/10ge2p1x520-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X520-DA2 | DOT1Q | L2BDMACLRN | BASE | VHOST | 1VM
  20 | ... | VHOST_1024
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L2 | Intel-X520-DA2
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  28 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  29 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  30 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  31 | ...
  32 | Test Template | Local Template
  33 | ...
  34 | Documentation | *RFC2544: Pkt throughput L2BD test cases with vhost*
  35 | ...
  36 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  37 | ... | with single links between nodes.
  38 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. 802.1q
  39 | ... | tagging is applied on link between DUT1 and DUT2.
  40 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
  41 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via
  42 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting
  43 | ... | vhost-user interfaces using 5 cores pinned to cpus 5-9 and 2048M
  44 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
  45 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
  46 | ... | io, rxd/txd=1024, burst=64. DUT1, DUT2 are tested with 2p10GE NIC X520
  47 | ... | Niantic by Intel.
  48 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  49 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  50 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  51 | ... | of packets transmitted. NDR and PDR are discovered for different
  52 | ... | Ethernet L2 frame sizes using MLRsearch library.
  53 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  54 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  55 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  56 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  57 | ... | addresses of the TG node interfaces.
  58
  59 *** Variables ***
  60 | ${subid}= | 10
  61 | ${tag_rewrite}= | pop-1
  62 | ${overhead}= | ${4}
  63 # Socket names
  64 | ${bd_id1}= | 1
  65 | ${bd_id2}= | 2
  66 | ${sock1}= | /tmp/sock-1-${bd_id1}
  67 | ${sock2}= | /tmp/sock-1-${bd_id2}
  68 # X520-DA2 bandwidth limit
  69 | ${s_limit}= | ${10000000000}
  70 # Traffic profile:
  71 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  72
  73 *** Keywords ***
  74 | Local Template
  75 | | [Documentation]
  76 | | ... | [Cfg] DUT runs L2BD switching config.
  77 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  78 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  79 | | ...
  80 | | ... | *Arguments:*
  81 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  82 | | ... | Type: integer, string
  83 | | ... | - phy_cores - Number of physical cores. Type: integer
  84 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  85 | | ...
  86 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  87 | | ...
  88 | | Set Test Variable | ${framesize}
  89 | | Set Test Variable | ${min_rate} | ${10000}
  90 | | ${dut1_vm_refs}= | Create Dictionary
  91 | | ${dut2_vm_refs}= | Create Dictionary
  92 | | Set Test Variable | ${dut1_vm_refs}
  93 | | Set Test Variable | ${dut2_vm_refs}
  94 | | ...
  95 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  96 | | And Add PCI devices to all DUTs
  97 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  98 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  99 | | And Apply startup configuration on all VPP DUTs
 100 | | When Initialize L2 bridge domains with Vhost-User and VLAN in a 3-node circular topology
 101 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
 102 | | ... | ${tag_rewrite}
 103 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 104 | | ... | DUT1 | ${sock1} | ${sock2} | DUT1_VM1 | jumbo=${jumbo}
 105 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 106 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 107 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 108 | | ... | DUT2 | ${sock1} | ${sock2} | DUT2_VM1 | jumbo=${jumbo}
 109 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 110 | | Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 111 | | Then Find NDR and PDR intervals using optimized search
 112 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 113
 114 *** Test Cases ***
 115 | tc01-64B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 116 | | [Tags] | 64B | 1C
 117 | | framesize=${64} | phy_cores=${1}
 118
 119 | tc02-64B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 120 | | [Tags] | 64B | 2C
 121 | | framesize=${64} | phy_cores=${2}
 122
 123 | tc03-64B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 124 | | [Tags] | 64B | 4C
 125 | | framesize=${64} | phy_cores=${4}
 126
 127 | tc04-1518B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 128 | | [Tags] | 1518B | 1C
 129 | | framesize=${1518} | phy_cores=${1}
 130
 131 | tc05-1518B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 132 | | [Tags] | 1518B | 2C
 133 | | framesize=${1518} | phy_cores=${2}
 134
 135 | tc06-1518B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 136 | | [Tags] | 1518B | 4C
 137 | | framesize=${1518} | phy_cores=${4}
 138
 139 | tc07-9000B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 140 | | [Tags] | 9000B | 1C
 141 | | framesize=${9000} | phy_cores=${1}
 142
 143 | tc08-9000B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 144 | | [Tags] | 9000B | 2C
 145 | | framesize=${9000} | phy_cores=${2}
 146
 147 | tc09-9000B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 148 | | [Tags] | 9000B | 4C
 149 | | framesize=${9000} | phy_cores=${4}
 150
 151 | tc10-IMIX-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 152 | | [Tags] | IMIX | 1C
 153 | | framesize=IMIX_v4_1 | phy_cores=${1}
 154
 155 | tc11-IMIX-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 156 | | [Tags] | IMIX | 2C
 157 | | framesize=IMIX_v4_1 | phy_cores=${2}
 158
 159 | tc12-IMIX-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 160 | | [Tags] | IMIX | 4C
 161 | | framesize=IMIX_v4_1 | phy_cores=${4}