tests/vpp/perf/vm_vhost/10ge2p1x710-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | DOT1Q | L2BDMACLRN | BASE | VHOST | 1VM
  19 | ... | VHOST_1024 | NF_TESTPMD | DRV_VFIO_PCI
  20 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  21 | ... | dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm
  22 |
  23 | Suite Setup | Setup suite topology interfaces | performance
  24 | Suite Teardown | Tear down suite | performance
  25 | Test Setup | Setup test | performance
  26 | Test Teardown | Tear down test | performance | vhost
  27 |
  28 | Test Template | Local Template
  29 |
  30 | Documentation | *RFC2544: Pkt throughput L2BD with vhost and IEEE 802.1Q test
  31 | ... | cases*
  32 |
  33 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4. IEEE\
  36 | ... | 802.1Q tagging is applied on link between DUT1 and DUT2.
  37 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-\
  38 | ... | domain and MAC learning enabled. Qemu VNFs are \
  39 | ... | connected to VPP via vhost-user interfaces. Guest is running testpmd \
  40 | ... | interconnecting vhost-user interfaces, rxd/txd=1024. DUT1/DUT2 is \
  41 | ... | tested with ${nic_name}.
  42 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  43 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  44 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  45 | ... | of packets transmitted. NDR and PDR are discovered for different\
  46 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  47 | ... | Test packets are\
  48 | ... | generated by TG on links to DUTs. TG traffic profile contains two L3\
  49 | ... | flow-groups (flow-group per direction, 254 flows per flow-group) with\
  50 | ... | all packets containing Ethernet header, IPv4 header with IP protocol=61\
  51 | ... | and static payload. MAC addresses are matching MAC addresses of the TG\
  52 | ... | node interfaces.
  53 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  54
  55 *** Variables ***
  56 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  57 | ${crypto_type}= | ${None}
  58 | ${nic_name}= | Intel-X710
  59 | ${nic_driver}= | vfio-pci
  60 | ${nic_rxq_size}= | 0
  61 | ${nic_txq_size}= | 0
  62 | ${nic_pfs}= | 2
  63 | ${nic_vfs}= | 0
  64 | ${osi_layer}= | L2
  65 | ${overhead}= | ${4}
  66 | ${subid}= | 10
  67 | ${tag_rewrite}= | pop-1
  68 | ${bd_id1}= | 1
  69 | ${bd_id2}= | 2
  70 | ${nf_dtcr}= | ${1}
  71 | ${nf_dtc}= | ${1}
  72 | ${nf_chains}= | ${1}
  73 | ${nf_nodes}= | ${1}
  74 # Traffic profile:
  75 | ${traffic_profile}= | trex-stl-3n-ethip4-ip4src254
  76
  77 *** Keywords ***
  78 | Local Template
  79 | | [Documentation]
  80 | | ... | [Cfg] Each DUT runs L2BD switching with VLAN and uses ${phy_cores}\
  81 | | ... | physical core(s) for worker threads.
  82 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  83 | |
  84 | | ... | *Arguments:*
  85 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  86 | | ... | Type: integer, string
  87 | | ... | - phy_cores - Number of physical cores. Type: integer
  88 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  89 | |
  90 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  91 | |
  92 | | Set Test Variable | \${frame_size}
  93 | |
  94 | | Given Set Max Rate And Jumbo
  95 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  96 | | And Pre-initialize layer driver | ${nic_driver}
  97 | | And Apply startup configuration on all VPP DUTs
  98 | | When Initialize layer driver | ${nic_driver}
  99 | | And Initialize layer interface
 100 | | And Initialize L2 bridge domains with Vhost-User and VLAN in circular topology
 101 | | ... | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
 102 | | And Configure chains of NFs connected via vhost-user
 103 | | ... | nf_chains=${nf_chains} | nf_nodes=${nf_nodes} | jumbo=${jumbo}
 104 | | ... | use_tuned_cfs=${False} | auto_scale=${True} | vnf=testpmd_io
 105 | | Then Find NDR and PDR intervals using optimized search
 106
 107 *** Test Cases ***
 108 | 64B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 109 | | [Tags] | 64B | 1C
 110 | | frame_size=${64} | phy_cores=${1}
 111
 112 | 64B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 113 | | [Tags] | 64B | 2C
 114 | | frame_size=${64} | phy_cores=${2}
 115
 116 | 64B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 117 | | [Tags] | 64B | 4C
 118 | | frame_size=${64} | phy_cores=${4}
 119
 120 | 1518B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 121 | | [Tags] | 1518B | 1C
 122 | | frame_size=${1518} | phy_cores=${1}
 123
 124 | 1518B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 125 | | [Tags] | 1518B | 2C
 126 | | frame_size=${1518} | phy_cores=${2}
 127
 128 | 1518B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 129 | | [Tags] | 1518B | 4C
 130 | | frame_size=${1518} | phy_cores=${4}
 131
 132 | 9000B-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 133 | | [Tags] | 9000B | 1C
 134 | | frame_size=${9000} | phy_cores=${1}
 135
 136 | 9000B-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 137 | | [Tags] | 9000B | 2C
 138 | | frame_size=${9000} | phy_cores=${2}
 139
 140 | 9000B-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 141 | | [Tags] | 9000B | 4C
 142 | | frame_size=${9000} | phy_cores=${4}
 143
 144 | IMIX-1c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 145 | | [Tags] | IMIX | 1C
 146 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 147
 148 | IMIX-2c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 149 | | [Tags] | IMIX | 2C
 150 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 151
 152 | IMIX-4c-dot1q-l2bdbasemaclrn-eth-2vhostvr1024-1vm-ndrpdr
 153 | | [Tags] | IMIX | 4C
 154 | | frame_size=IMIX_v4_1 | phy_cores=${4}