tests/vpp/perf/vm_vhost/10ge2p1x520-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-X520-DA2 | ETH | L2BDMACLRN | BASE | VHOST | VM | VHOST_1024
  19 | ... | CFS_OPT
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-X520-DA2
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance mrr test with vhost and VM with dpdk-testpmd
  27 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  28 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *Raw results L2BD test cases with vhost*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  35 | ... | with single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. 802.1q
  37 | ... | tagging is applied on link between DUT1 and DUT2.
  38 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
  39 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via
  40 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting
  41 | ... | vhost-user interfaces using 5 cores pinned to cpus 5-9 and 2048M
  42 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
  43 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
  44 | ... | io, rxd/txd=1024, burst=64. Scheduler policy is set to SCHED_RR with
  45 | ... | priority 1 for all Qemu CPUs. DUT1, DUT2 are tested with 2p10GE NIC X520
  46 | ... | Niantic by Intel..
  47 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  48 | ... | at line rate and reports total received/sent packets over trial period.
  49 | ... | Test packets are generated by TG on
  50 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  51 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  52 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
  53 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  54 | ... | interfaces.
  55 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  56
  57 *** Variables ***
  58 # X520-DA2 bandwidth limit
  59 | ${s_limit}= | ${10000000000}
  60 # Traffic profile:
  61 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  62
  63 *** Keywords ***
  64 | Local Template
  65 | | [Documentation]
  66 | | ... | [Cfg] DUT runs L2BD switching config.
  67 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  68 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  69 | | ... | trial throughput test.
  70 | | ...
  71 | | ... | *Arguments:*
  72 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  73 | | ... | Type: integer, string
  74 | | ... | - phy_cores - Number of physical cores. Type: integer
  75 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  76 | | ...
  77 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  78 | | ...
  79 | | ${dut1_vm_refs}= | Create Dictionary
  80 | | ${dut2_vm_refs}= | Create Dictionary
  81 | | Set Test Variable | ${dut1_vm_refs}
  82 | | Set Test Variable | ${dut2_vm_refs}
  83 | | ...
  84 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  85 | | And Add PCI devices to all DUTs
  86 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  87 | | ... | ${s_limit} | ${framesize}
  88 | | And Apply startup configuration on all VPP DUTs
  89 | | When Initialize L2 bridge domains with Vhost-User | nf_nodes=${1}
  90 | | And Configure guest VMs with dpdk-testpmd connected via vhost-user
  91 | | ... | vm_count=${1} | jumbo=${jumbo} | perf_qemu_qsz=${1024}
  92 | | ... | use_tuned_cfs=${True}
  93 | | And Setup Scheduler Policy for Vpp On All DUTs
  94 | | Then Traffic should pass with maximum rate
  95 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  96
  97 *** Test Cases ***
  98 | tc01-64B-1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
  99 | | [Tags] | 64B | 1C
 100 | | framesize=${64} | phy_cores=${1}
 101
 102 | tc02-64B-2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 103 | | [Tags] | 64B | 2C
 104 | | framesize=${64} | phy_cores=${2}
 105
 106 | tc03-64B-4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 107 | | [Tags] | 64B | 4C
 108 | | framesize=${64} | phy_cores=${4}
 109
 110 | tc04-1518B-1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 111 | | [Tags] | 1518B | 1C
 112 | | framesize=${1518} | phy_cores=${1}
 113
 114 | tc05-1518B-2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 115 | | [Tags] | 1518B | 2C
 116 | | framesize=${1518} | phy_cores=${2}
 117
 118 | tc06-1518B-4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 119 | | [Tags] | 1518B | 4C
 120 | | framesize=${1518} | phy_cores=${4}
 121
 122 | tc07-9000B-1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 123 | | [Tags] | 9000B | 1C
 124 | | framesize=${9000} | phy_cores=${1}
 125
 126 | tc08-9000B-2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 127 | | [Tags] | 9000B | 2C
 128 | | framesize=${9000} | phy_cores=${2}
 129
 130 | tc09-9000B-4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 131 | | [Tags] | 9000B | 4C
 132 | | framesize=${9000} | phy_cores=${4}
 133
 134 | tc10-IMIX-1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 135 | | [Tags] | IMIX | 1C
 136 | | framesize=IMIX_v4_1 | phy_cores=${1}
 137
 138 | tc11-IMIX-2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 139 | | [Tags] | IMIX | 2C
 140 | | framesize=IMIX_v4_1 | phy_cores=${2}
 141
 142 | tc12-IMIX-4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-cfsrr1-mrr
 143 | | [Tags] | IMIX | 4C
 144 | | framesize=IMIX_v4_1 | phy_cores=${4}