tests/vpp/perf/vm_vhost/10ge2p1x710-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Library | resources.libraries.python.QemuUtils
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | NIC_Intel-X710 | DOT1Q | L2BDMACLRN | BASE | VHOST | 1VM
  20 | ... | VHOST_1024
  21 | ...
  22 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  23 | ... | L2 | Intel-X710
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance mrr test with vhost and VM with dpdk-testpmd
  28 | ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
  29 | ... | dut2_node=${dut2} | dut2_vm_refs=${dut2_vm_refs}
  30 | ...
  31 | Test Template | Local Template
  32 | ...
  33 | Documentation | *Raw results L2BD with vhost and IEEE 802.1Q test cases*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. IEEE\
  38 | ... | 802.1Q tagging is applied on link between DUT1 and DUT2.
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-\
  40 | ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via\
  41 | ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting\
  42 | ... | vhost-user interfaces, forwarding mode is set to io, rxd/txd=1024.\
  43 | ... | DUT1 and DUT2 are tested with 2p10GE NIC X710 by Intel.
  44 | ... | *[Ver] TG verification:* In MaxReceivedRate tests TG sends traffic\
  45 | ... | at line rate and reports total received/sent packets over trial period.\
  46 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile\
  47 | ... | contains two L3 flow-groups (flow-group per direction, 254 flows per\
  48 | ... | flow-group) with all packets containing Ethernet header, IPv4 header\
  49 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC\
  50 | ... | addresses of the TG node interfaces.
  51 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  52
  53 *** Variables ***
  54 | ${subid}= | 10
  55 | ${tag_rewrite}= | pop-1
  56 | ${overhead}= | ${4}
  57 # Socket names
  58 | ${bd_id1}= | 1
  59 | ${bd_id2}= | 2
  60 | ${sock1}= | /tmp/sock-1-${bd_id1}
  61 | ${sock2}= | /tmp/sock-1-${bd_id2}
  62 # X710 bandwidth limit
  63 | ${s_limit}= | ${10000000000}
  64 # Traffic profile:
  65 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  66
  67 *** Keywords ***
  68 | Local Template
  69 | | [Documentation]
  70 | | ... | [Cfg] Each DUT runs L2BD switching with VLAN and uses ${phy_cores}\
  71 | | ... | physical core(s) for worker threads.
  72 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  73 | | ... | trial throughput test.
  74 | | ...
  75 | | ... | *Arguments:*
  76 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  77 | | ... | Type: integer, string
  78 | | ... | - phy_cores - Number of physical cores. Type: integer
  79 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  80 | | ...
  81 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  82 | | ...
  83 | | ${dut1_vm_refs}= | Create Dictionary
  84 | | ${dut2_vm_refs}= | Create Dictionary
  85 | | Set Test Variable | ${dut1_vm_refs}
  86 | | Set Test Variable | ${dut2_vm_refs}
  87 | | ...
  88 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  89 | | And Add PCI devices to all DUTs
  90 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  91 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
  92 | | And Apply startup configuration on all VPP DUTs
  93 | | When Initialize L2 bridge domains with Vhost-User and VLAN in circular topology
  94 | | ... | ${bd_id1} | ${bd_id2} | ${sock1} | ${sock2} | ${subid}
  95 | | ... | ${tag_rewrite}
  96 | | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
  97 | | ... | DUT1 | ${sock1} | ${sock2} | DUT1_VM1 | jumbo=${jumbo}
  98 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
  99 | | Set To Dictionary | ${dut1_vm_refs} | DUT1_VM1 | ${vm1}
 100 | | ${vm2}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
 101 | | ... | DUT2 | ${sock1} | ${sock2} | DUT2_VM1 | jumbo=${jumbo}
 102 | | ... | perf_qemu_qsz=${1024} | use_tuned_cfs=${False}
 103 | | Set To Dictionary | ${dut2_vm_refs} | DUT2_VM1 | ${vm2}
 104 | | Then Traffic should pass with maximum rate
 105 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
 106
 107 *** Test Cases ***
 108 | tc01-64B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 109 | | [Tags] | 64B | 1C
 110 | | framesize=${64} | phy_cores=${1}
 111
 112 | tc02-64B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 113 | | [Tags] | 64B | 2C
 114 | | framesize=${64} | phy_cores=${2}
 115
 116 | tc03-64B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 117 | | [Tags] | 64B | 4C
 118 | | framesize=${64} | phy_cores=${4}
 119
 120 | tc04-1518B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 121 | | [Tags] | 1518B | 1C
 122 | | framesize=${1518} | phy_cores=${1}
 123
 124 | tc05-1518B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 125 | | [Tags] | 1518B | 2C
 126 | | framesize=${1518} | phy_cores=${2}
 127
 128 | tc06-1518B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 129 | | [Tags] | 1518B | 4C
 130 | | framesize=${1518} | phy_cores=${4}
 131
 132 | tc07-9000B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 133 | | [Tags] | 9000B | 1C
 134 | | framesize=${9000} | phy_cores=${1}
 135
 136 | tc08-9000B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 137 | | [Tags] | 9000B | 2C
 138 | | framesize=${9000} | phy_cores=${2}
 139
 140 | tc09-9000B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 141 | | [Tags] | 9000B | 4C
 142 | | framesize=${9000} | phy_cores=${4}
 143
 144 | tc10-IMIX-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 145 | | [Tags] | IMIX | 1C
 146 | | framesize=IMIX_v4_1 | phy_cores=${1}
 147
 148 | tc11-IMIX-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 149 | | [Tags] | IMIX | 2C
 150 | | framesize=IMIX_v4_1 | phy_cores=${2}
 151
 152 | tc12-IMIX-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-mrr
 153 | | [Tags] | IMIX | 4C
 154 | | framesize=IMIX_v4_1 | phy_cores=${4}