tests/vpp/perf/vm_vhost/10ge2p1x520-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Documentation | *RFC2544: Pkt throughput L2BD test cases with vhost*
  16 | ...
  17 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  18 | ... | with single links between nodes.
  19 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  20 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
  21 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via
  22 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting
  23 | ... | vhost-user interfaces using 5 cores pinned to cpus 5-9 and 2048M
  24 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
  25 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
  26 | ... | io, rxd/txd=1024, burst=64. DUT1, DUT2 are tested with 2p10GE NIC X520
  27 | ... | Niantic by Intel.
  28 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  29 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  30 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  31 | ... | of packets transmitted. NDR and PDR are discovered for different
  32 | ... | Ethernet L2 frame sizes using either binary search or linear search
  33 | ... | algorithms with configured starting rate and final step that determines
  34 | ... | throughput measurement resolution. Test packets are generated by TG on
  35 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  36 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  37 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
  38 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  39 | ... | interfaces.
  40 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  41 | ...
  42 | Resource | resources/libraries/robot/performance/performance_setup.robot
  43 | Library | resources.libraries.python.QemuUtils
  44 | ...
  45 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  46 | ... | NIC_Intel-X520-DA2 | ETH | L2BDMACLRN | BASE | VHOST | VM | VHOST_1024
  47 | ...
  48 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  49 | ... | L2 | Intel-X520-DA2
  50 | Suite Teardown | Tear down 3-node performance topology
  51 | ...
  52 | Test Setup | Set up performance test
  53 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  54 | ... | ${10000}pps | ${64} | ${traffic_profile}
  55 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  56 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  57 | ...
  58 | Test Template | Find NDRPDR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
  59
  60 *** Variables ***
  61 | ${perf_qemu_qsz}= | 1024
  62 | ${min_rate}= | ${20000}
  63 # X520-DA2 bandwidth limit
  64 | ${s_limit} | ${10000000000}
  65 # Socket names
  66 | ${bd_id1}= | 1
  67 | ${bd_id2}= | 2
  68 | ${sock1}= | /tmp/sock-1-${bd_id1}
  69 | ${sock2}= | /tmp/sock-1-${bd_id2}
  70 # Traffic profile:
  71 | ${traffic_profile} | trex-sl-3n-ethip4-ip4src254
  72
  73 *** Keywords ***
  74 | Find NDRPDR for eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm
  75 | | [Documentation]
  76 | | ... | [Cfg] DUT runs L2BD switching config with ${wt} thread, ${wt} phy\
  77 | | ... | core, ${rxq} receive queue per NIC port.
  78 | | ... | [Ver] Find NDR for ${framesize} frames \
  79 | | ... | using binary search start at 10GE linerate.
  80 | | ...
  81 | | [Arguments] | ${framesize} | ${wt} | ${rxq}
  82 | | ...
  83 | | # Test Variables required for test and test teardown
  84 | | Set Test Variable | ${framesize}
  85 | | ${get_framesize}= | Get Frame Size | ${framesize}
  86 | | ${max_unidirectional_rate}= | Calculate pps | ${s_limit} | ${get_framesize}
  87 | | ${max_rate}= | Evaluate | 2*${max_unidirectional_rate}
  88 | | ${dut1_vm_refs}= | Create Dictionary
  89 | | ${dut2_vm_refs}= | Create Dictionary
  90 | | Set Test Variable | ${dut1_vm_refs}
  91 | | Set Test Variable | ${dut2_vm_refs}
  92 | | ${jumbo_frames}= | Set Variable If | ${get_framesize} < ${1522}
  93 | | ... | ${False} | ${True}
  94 | | ...
  95 | | Given Add '${wt}' worker threads and '${rxq}' rxqueues in 3-node single-link circular topology
  96 | | And Add PCI devices to all DUTs
  97 | | And Run Keyword If | ${get_framesize} < ${1522}
  98 | | ... | Add no multi seg to all DUTs
  99 | | And Apply startup configuration on all VPP DUTs
 100 | | When Initialize L2 bridge domains with Vhost-User in 3-node circular topology
 101 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2}
 102 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 103 | | ... | ${dut1} | ${sock1} | ${sock2} | DUT1_VM1
 104 | | ... | jumbo_frames=${jumbo_frames}
 105 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 106 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 107 | | ... | ${dut2} | ${sock1} | ${sock2} | DUT2_VM1
 108 | | ... | jumbo_frames=${jumbo_frames}
 109 | | Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 110 | | Then Find NDR and PDR intervals using optimized search
 111 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 112
 113 *** Test Cases ***
 114 | tc01-64B-1t1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 115 | | [Tags] | 64B | 1C
 116 | | ...
 117 | | framesize=${64} | wt=1 | rxq=1
 118
 119 | tc02-1518B-1t1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 120 | | [Tags] | 1518B | 1C
 121 | | ...
 122 | | framesize=${1518} | wt=1 | rxq=1
 123
 124 | tc03-9000B-1t1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 125 | | [Tags] | 9000B | 1C
 126 | | ...
 127 | | framesize=${9000} | wt=1 | rxq=1
 128
 129 | tc04-IMIX-1t1c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 130 | | [Tags] | IMIX | 1C
 131 | | ...
 132 | | framesize=IMIX_v4_1 | wt=1 | rxq=1
 133
 134 | tc05-64B-2t2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 135 | | [Tags] | 64B | 2C
 136 | | ...
 137 | | framesize=${64} | wt=2 | rxq=1
 138
 139 | tc06-1518B-2t2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 140 | | [Tags] | 1518B | 2C
 141 | | ...
 142 | | framesize=${1518} | wt=2 | rxq=1
 143
 144 | tc07-9000B-2t2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 145 | | [Tags] | 9000B | 2C
 146 | | ...
 147 | | framesize=${9000} | wt=2 | rxq=1
 148
 149 | tc08-IMIX-2t2c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 150 | | [Tags] | IMIX | 2C
 151 | | ...
 152 | | framesize=IMIX_v4_1 | wt=2 | rxq=1
 153
 154 | tc09-64B-4t4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 155 | | [Tags] | 64B | 4C
 156 | | ...
 157 | | framesize=${64} | wt=4 | rxq=2
 158
 159 | tc10-1518B-4t4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 160 | | [Tags] | 1518B | 4C
 161 | | ...
 162 | | framesize=${1518} | wt=4 | rxq=2
 163
 164 | tc11-9000B-4t4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 165 | | [Tags] | 9000B | 4C
 166 | | ...
 167 | | framesize=${9000} | wt=4 | rxq=2
 168
 169 | tc12-IMIX-4t4c-eth-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 170 | | [Tags] | IMIX | 4C
 171 | | ...
 172 | | framesize=IMIX_v4_1 | wt=4 | rxq=2