tests/vpp/perf/vm_vhost/10ge2p1x710-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | DOT1Q | L2XCFWD | BASE | VHOST | 1VM
  19 | ... | VHOST_1024 | LBOND | LBOND_VPP | LBOND_MODE_LACP | LBOND_LB_L34
  20 | ... | LBOND_1L | NF_VPPL2XC | DRV_VFIO_PCI
  21 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  22 | ... | 1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc
  23 |
  24 | Suite Setup | Setup suite topology interfaces | performance
  25 | Suite Teardown | Tear down suite | performance
  26 | Test Setup | Setup test | performance
  27 | Test Teardown | Tear down test | performance | vhost
  28 |
  29 | Test Template | Local Template
  30 |
  31 | Documentation | **RFC2544: Pkt throughput L2XC test cases with vhost and vpp \
  32 | ... | link bonding**
  33 | ... |
  34 | ... | - **[Top] Network Topologies:** TG-DUT1-DUT2-TG 3-node circular \
  35 | ... | topology with single links between nodes.
  36 | ... |
  37 | ... | - **[Enc] Packet Encapsulations:** Eth-IPv4 for L2 cross connect. \
  38 | ... | 802.1q tagging is applied on link between DUT1 and DUT2.
  39 | ... |
  40 | ... | - **[Cfg] DUT configuration:** DUT1 and DUT2 are configured with VPP \
  41 | ... | link bonding (mode LACP, transmit policy l34) on link between DUT1 and \
  42 | ... | DUT2 and L2 cross- connect. Qemu VNFs are \
  43 | ... | connected to VPP via vhost-user interfaces. Guest is running VPP l2xc \
  44 | ... | interconnecting vhost-user interfaces, rxd/txd=1024. DUT1/DUT2 is \
  45 | ... | tested with ${nic_name}.
  46 | ... |
  47 | ... | - **[Ver] TG verification:** TG finds and reports throughput NDR (Non \
  48 | ... | Drop Rate) with zero packet loss tolerance and throughput PDR \
  49 | ... | (Partial Drop Rate) with non-zero packet loss tolerance (LT) \
  50 | ... | expressed in percentage of packets transmitted. NDR and PDR are \
  51 | ... | discovered for different Ethernet L2 frame sizes using MLRsearch \
  52 | ... | library.
  53 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile \
  54 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per \
  55 | ... | flow-group) with all packets containing Ethernet header, IPv4 header \
  56 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC \
  57 | ... | addresses of the TG node interfaces.
  58 | ... |
  59 | ... | - **[Ref] Applicable standard specifications:** RFC2544.
  60
  61 *** Variables ***
  62 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so | lacp_plugin.so
  63 | ${crypto_type}= | ${None}
  64 | ${nic_name}= | Intel-X710
  65 | ${nic_driver}= | vfio-pci
  66 | ${nic_rxq_size}= | 0
  67 | ${nic_txq_size}= | 0
  68 | ${nic_pfs}= | 2
  69 | ${nic_vfs}= | 0
  70 | ${osi_layer}= | L2
  71 | ${overhead}= | ${4}
  72 | ${subid}= | 10
  73 | ${tag_rewrite}= | pop-1
  74 | ${nf_dtcr}= | ${1}
  75 | ${nf_dtc}= | ${1}
  76 | ${nf_chains}= | ${1}
  77 | ${nf_nodes}= | ${1}
  78 # Link bonding config
  79 | ${bond_mode}= | lacp
  80 | ${lb_mode}= | l34
  81 # Traffic profile:
  82 | ${traffic_profile}= | trex-stl-3n-ethip4-ip4src254
  83
  84 *** Keywords ***
  85 | Local Template
  86 | | [Documentation]
  87 | | ... | - **[Cfg]** DUT runs L2XC switching config. \
  88 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  89 | | ... | - **[Ver]** Measure NDR and PDR values using MLRsearch algorithm.
  90 | |
  91 | | ... | *Arguments:*
  92 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  93 | | ... | Type: integer, string
  94 | | ... | - phy_cores - Number of physical cores. Type: integer
  95 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  96 | |
  97 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  98 | |
  99 | | Set Test Variable | \${frame_size}
 100 | | Set Test Variable | ${vlan_strip_off} | ${TRUE}
 101 | |
 102 | | Given Set Max Rate And Jumbo
 103 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
 104 | | And Pre-initialize layer driver | ${nic_driver}
 105 | | And Apply startup configuration on all VPP DUTs
 106 | | When Initialize layer driver | ${nic_driver}
 107 | | And Initialize layer interface
 108 | | And Initialize L2 xconnect with Vhost-User and VLAN with VPP link bonding in 3-node circular topology
 109 | | ... | ${subid} | ${tag_rewrite} | ${bond_mode} | ${lb_mode}
 110 | | And Configure chains of NFs connected via vhost-user
 111 | | ... | nf_chains=${nf_chains} | nf_nodes=${nf_nodes} | jumbo=${jumbo}
 112 | | ... | use_tuned_cfs=${False} | auto_scale=${True}
 113 | | ... | vnf=vppl2xc_2vhostvr1024
 114 | | Then Find NDR and PDR intervals using optimized search
 115
 116 *** Test Cases ***
 117 | 64B-1c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 118 | | [Tags] | 64B | 1C
 119 | | frame_size=${64} | phy_cores=${1}
 120
 121 | 64B-2c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 122 | | [Tags] | 64B | 2C
 123 | | frame_size=${64} | phy_cores=${2}
 124
 125 | 64B-4c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 126 | | [Tags] | 64B | 4C
 127 | | frame_size=${64} | phy_cores=${4}
 128
 129 | 1518B-1c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 130 | | [Tags] | 1518B | 1C
 131 | | frame_size=${1518} | phy_cores=${1}
 132
 133 | 1518B-2c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 134 | | [Tags] | 1518B | 2C
 135 | | frame_size=${1518} | phy_cores=${2}
 136
 137 | 1518B-4c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 138 | | [Tags] | 1518B | 4C
 139 | | frame_size=${1518} | phy_cores=${4}
 140
 141 | 9000B-1c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 142 | | [Tags] | 9000B | 1C
 143 | | frame_size=${9000} | phy_cores=${1}
 144
 145 | 9000B-2c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 146 | | [Tags] | 9000B | 2C
 147 | | frame_size=${9000} | phy_cores=${2}
 148
 149 | 9000B-4c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 150 | | [Tags] | 9000B | 4C
 151 | | frame_size=${9000} | phy_cores=${4}
 152
 153 | IMIX-1c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 154 | | [Tags] | IMIX | 1C
 155 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 156
 157 | IMIX-2c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 158 | | [Tags] | IMIX | 2C
 159 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 160
 161 | IMIX-4c-1lbvpplacp-dot1q-l2xcbase-eth-2vhostvr1024-1vm-vppl2xc-ndrpdr
 162 | | [Tags] | IMIX | 4C
 163 | | frame_size=IMIX_v4_1 | phy_cores=${4}