tests/vpp/perf/vm_vhost/10ge2p1x710-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X710 | DOT1Q | L2BDMACLRN | BASE | VHOST | 1VM
  20 | ... | VHOST_1024 | LBOND | LBOND_VPP | LBOND_MODE_LACP | LBOND_LB_L34
  21 | ... | LBOND_1L
  22 | ...
  23 | Suite Setup | Run Keywords
  24 | ... | Set up 3-node performance topology with DUT's NIC model | L2
  25 | ... | Intel-X710
  26 | ... | AND | Set up performance test suite with LACP mode link bonding
  27 | ...
  28 | Suite Teardown | Tear down 3-node performance topology
  29 | ...
  30 | Test Setup | Set up performance test
  31 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  32 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  33 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  34 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  35 | ...
  36 | Test Template | Local Template
  37 | ...
  38 | Documentation | *RFC2544: Pkt throughput L2BD test cases with vhost and vpp link bonding*
  39 | ...
  40 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  41 | ... | with single links between nodes.
  42 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. 802.1q
  43 | ... | tagging is applied on link between DUT1 and DUT2.
  44 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with VPP
  45 | ... | link bonding (mode LACP, transmit policy l34) on link between DUT1 and
  46 | ... | DUT2 and L2 bridge-domain with MAC learning enabled. Qemu Guest is
  47 | ... | connected to VPP via vhost-user interfaces. Guest is running DPDK
  48 | ... | testpmd interconnecting vhost-user interfaces using 5 cores pinned to
  49 | ... | cpus 5-9 and 2048M memory. Testpmd is using socket-mem=1024M (512x2M
  50 | ... | hugepages), 5 cores (1 main core and 4 cores dedicated for io),
  51 | ... | forwarding mode is set to io, rxd/txd=1024, burst=64. DUT1, DUT2 are
  52 | ... | tested with 2p10GE NIC X710 Fortville by Intel.
  53 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  54 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  55 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  56 | ... | of packets transmitted. NDR and PDR are discovered for different
  57 | ... | Ethernet L2 frame sizes using MLRsearch library.
  58 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  59 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per
  60 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  61 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  62 | ... | addresses of the TG node interfaces.
  63
  64 *** Variables ***
  65 | ${subid}= | 10
  66 | ${tag_rewrite}= | pop-1
  67 | ${overhead}= | ${4}
  68 # Link bonding config
  69 | ${bond_mode}= | lacp
  70 | ${lb_mode}= | l34
  71 # Socket names
  72 | ${bd_id1}= | 1
  73 | ${bd_id2}= | 2
  74 | ${sock1}= | /tmp/sock-1-${bd_id1}
  75 | ${sock2}= | /tmp/sock-1-${bd_id2}
  76 # X710 bandwidth limit
  77 | ${s_limit}= | ${10000000000}
  78 # Traffic profile:
  79 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  80
  81 *** Keywords ***
  82 | Local Template
  83 | | [Documentation]
  84 | | ... | [Cfg] DUT runs L2BD switching config.
  85 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  86 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  87 | | ...
  88 | | ... | *Arguments:*
  89 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  90 | | ... | Type: integer, string
  91 | | ... | - phy_cores - Number of physical cores. Type: integer
  92 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  93 | | ...
  94 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  95 | | ...
  96 | | Set Test Variable | ${framesize}
  97 | | Set Test Variable | ${min_rate} | ${10000}
  98 | | ${dut1_vm_refs}= | Create Dictionary
  99 | | ${dut2_vm_refs}= | Create Dictionary
 100 | | Set Test Variable | ${dut1_vm_refs}
 101 | | Set Test Variable | ${dut2_vm_refs}
 102 | | ...
 103 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
 104 | | And Add PCI devices to all DUTs
 105 | | And Add VLAN Strip Offload switch off between DUTs in 3-node single link topology
 106 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
 107 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
 108 | | And Apply startup configuration on all VPP DUTs
 109 | | When Initialize L2 bridge domains with Vhost-User and VLAN with VPP link bonding in a 3-node circular topology
 110 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
 111 | | ... | ${tag_rewrite} | ${bond_mode} | ${lb_mode}
 112 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 113 | | ... | DUT1 | ${sock1} | ${sock2} | DUT1_VM1 | jumbo=${jumbo}
 114 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 115 | | And Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 116 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 117 | | ... | DUT2 | ${sock1} | ${sock2} | DUT2_VM1 | jumbo=${jumbo}
 118 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 119 | | And Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 120 | | And All Vpp Interfaces Ready Wait | ${nodes}
 121 | | Then Find NDR and PDR intervals using optimized search
 122 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 123
 124 *** Test Cases ***
 125 | tc01-64B-1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 126 | | [Tags] | 64B | 1C
 127 | | framesize=${64} | phy_cores=${1}
 128
 129 | tc02-64B-2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 130 | | [Tags] | 64B | 2C
 131 | | framesize=${64} | phy_cores=${2}
 132
 133 | tc03-64B-4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 134 | | [Tags] | 64B | 4C
 135 | | framesize=${64} | phy_cores=${4}
 136
 137 | tc04-1518B-1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 138 | | [Tags] | 1518B | 1C
 139 | | framesize=${1518} | phy_cores=${1}
 140
 141 | tc05-1518B-2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 142 | | [Tags] | 1518B | 2C
 143 | | framesize=${1518} | phy_cores=${2}
 144
 145 | tc06-1518B-4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 146 | | [Tags] | 1518B | 4C
 147 | | framesize=${1518} | phy_cores=${4}
 148
 149 | tc07-9000B-1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 150 | | [Tags] | 9000B | 1C
 151 | | framesize=${9000} | phy_cores=${1}
 152
 153 | tc08-9000B-2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 154 | | [Tags] | 9000B | 2C
 155 | | framesize=${9000} | phy_cores=${2}
 156
 157 | tc09-9000B-4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 158 | | [Tags] | 9000B | 4C
 159 | | framesize=${9000} | phy_cores=${4}
 160
 161 | tc10-IMIX-1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 162 | | [Tags] | IMIX | 1C
 163 | | framesize=IMIX_v4_1 | phy_cores=${1}
 164
 165 | tc11-IMIX-2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 166 | | [Tags] | IMIX | 2C
 167 | | framesize=IMIX_v4_1 | phy_cores=${2}
 168
 169 | tc12-IMIX-4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 170 | | [Tags] | IMIX | 4C
 171 | | framesize=IMIX_v4_1 | phy_cores=${4}