tests/vpp/perf/vm_vhost/10ge2p1x520-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-X520-DA2 | L2BDMACLRN | ENCAP | VXLAN | L2OVRLAY | IP4UNRLAY
  19 | ... | VHOST | 1VM | VHOST_1024
  20 | ...
  21 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  22 | ... | L2 | Intel-X520-DA2
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance mrr test with vhost and VM with dpdk-testpmd
  27 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  28 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *Raw results L2BD test cases with VXLANoIPv4
  33 | ... | and vhost*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  38 | ... | Eth-IPv4-VXLAN-Eth-IPv4 is applied on link between DUT1 and DUT2.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
  40 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via
  41 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting
  42 | ... | vhost-user interfaces using 5 cores pinned to cpus 5-9 and 2048M
  43 | ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
  44 | ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
  45 | ... | io, rxd/txd=1024, burst=64. DUT1, DUT2 are tested with 2p10GE NIC X520
  46 | ... | Niantic by Intel.
  47 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  48 | ... | at line rate and reports total received/sent packets over trial period.
  49 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  50 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  51 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  52 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  53 | ... | addresses of the TG node interfaces.
  54 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  55
  56 *** Variables ***
  57 # Socket names
  58 | ${bd_id1}= | 1
  59 | ${bd_id2}= | 2
  60 | ${sock1}= | /tmp/sock-1-${bd_id1}
  61 | ${sock2}= | /tmp/sock-1-${bd_id2}
  62 # X520-DA2 bandwidth limit
  63 | ${s_limit}= | ${10000000000}
  64 | ${overhead}= | ${50}
  65 # Traffic profile:
  66 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  67
  68 *** Keywords ***
  69 | Local Template
  70 | | [Documentation]
  71 | | ... | [Cfg] DUT runs L2BD switching config.
  72 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  73 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  74 | | ... | trial throughput test.
  75 | | ...
  76 | | ... | *Arguments:*
  77 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  78 | | ... | Type: integer, string
  79 | | ... | - phy_cores - Number of physical cores. Type: integer
  80 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  81 | | ...
  82 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  83 | | ...
  84 | | ${dut1_vm_refs}= | Create Dictionary
  85 | | ${dut2_vm_refs}= | Create Dictionary
  86 | | Set Test Variable | ${dut1_vm_refs}
  87 | | Set Test Variable | ${dut2_vm_refs}
  88 | | ...
  89 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  90 | | And Add PCI devices to all DUTs
  91 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  92 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  93 | | And Apply startup configuration on all VPP DUTs
  94 | | When Initialize L2 bridge domains with Vhost-User and VXLANoIPv4 in 3-node circular topology
  95 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2}
  96 | | And Configure guest VMs with dpdk-testpmd connected via vhost-user
  97 | | ... | vm_count=${1} | jumbo=${jumbo} | perf_qemu_qsz=${1024}
  98 | | ... | use_tuned_cfs=${False}
  99 | | Then Traffic should pass with maximum rate
 100 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
 101
 102 *** Test Cases ***
 103 | tc01-64B-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 104 | | [Tags] | 64B | 1C
 105 | | framesize=${64} | phy_cores=${1}
 106
 107 | tc02-64B-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 108 | | [Tags] | 64B | 2C
 109 | | framesize=${64} | phy_cores=${2}
 110
 111 | tc03-64B-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 112 | | [Tags] | 64B | 4C
 113 | | framesize=${64} | phy_cores=${4}
 114
 115 | tc04-1518B-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 116 | | [Tags] | 1518B | 1C
 117 | | framesize=${1518} | phy_cores=${1}
 118
 119 | tc05-1518B-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 120 | | [Tags] | 1518B | 2C
 121 | | framesize=${1518} | phy_cores=${2}
 122
 123 | tc06-1518B-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 124 | | [Tags] | 1518B | 4C
 125 | | framesize=${1518} | phy_cores=${4}
 126
 127 | tc07-9000B-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 128 | | [Tags] | 9000B | 1C
 129 | | framesize=${9000} | phy_cores=${1}
 130
 131 | tc08-9000B-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 132 | | [Tags] | 9000B | 2C
 133 | | framesize=${9000} | phy_cores=${2}
 134
 135 | tc09-9000B-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 136 | | [Tags] | 9000B | 4C
 137 | | framesize=${9000} | phy_cores=${4}
 138
 139 | tc10-IMIX-1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 140 | | [Tags] | IMIX | 1C
 141 | | framesize=IMIX_v4_1 | phy_cores=${1}
 142
 143 | tc11-IMIX-2c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 144 | | [Tags] | IMIX | 2C
 145 | | framesize=IMIX_v4_1 | phy_cores=${2}
 146
 147 | tc12-IMIX-4c-ethip4vxlan-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 148 | | [Tags] | IMIX | 4C
 149 | | framesize=IMIX_v4_1 | phy_cores=${4}