tests/vpp/perf/vm_vhost/10ge2p1x710-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdrdisc.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDRDISC
  19 | ... | NIC_Intel-X710 | DOT1Q | L2BDMACLRN | BASE | VHOST | VM
  20 | ... | VHOST_1024 | LBOND | LBOND_VPP| LBOND_MODE_LACP | LBOND_LB_L34
  21 | ...
  22 | Suite Setup | Run Keywords
  23 | ... | Set up 3-node performance topology with DUT's NIC model | L2
  24 | ... | Intel-X520-DA2
  25 | ... | AND | Set up performance test suite with LACP mode link bonding
  26 | ...
  27 | Suite Teardown | Tear down 3-node performance topology
  28 | ...
  29 | Test Setup | Set up performance test
  30 | Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd
  31 | ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
  32 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  33 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  34 | ...
  35 | Test Template | Local template
  36 | ...
  37 | Documentation | *RFC2544: Packet throughput L2BD test cases with vhost and
  38 | ... | vpp link bonding*
  39 | ...
  40 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  41 | ... | with single links between nodes.
  42 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. 802.1q
  43 | ... | tagging is applied on link between DUT1 and DUT2.
  44 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with VPP
  45 | ... | link bonding (mode LACP, transmit policy l34) on link between DUT1 and
  46 | ... | DUT2 and L2 bridge-domain with MAC learning enabled. Qemu Guest is
  47 | ... | connected to VPP via vhost-user interfaces. Guest is running DPDK
  48 | ... | testpmd interconnecting vhost-user interfaces using 5 cores pinned to
  49 | ... | cpus 5-9 and 2048M memory. Testpmd is using socket-mem=1024M (512x2M
  50 | ... | hugepages), 5 cores (1 main core and 4 cores dedicated for io),
  51 | ... | forwarding mode is set to io, rxd/txd=1024, burst=64. DUT1, DUT2 are
  52 | ... | tested with 2p10GE NIC X710 Fortville by Intel.
  53 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  54 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  55 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  56 | ... | of packets transmitted. NDR and PDR are discovered for different
  57 | ... | Ethernet L2 frame sizes using either binary search or linear search
  58 | ... | algorithms with configured starting rate and final step that determines
  59 | ... | throughput measurement resolution. Test packets are generated by TG on
  60 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  61 | ... | (flow-group per direction, 253 flows per flow-group) with all packets
  62 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
  63 | ... | payload. MAC addresses are matching MAC addresses of the TG node
  64 | ... | interfaces.
  65 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  66
  67 *** Variables ***
  68 | ${perf_qemu_qsz}= | 1024
  69 | ${subid}= | 10
  70 | ${tag_rewrite}= | pop-1
  71 | ${vlan_overhead}= | ${4}
  72 # Link bonding config
  73 | ${bond_mode}= | lacp
  74 | ${lb_mode}= | l34
  75 # X710 bandwidth limit
  76 | ${s_limit} | ${10000000000}
  77 # Socket names
  78 | ${bd_id1}= | 1
  79 | ${bd_id2}= | 2
  80 | ${sock1}= | /tmp/sock-1-${bd_id1}
  81 | ${sock2}= | /tmp/sock-1-${bd_id2}
  82 # Traffic profile:
  83 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  84
  85 *** Keywords ***
  86 | Local template
  87 | | [Arguments] | ${phy_cores} | ${framesize} | ${search_type} | ${rxq}=${None}
  88 | | ... | ${min_rate}=${10000}
  89 | | ...
  90 | | Set Test Variable | ${framesize}
  91 | | Set Test Variable | ${min_rate}
  92 | | ${get_framesize}= | Get Frame Size | ${framesize}
  93 | | ${max_rate}= | Calculate pps | ${s_limit}
  94 | | ... | ${get_framesize + ${vlan_overhead}}
  95 | | ${binary_min}= | Set Variable | ${min_rate}
  96 | | ${binary_max}= | Set Variable | ${max_rate}
  97 | | ${threshold}= | Set Variable | ${min_rate}
  98 | | ${dut1_vm_refs}= | Create Dictionary
  99 | | ${dut2_vm_refs}= | Create Dictionary
 100 | | Set Test Variable | ${dut1_vm_refs}
 101 | | Set Test Variable | ${dut2_vm_refs}
 102 | | ${jumbo_frames}= | Set Variable If
 103 | | ... | ${get_framesize + ${vlan_overhead}} < ${1522} | ${False} | ${True}
 104 | | ...
 105 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
 106 | | And Add PCI devices to all DUTs
 107 | | And Add VLAN Strip Offload switch off between DUTs in 3-node single link topology
 108 | | And Run Keyword If | ${get_framesize + ${vlan_overhead}} < ${1522}
 109 | | ... | Add no multi seg to all DUTs
 110 | | And Apply startup configuration on all VPP DUTs
 111 | | When Initialize L2 bridge domains with Vhost-User and VLAN with VPP link bonding in a 3-node circular topology
 112 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
 113 | | ... | ${tag_rewrite} | ${bond_mode} | ${lb_mode}
 114 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 115 | | ... | ${dut1} | ${sock1} | ${sock2} | DUT1_VM1
 116 | | ... | jumbo_frames=${jumbo_frames}
 117 | | And Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 118 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 119 | | ... | ${dut2} | ${sock1} | ${sock2} | DUT2_VM1
 120 | | ... | jumbo_frames=${jumbo_frames}
 121 | | And Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 122 | | And All Vpp Interfaces Ready Wait | ${nodes}
 123 | | Then Run Keyword If | '${search_type}' == 'NDR'
 124 | | ... | Find NDR using binary search and pps
 125 | | ... | ${framesize} | ${binary_min} | ${binary_max} | ${traffic_profile}
 126 | | ... | ${min_rate} | ${max_rate} | ${threshold}
 127 | | ... | ELSE IF | '${search_type}' == 'PDR'
 128 | | ... | Find PDR using binary search and pps
 129 | | ... | ${framesize} | ${binary_min} | ${binary_max} | ${traffic_profile}
 130 | | ... | ${min_rate} | ${max_rate} | ${threshold}
 131 | | ... | ${perf_pdr_loss_acceptance} | ${perf_pdr_loss_acceptance_type}
 132
 133 *** Test Cases ***
 134 | tc01-64B-1t1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 135 | | [Tags] | 64B | 1C | NDRDISC
 136 | | phy_cores=${1} | framesize=${64} | search_type=NDR
 137
 138 | tc02-64B-1t1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 139 | | [Tags] | 64B | 1C | PDRDISC | SKIP_PATCH
 140 | | phy_cores=${1} | framesize=${64} | search_type=PDR
 141
 142 | tc03-1518B-1t1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 143 | | [Tags] | 1518B | 1C | NDRDISC
 144 | | phy_cores=${1} | framesize=${1518} | search_type=NDR
 145
 146 | tc04-1518B-1t1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 147 | | [Tags] | 1518B | 1C | PDRDISC | SKIP_PATCH
 148 | | phy_cores=${1} | framesize=${1518} | search_type=PDR
 149
 150 | tc05-9000B-1t1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 151 | | [Tags] | 9000B | 1C | NDRDISC
 152 | | phy_cores=${1} | framesize=${9000} | search_type=NDR
 153
 154 | tc06-9000B-1t1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 155 | | [Tags] | 9000B | 1C | PDRDISC | SKIP_PATCH
 156 | | phy_cores=${1} | framesize=${9000} | search_type=PDR
 157
 158 | tc07-IMIX-1t1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 159 | | [Tags] | IMIX | 1C | NDRDISC
 160 | | phy_cores=${1} | framesize=IMIX_v4_1 | search_type=NDR
 161
 162 | tc08-IMIX-1t1c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 163 | | [Tags] | IMIX | 1C | PDRDISC | SKIP_PATCH
 164 | | phy_cores=${1} | framesize=IMIX_v4_1 | search_type=PDR
 165
 166 | tc09-64B-2t2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 167 | | [Tags] | 64B | 2C | NDRDISC
 168 | | phy_cores=${2} | framesize=${64} | search_type=NDR
 169
 170 | tc10-64B-2t2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 171 | | [Tags] | 64B | 2C | PDRDISC | SKIP_PATCH
 172 | | phy_cores=${2} | framesize=${64} | search_type=PDR
 173
 174 | tc11-1518B-2t2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 175 | | [Tags] | 1518B | 2C | NDRDISC | SKIP_PATCH
 176 | | phy_cores=${2} | framesize=${1518} | search_type=NDR
 177
 178 | tc12-1518B-2t2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 179 | | [Tags] | 1518B | 2C | PDRDISC | SKIP_PATCH
 180 | | phy_cores=${2} | framesize=${1518} | search_type=PDR
 181
 182 | tc13-9000B-2t2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 183 | | [Tags] | 9000B | 2C | NDRDISC | SKIP_PATCH
 184 | | phy_cores=${2} | framesize=${9000} | search_type=NDR
 185
 186 | tc14-9000B-2t2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 187 | | [Tags] | 9000B | 2C | PDRDISC | SKIP_PATCH
 188 | | phy_cores=${2} | framesize=${9000} | search_type=PDR
 189
 190 | tc15-IMIX-2t2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 191 | | [Tags] | IMIX | 2C | NDRDISC | SKIP_PATCH
 192 | | phy_cores=${2} | framesize=IMIX_v4_1 | search_type=NDR
 193
 194 | tc16-IMIX-2t2c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 195 | | [Tags] | IMIX | 2C | PDRDISC | SKIP_PATCH
 196 | | phy_cores=${2} | framesize=IMIX_v4_1 | search_type=PDR
 197
 198 | tc17-64B-4t4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 199 | | [Tags] | 64B | 4C | NDRDISC
 200 | | phy_cores=${4} | framesize=${64} | search_type=NDR
 201
 202 | tc18-64B-4t4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 203 | | [Tags] | 64B | 4C | PDRDISC | SKIP_PATCH
 204 | | phy_cores=${4} | framesize=${64} | search_type=PDR
 205
 206 | tc19-1518B-4t4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 207 | | [Tags] | 1518B | 4C | NDRDISC | SKIP_PATCH
 208 | | phy_cores=${4} | framesize=${1518} | search_type=NDR
 209
 210 | tc20-1518B-4t4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 211 | | [Tags] | 1518B | 4C | PDRDISC | SKIP_PATCH
 212 | | phy_cores=${4} | framesize=${1518} | search_type=PDR
 213
 214 | tc21-9000B-4t4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 215 | | [Tags] | 9000B | 4C | NDRDISC | SKIP_PATCH
 216 | | phy_cores=${4} | framesize=${9000} | search_type=NDR
 217
 218 | tc22-9000B-4t4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 219 | | [Tags] | 9000B | 4C | PDRDISC | SKIP_PATCH
 220 | | phy_cores=${4} | framesize=${9000} | search_type=PDR
 221
 222 | tc23-IMIX-4t4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrdisc
 223 | | [Tags] | IMIX | 4C | NDRDISC | SKIP_PATCH
 224 | | phy_cores=${4} | framesize=IMIX_v4_1 | search_type=NDR
 225
 226 | tc24-IMIX-4t4c-1lbvpplacp-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-pdrdisc
 227 | | [Tags] | IMIX | 4C | PDRDISC | SKIP_PATCH
 228 | | phy_cores=${4} | framesize=IMIX_v4_1 | search_type=PDR