tests/vpp/perf/vm_vhost/10ge2p1x520-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X520-DA2 | ETH | L2BDMACLRN | SCALE | FIB_1M | VHOST | VM
  20 | ... | VHOST_1024 | CFS_OPT
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L2 | Intel-X520-DA2
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  28 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  29 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  30 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  31 | ...
  32 | Test Template | Local Template
  33 | ...
  34 | Documentation | *RFC2544: Packet throughput L2BD test cases with vhost*
  35 | ...
  36 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  37 | ... | with single links between nodes.
  38 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.\
  39 | ... | 802.1q tagging is applied on link between DUT1 and DUT2.
  40 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-\
  41 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via\
  42 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting\
  43 | ... | vhost-user interfaces using 5 cores pinned to cpus 5-9 and 2048M\
  44 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores\
  45 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to\
  46 | ... | io, rxd/txd=1024, burst=64. Scheduler policy is set to SCHED_RR with\
  47 | ... | priority 1 for all Qemu CPUs. DUT1, DUT2 are tested with 2p10GE NIC\
  48 | ... | X520 Niantic by Intel..
  49 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  50 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  51 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  52 | ... | of packets transmitted. NDR and PDR are discovered for different\
  53 | ... | Ethernet L2 frame sizes using MLRsearch library.
  54 | ... | Test packets are generated by TG on\
  55 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
  56 | ... | (flow-group per direction, 500k flows per flow-group) with all packets\
  57 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static\
  58 | ... | payload. MAC addresses ranges are incremented as follows:
  59 | ... | port01_src ca:fe:00:00:00:00 - port01_src ca:fe:00:07:a1:1f,\
  60 | ... | port01_dst fa:ce:00:00:00:00 - port01_dst fa:ce:00:07:a1:1f,\
  61 | ... | port02_src fa:ce:00:00:00:00 - port02_src fa:ce:00:07:a1:1f,\
  62 | ... | port02_dst ca:fe:00:00:00:00 - port02_dst ca:fe:00:07:a1:1f,\
  63 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  64
  65 *** Variables ***
  66 | ${perf_qemu_qsz}= | 1024
  67 # X520-DA2 bandwidth limit
  68 | ${s_limit}= | ${10000000000}
  69 # Socket names
  70 | ${bd_id1}= | 1
  71 | ${bd_id2}= | 2
  72 | ${sock1}= | /tmp/sock-1-${bd_id1}
  73 | ${sock2}= | /tmp/sock-1-${bd_id2}
  74 # Traffic profile:
  75 | ${traffic_profile}= | trex-sl-3n-ethip4-macsrc500kdst500k
  76
  77 *** Keywords ***
  78 | Local Template
  79 | | [Documentation] | FIXME.
  80 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  81 | | ...
  82 | | Set Test Variable | ${use_tuned_cfs} | ${True}
  83 | | Set Test Variable | ${framesize}
  84 | | Set Test Variable | ${min_rate} | ${10000}
  85 | | ${dut1_vm_refs}= | Create Dictionary
  86 | | ${dut2_vm_refs}= | Create Dictionary
  87 | | Set Test Variable | ${dut1_vm_refs}
  88 | | Set Test Variable | ${dut2_vm_refs}
  89 | | ...
  90 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  91 | | And Add PCI devices to all DUTs
  92 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  93 | | ... | ${s_limit} | ${framesize}
  94 | | And Apply startup configuration on all VPP DUTs
  95 | | When Initialize L2 bridge domains with Vhost-User in 3-node circular topology
  96 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2}
  97 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
  98 | | ... | ${dut1} | ${sock1} | ${sock2} | DUT1_VM1
  99 | | ... | jumbo_frames=${jumbo}
 100 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 101 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 102 | | ... | ${dut2} | ${sock1} | ${sock2} | DUT2_VM1
 103 | | ... | jumbo_frames=${jumbo}
 104 | | Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 105 | | Setup Scheduler Policy for Vpp On All DUTs
 106 | | Then Find NDR and PDR intervals using optimized search
 107 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 108
 109 *** Test Cases ***
 110 | tc01-64B-1c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 111 | | [Tags] | 64B | 1C
 112 | | framesize=${64} | phy_cores=${1}
 113
 114 | tc02-64B-2c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 115 | | [Tags] | 64B | 2C
 116 | | framesize=${64} | phy_cores=${2}
 117
 118 | tc03-64B-4c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 119 | | [Tags] | 64B | 4C
 120 | | framesize=${64} | phy_cores=${4}
 121
 122 | tc04-1518B-1c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 123 | | [Tags] | 1518B | 1C
 124 | | framesize=${1518} | phy_cores=${1}
 125
 126 | tc05-1518B-2c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 127 | | [Tags] | 1518B | 2C
 128 | | framesize=${1518} | phy_cores=${2}
 129
 130 | tc06-1518B-4c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 131 | | [Tags] | 1518B | 4C
 132 | | framesize=${1518} | phy_cores=${4}
 133
 134 | tc07-9000B-1c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 135 | | [Tags] | 9000B | 1C
 136 | | framesize=${9000} | phy_cores=${1}
 137
 138 | tc08-9000B-2c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 139 | | [Tags] | 9000B | 2C
 140 | | framesize=${9000} | phy_cores=${2}
 141
 142 | tc09-9000B-4c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 143 | | [Tags] | 9000B | 4C
 144 | | framesize=${9000} | phy_cores=${4}
 145
 146 | tc10-IMIX-1c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 147 | | [Tags] | IMIX | 1C
 148 | | framesize=IMIX_v4_1 | phy_cores=${1}
 149
 150 | tc11-IMIX-2c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 151 | | [Tags] | IMIX | 2C
 152 | | framesize=IMIX_v4_1 | phy_cores=${2}
 153
 154 | tc12-IMIX-4c-eth-l2bdscale1mmaclrn-eth-2vhostvr1024-1vm-cfsrr1-ndrpdr
 155 | | [Tags] | IMIX | 4C
 156 | | framesize=IMIX_v4_1 | phy_cores=${4}