tests/vpp/perf/vm_vhost/10ge2p1x520-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrchk.robot

   1 # Copyright (c) 2017 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | PDRCHK
  19 | ... | NIC_Intel-X520-DA2 | DOT1Q | L2BDMACLRN | BASE | VHOST | VM | VHOST_1024
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-X520-DA2
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance pdrchk test with vhost and VM with dpdk-testpmd
  27 | ... | ${rate}pps | ${framesize} | ${traffic_profile}
  28 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  29 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  30 | ...
  31 | Documentation | *RFC2544: Packet throughput L2BD test cases with vhost*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. 802.1q
  36 | ... | tagging is applied on link between DUT1 and DUT2.
  37 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
  38 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via
  39 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting
  40 | ... | vhost-user interfaces using 5 cores pinned to cpus 5-9 and 2048M
  41 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
  42 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
  43 | ... | io, rxd/txd=256, burst=64. DUT1, DUT2 are tested with 2p10GE NIC X520
  44 | ... | Niantic by Intel.
  45 | ... | *[Ver] TG verification:* TG verifies throughput PDR (Partial Drop
  46 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  47 | ... | of packets transmitted. Ref-PDR value is periodically updated acording to
  48 | ... | formula: ref-PDR = 0.9x PDR, where PDR is found in RFC2544 long
  49 | ... | performance tests for the same DUT configuration. Test packets are
  50 | ... | generated by TG on links to DUTs. TG traffic profile contains two L3
  51 | ... | flow-groups (flow-group per direction, 253 flows per flow-group) with
  52 | ... | all packets containing Ethernet header, IPv4 header with IP protocol=61
  53 | ... | and static payload. MAC addresses are matching MAC addresses of the
  54 | ... | TG node interfaces.
  55 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  56
  57 *** Variables ***
  58 | ${subid}= | 10
  59 | ${tag_rewrite}= | pop-1
  60 # Socket names
  61 | ${bd_id1}= | 1
  62 | ${bd_id2}= | 2
  63 | ${sock1}= | /tmp/sock-1-${bd_id1}
  64 | ${sock2}= | /tmp/sock-1-${bd_id2}
  65 # Traffic profile:
  66 | ${traffic_profile} | trex-sl-3n-ethip4-ip4src254
  67
  68 *** Keywords ***
  69 | Check PDR for L2 bridge domain with vhost and VM with dpdk-testpmd
  70 | | [Documentation]
  71 | | ... | [Cfg] DUT runs L2BD switching config with ${wt} thread, ${wt} phy\
  72 | | ... | core, ${rxq} receive queue per NIC port.
  73 | | ... | [Ver] Verify ref-PDR for ${framesize} Byte frames using single trial\
  74 | | ... | throughput test at 2x ${rate}.
  75 | | ...
  76 | | [Arguments] | ${framesize} | ${rate} | ${wt} | ${rxq}
  77 | | ...
  78 | | # Test Variables required for test and test teardown
  79 | | Set Test Variable | ${framesize}
  80 | | Set Test Variable | ${rate}
  81 | | ${get_framesize}= | Get Frame Size | ${framesize}
  82 | | ${dut1_vm_refs}= | Create Dictionary
  83 | | ${dut2_vm_refs}= | Create Dictionary
  84 | | Set Test Variable | ${dut1_vm_refs}
  85 | | Set Test Variable | ${dut2_vm_refs}
  86 | | ...
  87 | | Given Add '${wt}' worker threads and '${rxq}' rxqueues in 3-node single-link circular topology
  88 | | And Add PCI devices to DUTs in 3-node single link topology
  89 | | And Run Keyword If | ${get_framesize} < ${1522}
  90 | | ... | Add no multi seg to all DUTs
  91 | | And Apply startup configuration on all VPP DUTs
  92 | | When Initialize L2 bridge domains with Vhost-User and VLAN in a 3-node circular topology
  93 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
  94 | | ... | ${tag_rewrite}
  95 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
  96 | | ... | ${dut1} | ${sock1} | ${sock2} | DUT1_VM1
  97 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
  98 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
  99 | | ... | ${dut2} | ${sock1} | ${sock2} | DUT2_VM1
 100 | | Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 101 | | Run Keyword Unless | ${qemu_built} | Set Suite Variable | ${qemu_built}
 102 | | ... | ${True}
 103 | | Then Traffic should pass with partial loss | ${perf_trial_duration}
 104 | | ... | ${rate} | ${framesize} | ${traffic_profile}
 105 | | ... | ${perf_pdr_loss_acceptance} | ${perf_pdr_loss_acceptance_type}
 106
 107 *** Test Cases ***
 108 | tc01-64B-1t1c-dot1q-l2bdbasemaclrn-eth-2vhost-1vm-pdrchk
 109 | | [Documentation]
 110 | | ... | [Cfg] DUT runs L2BD switching config with 1 thread, 1 phy\
 111 | | ... | core, 1 receive queue per NIC port.
 112 | | ... | [Ver] Verify ref-PDR for 64 Byte frames using single trial\
 113 | | ... | throughput test at 2x ${rate}.
 114 | | ...
 115 | | [Tags] | 64B | 1T1C | STHREAD
 116 | | ...
 117 | | [Template] | Check PDR for L2 bridge domain with vhost and VM with dpdk-testpmd
 118 | | framesize=${64} | rate=1.2mpps | wt=1 | rxq=1
 119
 120 | tc02-1518B-1t1c-dot1q-l2bdbasemaclrn-eth-2vhost-1vm-pdrchk
 121 | | [Documentation]
 122 | | ... | [Cfg] DUT runs L2BD switching config with 1 thread, 1 phy\
 123 | | ... | core, 1 receive queue per NIC port.
 124 | | ... | [Ver] Verify ref-PDR for 1518 Byte frames using single trial\
 125 | | ... | throughput test at 2x ${rate}.
 126 | | ...
 127 | | [Tags] | 1518B | 1T1C | STHREAD
 128 | | ...
 129 | | [Template] | Check PDR for L2 bridge domain with vhost and VM with dpdk-testpmd
 130 | | framesize=${1518} | rate=350000pps | wt=1 | rxq=1
 131
 132 | tc03-IMIX-1t1c-dot1q-l2bdbasemaclrn-eth-2vhost-1vm-pdrchk
 133 | | [Documentation]
 134 | | ... | [Cfg] DUT runs L2BD switching config with 1 thread, 1 phy\
 135 | | ... | core, 1 receive queue per NIC port.
 136 | | ... | [Ver] Verify ref-PDR for 64 Byte frames using single trial\
 137 | | ... | throughput test at 2x ${rate}.
 138 | | ...
 139 | | [Tags] | IMIX | 1T1C | STHREAD
 140 | | ...
 141 | | [Template] | Check PDR for L2 bridge domain with vhost and VM with dpdk-testpmd
 142 | | framesize=IMIX_v4_1 | rate=0.9mpps | wt=1 | rxq=1
 143
 144 | tc04-64B-2t2c-dot1q-l2bdbasemaclrn-eth-2vhost-1vm-pdrchk
 145 | | [Documentation]
 146 | | ... | [Cfg] DUT runs L2BD switching config with 2 threads, 2 phy\
 147 | | ... | cores, 1 receive queue per NIC port.
 148 | | ... | [Ver] Verify ref-PDR for 64 Byte frames using single trial\
 149 | | ... | throughput test at 2x ${rate}.
 150 | | ...
 151 | | [Tags] | 64B | 2T2C | MTHREAD
 152 | | ...
 153 | | [Template] | Check PDR for L2 bridge domain with vhost and VM with dpdk-testpmd
 154 | | framesize=${64} | rate=2.2mpps | wt=2 | rxq=1
 155
 156 | tc05-1518B-2t2c-dot1q-l2bdbasemaclrn-eth-2vhost-1vm-pdrchk
 157 | | [Documentation]
 158 | | ... | [Cfg] DUT runs L2BD switching config with 2 threads, 2 phy\
 159 | | ... | cores, 1 receive queue per NIC port.
 160 | | ... | [Ver] Verify ref-PDR for 1518 Byte frames using single trial\
 161 | | ... | throughput test at 2x ${rate}.
 162 | | ...
 163 | | [Tags] | 1518B | 2T2C | MTHREAD
 164 | | ...
 165 | | [Template] | Check PDR for L2 bridge domain with vhost and VM with dpdk-testpmd
 166 | | framesize=${1518} | rate=0.6mpps | wt=2 | rxq=1
 167
 168 | tc06-IMIX-2t2c-dot1q-l2bdbasemaclrn-eth-2vhost-1vm-pdrchk
 169 | | [Documentation]
 170 | | ... | [Cfg] DUT runs L2BD switching config with 2 threads, 2 phy\
 171 | | ... | cores, 1 receive queue per NIC port.
 172 | | ... | [Ver] Verify ref-PDR for 64 Byte frames using single trial\
 173 | | ... | throughput test at 2x ${rate}.
 174 | | ...
 175 | | [Tags] | IMIX | 2T2C | MTHREAD
 176 | | ...
 177 | | [Template] | Check PDR for L2 bridge domain with vhost and VM with dpdk-testpmd
 178 | | framesize=IMIX_v4_1 | rate=1.5pps | wt=2 | rxq=1
 179
 180 | tc07-64B-4t4c-dot1q-l2bdbasemaclrn-eth-2vhost-1vm-pdrchk
 181 | | [Documentation]
 182 | | ... | [Cfg] DUT runs L2BD switching config with 4 threads, 4 phy\
 183 | | ... | cores, 2 receive queues per NIC port.
 184 | | ... | [Ver] Verify ref-PDR for 64 Byte frames using single trial\
 185 | | ... | throughput test at 2x ${rate}.
 186 | | ...
 187 | | [Tags] | 64B | 4T4C | MTHREAD
 188 | | ...
 189 | | [Template] | Check PDR for L2 bridge domain with vhost and VM with dpdk-testpmd
 190 | | framesize=${64} | rate=3.4mpps | wt=4 | rxq=2
 191
 192 | tc08-1518B-4t4c-dot1q-l2bdbasemaclrn-eth-2vhost-1vm-pdrchk
 193 | | [Documentation]
 194 | | ... | [Cfg] DUT runs L2BD switching config with 4 threads, 4 phy\
 195 | | ... | cores, 2 receive queues per NIC port.
 196 | | ... | [Ver] Verify ref-PDR for 1518 Byte frames using single trial\
 197 | | ... | throughput test at 2x ${rate}.
 198 | | ...
 199 | | [Tags] | 1518B | 4T4C | MTHREAD
 200 | | ...
 201 | | [Template] | Check PDR for L2 bridge domain with vhost and VM with dpdk-testpmd
 202 | | framesize=${1518} | rate=0.7mpps | wt=4 | rxq=2
 203
 204 | tc09-IMIX-4t4c-dot1q-l2bdbasemaclrn-eth-2vhost-1vm-pdrchk
 205 | | [Documentation]
 206 | | ... | [Cfg] DUT runs L2BD switching config with 4 threads, 4 phy\
 207 | | ... | cores, 2 receive queues per NIC port.
 208 | | ... | [Ver] Verify ref-PDR for 64 Byte frames using single trial\
 209 | | ... | throughput test at 2x ${rate}.
 210 | | ...
 211 | | [Tags] | IMIX | 4T4C | MTHREAD
 212 | | ...
 213 | | [Template] | Check PDR for L2 bridge domain with vhost and VM with dpdk-testpmd
 214 | | framesize=IMIX_v4_1 | rate=2.2mpps | wt=4 | rxq=2