tests/vpp/perf/vm_vhost/10ge2p1x520-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X520-DA2 | ETH | IP4FWD | BASE | VHOST | VM | VHOST_256
  20 | ... | CFS_OPT
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L3 | Intel-X520-DA2
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  28 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  29 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  30 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  31 | ...
  32 | Test Template | Local Template
  33 | ...
  34 | Documentation | *RFC2544: Packet throughput IP4 test cases with vhost*
  35 | ...
  36 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  37 | ... | with single links between nodes.
  38 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4
  40 | ... | routing and two static IPv4 /24 route entries. Qemu Guest is connected
  41 | ... | to VPP via vhost-user interfaces. Guest is running DPDK testpmd
  42 | ... | interconnecting vhost-user interfaces using 5 cores pinned to cpus 5-9
  43 | ... | and 2048M memory. Testpmd is using socket-mem=1024M (512x2M hugepages),
  44 | ... | 5 cores (1 main core and 4 cores dedicated for io), forwarding mode is
  45 | ... | set to mac, rxd/txd=256, burst=64. Scheduler policy is set to SCHED_RR
  46 | ... | with priority 1 for all Qemu CPUs. DUT1, DUT2 are tested with 2p10GE
  47 | ... | NIC X520 Niantic by Intel.
  48 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  49 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  50 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  51 | ... | of packets transmitted. NDR and PDR are discovered for different
  52 | ... | Ethernet L2 frame sizes using MLRsearch library.
  53 | ... | Test packets are generated by TG on
  54 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  55 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  56 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
  57 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  58 | ... | interfaces.
  59 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  60
  61 *** Variables ***
  62 # X520-DA2 bandwidth limit
  63 | ${s_limit}= | ${10000000000}
  64 # Traffic profile:
  65 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src253
  66
  67 *** Keywords ***
  68 | Local Template
  69 | | [Documentation]
  70 | | ... | [Cfg] DUT runs IP4 routing config with required number of threads,\
  71 | | ... | phy cores and receive queues per NIC port.
  72 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  73 | | ...
  74 | | ... | *Arguments:*
  75 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  76 | | ... | Type: integer, string
  77 | | ... | - phy_cores - Number of physical cores. Type: integer
  78 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  79 | | ...
  80 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  81 | | ...
  82 | | Set Test Variable | ${use_tuned_cfs} | ${True}
  83 | | Set Test Variable | ${framesize}
  84 | | Set Test Variable | ${min_rate} | ${10000}
  85 | | ${dut1_vm_refs}= | Create Dictionary
  86 | | ${dut2_vm_refs}= | Create Dictionary
  87 | | Set Test Variable | ${dut1_vm_refs}
  88 | | Set Test Variable | ${dut2_vm_refs}
  89 | | ...
  90 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  91 | | And Add PCI devices to all DUTs
  92 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  93 | | ... | ${s_limit} | ${framesize}
  94 | | And Apply startup configuration on all VPP DUTs
  95 | | When Initialize IPv4 forwarding with vhost in 3-node circular topology
  96 | | ... | vm_count=${1}
  97 | | And Configure guest VMs with dpdk-testpmd-mac connected via vhost-user
  98 | | ... | vm_count=${1} | jumbo=${jumbo} | perf_qemu_qsz=${256}
  99 | | ... | use_tuned_cfs=${True}
 100 | | Setup Scheduler Policy for Vpp On All DUTs
 101 | | Then Find NDR and PDR intervals using optimized search
 102 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 103
 104 *** Test Cases ***
 105 | tc01-64B-1c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 106 | | [Tags] | 64B | 1C
 107 | | framesize=${64} | phy_cores=${1}
 108
 109 | tc02-64B-2c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 110 | | [Tags] | 64B | 2C
 111 | | framesize=${64} | phy_cores=${2}
 112
 113 | tc03-64B-4c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 114 | | [Tags] | 64B | 4C
 115 | | framesize=${64} | phy_cores=${4}
 116
 117 | tc04-1518B-1c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 118 | | [Tags] | 1518B | 1C
 119 | | framesize=${1518} | phy_cores=${1}
 120
 121 | tc05-1518B-2c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 122 | | [Tags] | 1518B | 2C
 123 | | framesize=${1518} | phy_cores=${2}
 124
 125 | tc06-1518B-4c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 126 | | [Tags] | 1518B | 4C
 127 | | framesize=${1518} | phy_cores=${4}
 128
 129 | tc07-9000B-1c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 130 | | [Tags] | 9000B | 1C
 131 | | framesize=${9000} | phy_cores=${1}
 132
 133 | tc08-9000B-2c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 134 | | [Tags] | 9000B | 2C
 135 | | framesize=${9000} | phy_cores=${2}
 136
 137 | tc09-9000B-4c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 138 | | [Tags] | 9000B | 4C
 139 | | framesize=${9000} | phy_cores=${4}
 140
 141 | tc10-IMIX-1c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 142 | | [Tags] | IMIX | 1C
 143 | | framesize=IMIX_v4_1 | phy_cores=${1}
 144
 145 | tc11-IMIX-2c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 146 | | [Tags] | IMIX | 2C
 147 | | framesize=IMIX_v4_1 | phy_cores=${2}
 148
 149 | tc12-IMIX-4c-ethip4-ip4base-eth-2vhostvr256-1vm-cfsrr1-ndrpdr
 150 | | [Tags] | IMIX | 4C
 151 | | framesize=IMIX_v4_1 | phy_cores=${4}