tests/vpp/perf/vm_vhost/10ge2p1x710-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | NIC_Intel-X710 | DOT1Q | L2BDMACLRN | BASE | VHOST | 1VM
  20 | ... | VHOST_1024 | LBOND | LBOND_DPDK | LBOND_MODE_XOR | LBOND_LB_L34
  21 | ... | LBOND_1L
  22 | ...
  23 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  24 | ... | L2 | Intel-X710
  25 | Suite Teardown | Tear down 3-node performance topology
  26 | ...
  27 | Test Setup | Set up performance test
  28 | Test Teardown | Tear down performance mrr test with vhost and VM with dpdk-testpmd
  29 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  30 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  31 | ...
  32 | Test Template | Local Template
  33 | ...
  34 | Documentation | *Raw results L2BD test cases with vhost and dpdk link bonding*
  35 | ...
  36 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  37 | ... | with single links between nodes.
  38 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. 802.1q
  39 | ... | tagging is applied on link between DUT1 and DUT2.
  40 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with DPDK
  41 | ... | link bonding (mode XOR, transmit policy l34) on link between DUT1 and
  42 | ... | DUT2 and L2 bridge-domain with MAC learning enabled. Qemu Guest is
  43 | ... | connected to VPP via vhost-user interfaces. Guest is running DPDK
  44 | ... | testpmd interconnecting vhost-user interfaces using 5 cores pinned to
  45 | ... | cpus 5-9 and 2048M memory. Testpmd is using socket-mem=1024M (512x2M
  46 | ... | hugepages), 5 cores (1 main core and 4 cores dedicated for io),
  47 | ... | forwarding mode is set to io, rxd/txd=1024, burst=64. DUT1, DUT2 are
  48 | ... | tested with 2p10GE NIC X710 Fortville by Intel.
  49 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  50 | ... | at line rate and reports total received/sent packets over trial period.
  51 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  52 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  53 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  54 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  55 | ... | addresses of the TG node interfaces.
  56
  57 *** Variables ***
  58 | ${dut1_eth_bond_if1}= | eth_bond1
  59 | ${dut1_eth_bond_if1_name}= | BondEthernet0
  60 | ${dut2_eth_bond_if1}= | eth_bond1
  61 | ${dut2_eth_bond_if1_name}= | BondEthernet0
  62 | ${subid}= | 10
  63 | ${tag_rewrite}= | pop-1
  64 | ${overhead}= | ${4}
  65 # Socket names
  66 | ${bd_id1}= | 1
  67 | ${bd_id2}= | 2
  68 | ${sock1}= | /tmp/sock-1-${bd_id1}
  69 | ${sock2}= | /tmp/sock-1-${bd_id2}
  70 # X710 bandwidth limit
  71 | ${s_limit}= | ${10000000000}
  72 # Traffic profile:
  73 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  74
  75 *** Keywords ***
  76 | Local Template
  77 | | [Documentation]
  78 | | ... | [Cfg] DUT runs L2BD switching config.
  79 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  80 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  81 | | ... | trial throughput test.
  82 | | ...
  83 | | ... | *Arguments:*
  84 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  85 | | ... | Type: integer, string
  86 | | ... | - phy_cores - Number of physical cores. Type: integer
  87 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  88 | | ...
  89 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  90 | | ...
  91 | | ${dut1_vm_refs}= | Create Dictionary
  92 | | ${dut2_vm_refs}= | Create Dictionary
  93 | | Set Test Variable | ${dut1_vm_refs}
  94 | | Set Test Variable | ${dut2_vm_refs}
  95 | | ...
  96 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  97 | | And Add PCI devices to all DUTs
  98 | | And Add VLAN Strip Offload switch off between DUTs in 3-node single link topology
  99 | | And Add DPDK bonded Ethernet interfaces to DUTs in 3-node single link topology
 100 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
 101 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
 102 | | And Apply startup configuration on all VPP DUTs
 103 | | When Initialize L2 bridge domains with Vhost-User and VLAN with DPDK link bonding in a 3-node circular topology
 104 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
 105 | | ... | ${tag_rewrite}
 106 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 107 | | ... | DUT1 | ${sock1} | ${sock2} | DUT1_VM1 | jumbo=${jumbo}
 108 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 109 | | And Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 110 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 111 | | ... | DUT2 | ${sock1} | ${sock2} | DUT2_VM1 | jumbo=${jumbo}
 112 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 113 | | And Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 114 | | Then Traffic should pass with maximum rate
 115 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
 116
 117 *** Test Cases ***
 118 | tc01-64B-1c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 119 | | [Tags] | 64B | 1C
 120 | | framesize=${64} | phy_cores=${1}
 121
 122 | tc02-64B-2c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 123 | | [Tags] | 64B | 2C
 124 | | framesize=${64} | phy_cores=${2}
 125
 126 | tc03-64B-4c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 127 | | [Tags] | 64B | 4C
 128 | | framesize=${64} | phy_cores=${4}
 129
 130 | tc04-1518B-1c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 131 | | [Tags] | 1518B | 1C
 132 | | framesize=${1518} | phy_cores=${1}
 133
 134 | tc05-1518B-2c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 135 | | [Tags] | 1518B | 2C
 136 | | framesize=${1518} | phy_cores=${2}
 137
 138 | tc06-1518B-4c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 139 | | [Tags] | 1518B | 4C
 140 | | framesize=${1518} | phy_cores=${4}
 141
 142 | tc07-9000B-1c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 143 | | [Tags] | 9000B | 1C
 144 | | framesize=${9000} | phy_cores=${1}
 145
 146 | tc08-9000B-2c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 147 | | [Tags] | 9000B | 2C
 148 | | framesize=${9000} | phy_cores=${2}
 149
 150 | tc09-9000B-4c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 151 | | [Tags] | 9000B | 4C
 152 | | framesize=${9000} | phy_cores=${4}
 153
 154 | tc10-IMIX-1c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 155 | | [Tags] | IMIX | 1C
 156 | | framesize=IMIX_v4_1 | phy_cores=${1}
 157
 158 | tc11-IMIX-2c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 159 | | [Tags] | IMIX | 2C
 160 | | framesize=IMIX_v4_1 | phy_cores=${2}
 161
 162 | tc12-IMIX-4c-1lbdpdk-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 163 | | [Tags] | IMIX | 4C
 164 | | framesize=IMIX_v4_1 | phy_cores=${4}